# Sentences, clauses, imperatives, and sentential complements

Last update: 2006-01-25 20:10:39 CET

- Clauses
- Clauses missing object noun phrases
- Imperatives
- Embedded sentences
- Sentences

Produced by gfdoc - a rudimentary GF document generator. (c) Aarne Ranta (aarne@cs.chalmers.se) 2002 under GNU GPL.

        abstract Sentence = Cat ** {

## Clauses

The `NP VP` predication rule form a clause whose linearization gives a table of all tense variants, positive and negative. Clauses are converted to `S` (with fixed tense) in Tensed.

          fun
            PredVP    : NP -> VP -> Cl ;         -- John walks

Using an embedded sentence as a subject is treated separately. This can be overgenerating. E.g. whether you go as subject is only meaningful for some verb phrases.

            PredSCVP  : SC -> VP -> Cl ;         -- that you go makes me happy

## Clauses missing object noun phrases

This category is a variant of the 'slash category' `S/NP` of GPSG and categorial grammars, which in turn replaces movement transformations in the formation of questions and relative clauses. Except `SlashV2`, the construction rules can be seen as special cases of function composition, in the style of CCG. Note the set is not complete and lacks e.g. verbs with more than 2 places.

            SlashV2   : NP -> V2 -> Slash ;      -- (whom) he sees
            SlashVVV2 : NP -> VV -> V2 -> Slash; -- (whom) he wants to see
            AdvSlash  : Slash -> Adv -> Slash ;  -- (whom) he sees tomorrow
            SlashPrep : Cl -> Prep -> Slash ;    -- (with whom) he walks

## Imperatives

An imperative is straightforwardly formed from a verb phrase. It has variation over positive and negative, singular and plural. To fix these parameters, see Phrase.

            ImpVP     : VP -> Imp ;              -- go

## Embedded sentences

Sentences, questions, and infinitival phrases can be used as subjects and (adverbial) complements.

            EmbedS    : S  -> SC ;               -- that you go
            EmbedQS   : QS -> SC ;               -- whether you go
            EmbedVP   : VP -> SC ;               -- to go

## Sentences

These are the 2 x 4 x 4 = 16 forms generated by different combinations of tense, polarity, and anteriority, which are defined in Tense.

          fun
            UseCl  : Tense -> Ant -> Pol -> Cl  -> S ;
            UseQCl : Tense -> Ant -> Pol -> QCl -> QS ;
            UseRCl : Tense -> Ant -> Pol -> RCl -> RS ;

        }

Examples for English `S`/`Cl`:

Pres Simul Pos ODir : he sleeps Pres Simul Neg ODir : he doesn't sleep Pres Anter Pos ODir : he has slept Pres Anter Neg ODir : he hasn't slept Past Simul Pos ODir : he slept Past Simul Neg ODir : he didn't sleep Past Anter Pos ODir : he had slept Past Anter Neg ODir : he hadn't slept Fut Simul Pos ODir : he will sleep Fut Simul Neg ODir : he won't sleep Fut Anter Pos ODir : he will have slept Fut Anter Neg ODir : he won't have slept Cond Simul Pos ODir : he would sleep Cond Simul Neg ODir : he wouldn't sleep Cond Anter Pos ODir : he would have slept Cond Anter Neg ODir : he wouldn't have slept