GitHub/gf-core
1
0
Fork 1
mirror of https://github.com/GrammaticalFramework/gf-core.git synced 2026-05-05 17:22:51 -06:00
Code Issues Packages Projects Releases Wiki Activity

danish and norwegian in 1.4

Browse Source
This commit is contained in:
aarne
2008-06-02 15:35:17 +00:00
parent 41e0ba7f64
commit 174bff70e0
56 changed files with 3198 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
lib/resource-1.4/danish/AdjectiveDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete AdjectiveDan of Adjective = CatDan ** AdjectiveScand with
(ResScand = ResDan) ;

2
lib/resource-1.4/danish/AdverbDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete AdverbDan of Adverb = CatDan ** AdverbScand with
(ResScand = ResDan) ;

2
lib/resource-1.4/danish/CatDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete CatDan of Cat = CommonX ** CatScand with
(ResScand = ResDan) ;

2
lib/resource-1.4/danish/ConjunctionDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete ConjunctionDan of Conjunction = CatDan ** ConjunctionScand with
(ResScand = ResDan) ;

7
lib/resource-1.4/danish/Danish.gf Normal file
View File

@@ -0,0 +1,7 @@
--# -path=.:../scandinavian:../abstract:../common:prelude
concrete Danish of DanishAbs =
LangDan,
IrregDan - [fly_V],
ExtraDan
** {} ;

5
lib/resource-1.4/danish/DanishAbs.gf Normal file
View File

@@ -0,0 +1,5 @@
abstract DanishAbs =
Lang,
IrregDanAbs - [fly_V],
ExtraDanAbs
** {} ;

86
lib/resource-1.4/danish/DiffDan.gf Normal file
View File

@@ -0,0 +1,86 @@
instance DiffDan of DiffScand = open CommonScand, Prelude in {
-- Parameters.
param
Gender = Utr | Neutr ;
oper
utrum = Utr ;
neutrum = Neutr ;
gennum : Gender -> Number -> GenNum = \g,n ->
case <<g,n> : Gender * Number> of {
<Utr, Sg> => SgUtr ;
<Neutr,Sg> => SgNeutr ;
_ => Plg
} ;
detDef : Species = Indef ;
Verb : Type = {
s : VForm => Str ;
part : Str ;
vtype : VType ;
isVaere : Bool
} ;
hasAuxBe v = v.isVaere ;
-- Strings.
conjThat = "at" ;
conjThan = "end" ;
conjAnd = "og" ;
infMark = "at" ;
compMore = "mere" ;
subjIf = "hvis" ;
artIndef : Gender => Str = table {
Utr => "en" ;
Neutr => "et"
} ;
verbHave =
mkVerb "have" "har" "hav" "havde" "haft" "haven" "havet" "havne" **
{part = [] ; isVaere = False} ;
verbBe =
mkVerb "være" "er" "var" "var" "været" "væren" "været" "værne" **
{part = [] ; isVaere = False} ;
verbBecome =
mkVerb "blive" "bliver" "bliv" "blev" "blevet"
"bliven" "blivet" "blivne" **
{part = [] ; isVaere = True} ;
auxFut = "vil" ; -- "skal" in ExtDan
auxCond = "ville" ;
negation : Polarity => Str = table {
Pos => [] ;
Neg => "ikke"
} ;
genderForms : (x1,x2 : Str) -> Gender => Str = \all,allt ->
table {
Utr => all ;
Neutr => allt
} ;
relPron : GenNum => RCase => Str = \\gn,c => case c of {
RNom => "som" ;
RGen => "hvis" ;
RPrep => gennumForms "hvilken" "hvilket" "hvilke" ! gn
} ;
pronSuch = gennumForms "sådan" "sådant" "sådanne" ;
reflPron : Agr -> Str = \a -> case a of {
{gn = Plg ; p = P1} => "oss" ;
{gn = Plg ; p = P2} => "jer" ;
{p = P1} => "mig" ;
{p = P2} => "dig" ;
{p = P3} => "sig"
} ;
}

3
lib/resource-1.4/danish/ExtraDan.gf Normal file
View File

@@ -0,0 +1,3 @@
concrete ExtraDan of ExtraDanAbs = ExtraScandDan ** open CommonScand, ResDan in {
}

7
lib/resource-1.4/danish/ExtraDanAbs.gf Normal file
View File

@@ -0,0 +1,7 @@
-- Structures special for Danish. These are not implemented in other
-- Scandinavian languages.
abstract ExtraDanAbs = ExtraScandAbs ** {
}

2
lib/resource-1.4/danish/ExtraScandDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete ExtraScandDan of ExtraScandAbs = CatDan ** ExtraScand with
(ResScand = ResDan) ;

21
lib/resource-1.4/danish/GrammarDan.gf Normal file
View File

@@ -0,0 +1,21 @@
--# -path=.:../scandinavian:../abstract:../common:prelude
concrete GrammarDan of Grammar =
NounDan,
VerbDan,
AdjectiveDan,
AdverbDan,
NumeralDan,
SentenceDan,
QuestionDan,
RelativeDan,
ConjunctionDan,
PhraseDan,
TextX,
IdiomDan,
StructuralDan
** {
flags startcat = Phr ; unlexer = text ; lexer = text ;
} ;

41
lib/resource-1.4/danish/IdiomDan.gf Normal file
View File

@@ -0,0 +1,41 @@
concrete IdiomDan of Idiom = CatDan **
open MorphoDan, ParadigmsDan, IrregDan, Prelude in {
flags optimize=all_subs ;
lin
ImpersCl vp = mkClause "det" (agrP3 MorphoDan.neutrum Sg) vp ;
GenericCl vp = mkClause "man" (agrP3 MorphoDan.utrum Sg) vp ;
CleftNP np rs = mkClause "det" (agrP3 MorphoDan.neutrum Sg)
(insertObj (\\_ => rs.s ! np.a)
(insertObj (\\_ => np.s ! rs.c) (predV verbBe))) ;
CleftAdv ad s = mkClause "det" (agrP3 MorphoDan.neutrum Sg)
(insertObj (\\_ => "som" ++ s.s ! Sub)
(insertObj (\\_ => ad.s) (predV verbBe))) ;
ExistNP np =
mkClause "det" (agrP3 MorphoDan.neutrum Sg) (insertObj
(\\_ => np.s ! accusative) (predV (depV finde_V))) ;
ExistIP ip = {
s = \\t,a,p =>
let
cls =
(mkClause "det" (agrP3 MorphoDan.neutrum Sg) (predV (depV finde_V))).s ! t ! a ! p ;
who = ip.s ! accusative
in table {
QDir => who ++ cls ! Inv ;
QIndir => who ++ cls ! Sub
}
} ;
ProgrVP vp =
insertObj (\\a => ["ved å"] ++ infVP vp a) (predV verbBe) ;
ImpPl1 vp = {s = ["lad os"] ++ infVP vp {gn = Plg ; p = P1}} ;
}

72
lib/resource-1.4/danish/IrregDan.gf Normal file
View File

@@ -0,0 +1,72 @@
--# -path=.:../scandinavian:../common:../abstract:../../prelude
-- http://users.cybercity.dk/~nmb3879/danishgram3.html
concrete IrregDan of IrregDanAbs = CatDan ** open Prelude, ParadigmsDan in {
flags optimize=values ;
lin
bære_V = irregV "bære" "bar" "båret" ;
bede_V = mkV "bede" "beder" "bedes" "bad" "bedt" "bed" ;
bide_V = irregV "bite" "bed" "bidt" ;
binde_V = irregV "binde" "bandt" "bundet" ;
blive_V = irregV "blive" "blev" "blevet" ;
brænde_V = irregV "brænde" "brandt" "brændt" ;--
bringe_V = irregV "bringe" "bragte" "bragt" ;
burde_V = irregV "burde" "burde" "burdet" ;--
dø_V = irregV "dø" "døde" "død" ;
drage_V = irregV "drage" "drog" "draget" ;
drikke_V = irregV "drikke" "drak" "drukket" ;
drive_V = irregV "drive" "drev" "drevet" ;
falde_V = irregV "falde" "faldt" "faldet" ;----er
få_V = irregV "få" "fik" "fået" ;
finde_V = irregV "finde" "fandt" "fundet" ;
flyde_V = irregV "flyde" "flød" "flydt" ;
flyve_V = irregV "flyve" "fløj" "fløjet" ;
forlade_V = irregV "forlade" "forlod" "forladet" ;
forstå_V = irregV "forstå" "forstod" "forstået" ;
fryse_V = irregV "fryse" "frøs" "frosset" ;
gå_V = irregV "gå" "gik" "gået" ;----er
give_V = irregV "give" "gav" "givet" ;
gnide_V = irregV "gnide" "gned" "gnidd" ;--
gøre_V = irregV "gøre" "gjorde" "gjort" ;
have_V = mkV "have" "har" "havde" "haft" "havd" "hav" ;
hente_V = irregV "hente" "hentet" "hendt" ;--
-- hete_V = irregV "hete" (variants {"het" ;-- "hette"}) "hett" ;--
-- hjelpe_V = irregV "hjelpe" "hjalp" "hjulpet" ;--
holde_V = irregV "holde" "holdt" "holdt" ;--
komme_V = irregV "komme" "kom" "kommet" ;
kunne_V = irregV "kunne" "kunne" "kunnet" ;
lade_V = irregV "lade" "lod" "ladet" ;
lægge_V = irregV "lægge" "lagde" "lagt" ;
le_V = irregV "le" "lo" "leet" ;
ligge_V = irregV "ligge" "lå" "ligget" ;
løbe_V = irregV "løbe" "løb" "løbet" ;
måtte_V = irregV "måtte" "måtte" "måttet" ;
renne_V = irregV "renne" "rant" "rent" ;--
sælge_V = irregV "sælge" "solgte" "solgt" ;
sætte_V = irregV "sætte" "satte" "sat" ;
se_V = irregV "se" "så" "set" ;
sidde_V = irregV "sidde" "sad" "siddet" ;
sige_V = irregV "sige" "sagde" "sagt" ;
skære_V = irregV "skære" "skar" "skåret" ;--
skrive_V = irregV "skrive" "skrev" "skrevet" ;
skulle_V = irregV "skulle" "skulle" "skullet" ;
slå_V = irregV "slå" "slog" "slått" ;--
sove_V = irregV "sove" "sov" "sovet" ;
spørge_V = irregV "spørge" "spurgte" "spurgt" ;
springe_V = irregV "springe" "sprang" "sprunget" ;--
stå_V = irregV "stå" "stod" "stået" ;
stikke_V = irregV "stikke" "stakk" "stukket" ;--
synge_V = irregV "synge" "sang" "sunget" ;--
tage_V = irregV "tage" "tog" "taget" ;
-- treffe_V = irregV "treffe" "traff" "truffet" ;--
-- trives_V = irregV "trives" "trivdes" (variants {"trives" ;-- "trivs"}) ;--
tælle_V = irregV "tælle" "talte" "talt" ;
vide_V = irregV "vide" "vidste" "vidst" ;
}
-- readFile "vrbs.tmp" >>= mapM_ (putStrLn . (\ (a:_:b:c:_) -> " " ++ a ++ "_V = irregV \"" ++ a ++ "\" \"" ++ b ++ "\" \"" ++ c ++ "\" ;") . words) . lines

65
lib/resource-1.4/danish/IrregDanAbs.gf Normal file
View File

@@ -0,0 +1,65 @@
abstract IrregDanAbs = Cat ** {
fun
bćre_V : V ;
bede_V : V ;
bide_V : V ;
binde_V : V ;
blive_V : V ;
brćnde_V : V ;
bringe_V : V ;
burde_V : V ;
dř_V : V ;
drage_V : V ;
drikke_V : V ;
drive_V : V ;
falde_V : V ;
fĺ_V : V ;
finde_V : V ;
flyde_V : V ;
flyve_V : V ;
forlade_V : V ;
forstĺ_V : V ;
fryse_V : V ;
gĺ_V : V ;
give_V : V ;
-- gjelde_V : V ;
gnide_V : V ;
gřre_V : V ;
have_V : V ;
hente_V : V ;
-- hete_V : V ;
-- hjelpe_V : V ;
holde_V : V ;
komme_V : V ;
kunne_V : V ;
lade_V : V ;
lćgge_V : V ;
le_V : V ;
ligge_V : V ;
lřbe_V : V ;
mĺtte_V : V ;
renne_V : V ;
sćlge_V : V ;
sćtte_V : V ;
se_V : V ;
sidde_V : V ;
sige_V : V ;
skćre_V : V ;
skrive_V : V ;
skulle_V : V ;
slĺ_V : V ;
sove_V : V ;
spřrge_V : V ;
springe_V : V ;
stĺ_V : V ;
stikke_V : V ;
synge_V : V ;
tage_V : V ;
tćlle_V : V ;
-- treffe_V : V ;
-- trives_V : V ;
vide_V : V ;
}

10
lib/resource-1.4/danish/LangDan.gf Normal file
View File

@@ -0,0 +1,10 @@
--# -path=.:../scandinavian:../abstract:../common:prelude
concrete LangDan of Lang =
GrammarDan,
LexiconDan
** {
flags startcat = Phr ; unlexer = text ; lexer = text ;
} ;

359
lib/resource-1.4/danish/LexiconDan.gf Normal file
View File

@@ -0,0 +1,359 @@
--# -path=.:../scandinavian:../common:../abstract:../../prelude
concrete LexiconDan of Lexicon = CatDan **
open Prelude, ParadigmsDan, IrregDan in {
flags startcat=Phr ; lexer=textlit ; unlexer=text ;
optimize=values ;
lin
airplane_N = mk2N "fly" "flyet" ;
answer_V2S = mkV2S (regV "svare") (mkPrep "til") ;
apartment_N = mk2N "værelse" "værelsen" ;
apple_N = mk3N "æble" "æblet" "æbler" ;
art_N = mk2N "kunst" "kunsten" ;
ask_V2Q = mkV2Q spørge_V noPrep ;
baby_N = mk2N "baby" "babyen" ; ---- babyen
bad_A = regADeg "dårlig" ; ----
bank_N = mk2N "bank" "banken" ;
beautiful_A = mk3ADeg "smuk" "smukt" "smukke" ; ----
become_VA = mkVA blive_V ;
beer_N = mk2N "øl" "ølet" ;
beg_V2V = mkV2V bede_V noPrep (mkPrep "at") ;
big_A = irregADeg "stor" "større" "størst";
bike_N = mkN "cykel" "cykeln" "cykler" "cyklerne" ; ----
bird_N = mk2N "fugl" "fuglen" ;
black_A = mk2ADeg "sort" "sort" ;
blue_A = mk2ADeg "blå" "blått";
boat_N = mk3N "båd" "båden" "både" ;
book_N = mkN "bog" "bogen" "bøger" "bøgene" ;
boot_N = mkN "støvle" "støvlen" "støvler" "støvlerne" ;
boss_N = mk2N "chef" "chefen" ;
boy_N = mk2N "dreng" "drengen" ;
bread_N = mk2N "brød" "brødet" ;
break_V2 = dirV2 (mk2V "knuse" "knuste") ;
broad_A = regADeg "bred" ;
brother_N2 = mkN2 (mk3N "broder" "brodren" "brødre") (mkPrep "til") ; ----
brown_A = regADeg "brun" ;
butter_N = mk2N "smør" "smøret" ;
buy_V2 = dirV2 (mk2V "købe" "købte") ; ----
camera_N = mk2N "kamera" "kameraen" ; ----
cap_N = mk2N "hue" "huen" ;
car_N = mk2N "bil" "bilen" ;
carpet_N = mk2N "tæppe" "tæppen" ;
cat_N = mk3N "kat" "katten" "katte" ;
ceiling_N = mk2N "loft" "loftet" ;
chair_N = mk3N "stol" "stolen" "stole" ;
cheese_N = mk2N "ost" "osten" ;
child_N = mk3N "barn" "barnet" "børn" ; ----
church_N = mk2N "kirke" "kirken" ;
city_N = mk2N "by" "byen" ;
clean_A = regADeg "ren" ;
clever_A = regADeg "flink" ;
close_V2 = dirV2 (mk2V "lukke" "lukkede") ;
coat_N = mk2N "frakke" "frakken" ;
cold_A = regADeg "kold" ;
come_V = vaereV komme_V ;
computer_N = mk2N "datamaskine" "datamaskinen" ;
country_N = mk2N "land" "landet" ;
cousin_N = mk3N "fætter" "fættren" "fættre" ; ----
cow_N = mk2N "ku" "kuen" ; ----
die_V = vaereV dø_V ;
dirty_A = regADeg "smudsig" ; ----
distance_N3 = mkN3 (regGenN "afstand" utrum) (mkPrep "fra") (mkPrep "til") ;
doctor_N = mk2N "læge" "lægen" ;
dog_N = mk2N "hund" "hunden" ;
door_N = mk2N "dør" "døren" ;
drink_V2 = dirV2 drikke_V ;
easy_A2V = mkA2V (regA "nem") (mkPrep "for") ; ----
eat_V2 = dirV2 (mk2V "spise" "spiste") ;
empty_A = mkADeg "tøm" "tømt" "tømme" "tømmere" "tømmest" ; ----
enemy_N = mk2N "fjende" "fjenden" ;
factory_N = mk2N "fabrik" "fabriken" ;
father_N2 = mkN2 ( (mk3N "far" "fadren" "fædre")) (mkPrep "til") ; ----
fear_VS = mkVS (regV "frygte") ;
find_V2 = dirV2 (irregV "finde" "fand" "fundet") ; ----
fish_N = mk2N "fisk" "fisken" ;
floor_N = mk2N "gulv" "gulvet" ;
forget_V2 = dirV2 (mkV "glemme" "glemmer" "glemmes" "glemte" "glemt" "glem") ; ----
fridge_N = mk2N "køleskab" "køleskabet" ;
friend_N = mk3N "ven" "vennen" "venner" ; ----
fruit_N = mk2N "frugt" "frugten" ;
fun_AV = mkAV (mkA "morsom" "morsomt" "morsomme") ; ----
garden_N = mk2N "have" "haven" ;
girl_N = mk2N "pige" "pigen" ;
glove_N = mk2N "handske" "handsken" ;
gold_N = mk2N "guld" "guldet" ;
good_A = mkADeg "god" "godt" "gode" "bedre" "bedst" ; ----
go_V = vaereV gå_V ;
green_A = mk3ADeg "grøn" "grønt" "grønne" ;
harbour_N = mk2N "havn" "havnen" ;
hate_V2 = dirV2 (regV "hade") ;
hat_N = mk3N "hat" "hatten" "hatte" ;
have_V2 = dirV2 have_V ;
hear_V2 = dirV2 (mk2V "høre" "hørte") ;
hill_N = mk2N "høj" "højen" ;
hope_VS = mkVS (regV "håbe") ;
horse_N = mk3N "hest" "hesten" "heste" ;
hot_A = regADeg "hed" ;
house_N = mk3N "hus" "huset" "huse" ;
important_A = regADeg "vigtig" ;
industry_N = mk2N "industri" "industrien" ;
iron_N = mk2N "jern" "jernet" ;
king_N = mk2N "konge" "kongen" ;
know_V2 = dirV2 vide_V ;
lake_N = mk2N "sø" "søen" ;
lamp_N = mk2N "lampe" "lampen" ;
learn_V2 = dirV2 (mk2V "lære" "lærte") ;
leather_N = mk2N "læder" "lædret" ;
leave_V2 = dirV2 forlade_V ;
like_V2 = mkV2 holde_V (mkPrep "af") ;
listen_V2 = dirV2 (regV "lytte") ;
live_V = mk2V "leve" "levde" ;
long_A = irregADeg "lang" "længere" "længst" ; ----
lose_V2 = dirV2 (regV "tabe") ;
love_N = mk2N "kærlighed" "kærligheden" ;
love_V2 = dirV2 (regV "elske") ;
man_N = mkN "mand" "manden" "mænd" "mændene" ;
married_A2 = mkA2 (mk2A "gift" "gift") (mkPrep "med") ;
meat_N = mk2N "kød" "kødet" ;
milk_N = mk2N "mælk" "mælken" ;
moon_N = mk2N "måne" "månen" ;
mother_N2 = mkN2 (mkN "moder" "moderen" "mødre" "mødrene") (mkPrep "til") ; ----
mountain_N = mk2N "bjerg" "bjerget" ;
music_N = mk2N "musik" "musiken" ;
narrow_A = regADeg "smal" ;
new_A = mkADeg "ny" "nytt" "nye" "nyere" "nyest" ;
newspaper_N = mk2N "avis" "avisen" ;
oil_N = mk2N "olie" "olien" ;
old_A = mkADeg "gammel" "gammelt" "gamle" "ældre" "ældst" ; ----
open_V2 = dirV2 (regV "åbne") ;
paint_V2A = mkV2A (regV "male") noPrep ;
paper_N = mk2N "papir" "papiret" ;
paris_PN = mkPN "Paris" neutrum ;
peace_N = mk2N "fred" "freden" ;
pen_N = mk2N "pen" "penen" ;
planet_N = mk2N "planet" "planeten" ;
plastic_N = mk2N "plast" "plasten" ;
play_V2 = dirV2 (mk2V "spille" "spilte") ;
policeman_N = mk2N "politibetjent" "politibetjenten" ; ----
priest_N = mk2N "præst" "præsten" ;
probable_AS = mkAS (regA "sandsynlig") ;
queen_N = mk2N "dronning" "dronningen" ;
radio_N = mk2N "radio" "radioen" ;
rain_V0 = mkV0 (regV "regne") ;
read_V2 = dirV2 (mk2V "læse" "læste") ;
red_A = regADeg "rød" ;
religion_N = mk2N "religion" "religionen" ;
restaurant_N = mk2N "restaurant" "restauranten" ;
river_N = mk2N "flod" "floden" ;
rock_N = mk2N "sten" "stenen" ;
roof_N = mk2N "tag" "taget" ;
rubber_N = mk2N "gummi" "gummien" ;
run_V = vaereV (regV "løbe") ;
say_VS = mkVS sige_V ;
school_N = mk2N "skole" "skolen" ;
science_N = mk2N "videnskab" "videnskaben" ;
sea_N = mk2N "hav" "havet" ;
see_V2 = dirV2 se_V ;
seek_V2 = mkV2 (mk2V "søge" "søgte") (mkPrep "efter") ;
sell_V3 = dirV3 sælge_V (mkPrep "til") ;
send_V3 = dirV3 (mk2V "sende" "sendte") (mkPrep "til") ;
sheep_N = mk2N "får" "fåret" ;
ship_N = mk2N "skib" "skibet" ;
shirt_N = mk2N "skjorte" "skjorten" ;
shoe_N = mk2N "sko" "skoen" ;
shop_N = mk2N "butik" "butiken" ;
short_A = regADeg "kort" ;
silver_N = mk2N "sølv" "sølvet";
sister_N = mk3N "søster" "søstren" "søstrer" ; ----
sleep_V = sove_V ;
small_A = mkADeg "lille" "lille" "små" "mindre" "mindst" ; ----
snake_N = mk2N "slange" "slangen" ;
sock_N = mk2N "sok" "sokken" ;
speak_V2 = dirV2 (regV "tale") ; ----
star_N = mk2N "stjerne" "stjernen" ;
steel_N = mk2N "stål" "stålet" ;
stone_N = mk2N "sten" "stenen" ;
stove_N = mk2N "komfur" "komfuren" ;
student_N = mk2N "student" "studenten" ;
stupid_A = mk3ADeg "dum" "dumt" "dumme" ;
sun_N = mk2N "sol" "solen" ;
switch8off_V2 = dirV2 (partV (regV "lukke") "for") ;
switch8on_V2 = dirV2 (partV (regV "lukke") "op") ;
table_N = mk2N "bord" "bordet" ;
talk_V3 = mkV3 (regV "tale") (mkPrep "til") (mkPrep "om") ;
teacher_N = mkN "lærer" "læreren" "lærere" "lærerne" ;
teach_V2 = dirV2 (mk2V "undervise" "underviste") ;
television_N = mk2N "fjernsyn" "fjernsynet" ;
thick_A = mk3ADeg "tyk" "tykt" "tykke" ;
thin_A = mk2ADeg "tynd" "tyndt" ; ----
train_N = mk2N "tog" "toget" ;
travel_V = vaereV (mk2V "rejse" "rejste") ;
tree_N = mkN "træ" "træet" "træer" "træene" ; ----
---- trousers_N = regGenN "trousers" ; ---- pl t !
ugly_A = mk3ADeg "grim" "grimt" "grimme" ;
understand_V2 = dirV2 (irregV "forstå" "forstod" "forstått") ;
university_N = mk2N "universitet" "universitetet" ;
village_N = mk2N "landsby" "landsbyen" ;
wait_V2 = mkV2 (regV "vente") (mkPrep "på") ;
walk_V = vaereV gå_V ;
warm_A = regADeg "varm" ;
war_N = mk2N "krig" "krigen" ;
watch_V2 = mkV2 se_V (mkPrep "på") ;
water_N = mk2N "vand" "vandet" ;
white_A = regADeg "hvid" ;
window_N = mkN "vindue" "vinduet" "vinduer" "vinduene" ; ---- er?
wine_N = mk2N "vin" "vinen" ;
win_V2 = dirV2 (irregV "vinde" "vand" "vundet") ;
woman_N = mk2N "kvinde" "kvinden" ;
wonder_VQ = mkVQ (depV (regV "undre")) ;
wood_N = mkN "træ" "træet" "træer" "træene" ; ----
write_V2 = dirV2 (irregV "skrive" "skrev" "skrevet") ;
yellow_A = regADeg "gul" ;
young_A = irregADeg "ung" "yngre" "yngst" ; ----
do_V2 = dirV2 gøre_V ;
now_Adv = mkAdv "nu" ;
already_Adv = mkAdv "allerede" ;
song_N = mk2N "sang" "sangen" ;
add_V3 = mkV3 (regV "tilføje") noPrep (mkPrep "til") ; ----
number_N = mk2N "nummer" "numret" ; ----
put_V2 = dirV2 sætte_V ;
stop_V = vaereV (regV "standse") ;
jump_V = regV "hoppe" ;
left_Ord = {s = "venstre" ; isDet = True} ;
right_Ord = {s = "højre" ; isDet = True} ;
far_Adv = mkAdv "fjern" ;
correct_A = regA "rigtig" ;
dry_A = mk3ADeg "tør" "tørt" "tørre" ;
dull_A = regA "sløv" ;
full_A = regA "fuld" ;
heavy_A = irregADeg "tung" "tyngre" "tyngst" ;
near_A = mkADeg "nære" "nære" "nære" "nærmere" "nærmest" ;
rotten_A = mk3ADeg "rådden" "råddent" "rådne" ; ----
round_A = regA "rund" ;
sharp_A = regA "skarp" ;
smooth_A = regA "jævn" ;
straight_A = mk3ADeg "ret" "rett" "rette" ; ----
wet_A = regA "våd" ;
wide_A = regA "bred" ;
animal_N = mk2N "dyr" "dyret" ;
ashes_N = mk2N "aske" "asken" ;
back_N = mk2N "ryg" "ryggen" ; ----
bark_N = mk2N "bark" "barken" ;
belly_N = mk2N "mave" "maven" ;
blood_N = mk2N "blod" "blodet" ;
bone_N = mk2N "ben" "benet" ;
breast_N = mk2N "bryst" "brystet" ;
cloud_N = mk2N "sky" "skyen" ;
day_N = mk3N "dag" "dagen" "dage" ;
dust_N = mk2N "støv" "støvet" ;
ear_N = mk3N "øre" "øret" "ører" ;
earth_N = mk2N "jord" "jorden" ;
egg_N = mk2N "æg" "æget" ;
eye_N = mk3N "øje" "øjet" "øjne" ;
fat_N = mk2N "fedt" "fedtet" ;
feather_N = mk2N "fjer" "fjeren" ;
fingernail_N = mk2N "negl" "neglen" ;
fire_N = mk2N "ild" "ilden" ;
flower_N = mk2N "blomst" "blomsten" ;
fog_N = mk2N "tåge" "tågen" ;
foot_N = mk2N "fod" "føder" ; ----
forest_N = mk2N "skov" "skoven" ;
grass_N = mk2N "græs" "græset" ;
guts_N = mk2N "tarm" "tarmen" ; ---- indvolde
hair_N = mk2N "hår" "håret" ;
hand_N = mk2N "hånd" "hånden" ;
head_N = mk2N "hoved" "hovedet" ;
heart_N = mk3N "hjerte" "hjertet" "hjerter" ;
horn_N = mk2N "horn" "hornet" ;
husband_N = mk2N "ægtefælle" "ægtefællen" ; ----
ice_N = mk2N "is" "isen" ;
knee_N = mkN "knæ" "knæt" "knær" "knæne" ; ----
leaf_N = mk2N "løv" "løvet" ;
leg_N = mk2N "ben" "benet" ;
liver_N = mkN "lever" "leveren" "levrer" "levrene" ; ----
louse_N = mk3N "lus" "lusen" "lus" ;
mouth_N = mk2N "mund" "munden" ;
name_N = mk2N "navn" "navnet" ;
neck_N = mk2N "hals" "halsen" ;
night_N = mk3N "nat" "natten" "nætter" ; ----
nose_N = mk2N "næse" "næsen" ;
person_N = mk2N "person" "personen" ;
rain_N = mk2N "regn" "regnet" ;
road_N = mk2N "vej" "vejen" ;
root_N = mk3N "rod" "roden" "røder" ; ----
rope_N = mk2N "reb" "rebet" ;
salt_N = mk2N "salt" "saltet" ;
sand_N = mk2N "sand" "sanden" ;
seed_N = mk2N "frø" "frøet" ;
skin_N = mk2N "skind" "skindet" ;
sky_N = mk3N "himmel" "himlen" "himler" ; ----
smoke_N = mk2N "røg" "røgen" ;
snow_N = mk2N "snø" "snøen" ;
stick_N = mk2N "pind" "pinden" ;
tail_N = mk2N "hale" "halen" ;
tongue_N = mk2N "tunge" "tungen" ;
tooth_N = mkN "tand" "tanden" "tænder" "tændene" ; ----
wife_N = mk2N "kone" "konen" ;
wind_N = mk2N "vind" "vinden" ;
wing_N = mk2N "vinge" "vingen" ;
worm_N = mk2N "orm" "ormen" ;
year_N = mk2N "år" "året" ;
bite_V2 = dirV2 bide_V ;
blow_V = mk2V "blæse" "blæste" ;
burn_V = brænde_V ;
count_V2 = dirV2 tælle_V ;
cut_V2 = dirV2 (skære_V) ;
dig_V = mk2V "grave" "gravde" ;
fall_V = vaereV falde_V ;
fear_V2 = dirV2 (regV "frygte") ;
fight_V2 = dirV2 (regV "kæmpe") ;
float_V = flyde_V ;
flow_V = regV "strømme" ;
fly_V = vaereV flyve_V ;
freeze_V = fryse_V ;
give_V3 = dirV3 give_V (mkPrep "til");
hit_V2 = dirV2 (slå_V) ;
hold_V2 = dirV2 (holde_V) ;
hunt_V2 = dirV2 (regV "jage") ;
kill_V2 = dirV2 (regV "dræbe") ;
laugh_V = le_V ;
lie_V = ligge_V ;
play_V = regV "spille" ;
pull_V2 = dirV2 (regV "trække") ;
push_V2 = dirV2 (regV "skubbe") ;
rub_V2 = dirV2 (gnide_V) ;
scratch_V2 = dirV2 (regV "kradse") ;
sew_V = mk2V "sy" "sydde" ;
sing_V = synge_V ;
sit_V = sidde_V ;
smell_V = regV "lugte" ;
spit_V = regV "spytte" ;
split_V2 = dirV2 (regV "splitte") ; ----
squeeze_V2 = dirV2 (regV "presse") ;
stab_V2 = dirV2 (stikke_V) ;
stand_V = vaereV stå_V ;
suck_V2 = dirV2 (regV "sutte") ; ----
swell_V = regV "svulme" ;
swim_V = regV "svømme" ;
think_V = mk2V "tænke" "tænkte" ; ----
throw_V2 = dirV2 (regV "kaste") ;
tie_V2 = dirV2 binde_V ;
turn_V = regV "dreje" ;
vomit_V = partV (regV "kaste") "op" ;
wash_V2 = dirV2 (regV "vaske") ;
wipe_V2 = dirV2 (regV "viske") ;
breathe_V = regV "ånde" ;
grammar_N = regN "grammatik" ;
language_N = mk2N "sprog" "sproget" ;
rule_N = mkN "regel" "regeln" "regler" "reglerne" ;
} ;

2
lib/resource-1.4/danish/MathDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete MathDan of Math = CatDan ** MathScand with
(ResScand = ResDan) ;

164
lib/resource-1.4/danish/MorphoDan.gf Normal file
View File

@@ -0,0 +1,164 @@
--1 A Simple Danish Resource Morphology
--
-- Aarne Ranta 2002
--
-- This resource morphology contains definitions needed in the resource
-- syntax. It moreover contains copies of the most usual inflectional patterns
-- as defined in functional morphology (in the Haskell file $RulesSw.hs$).
--
-- We use the parameter types and word classes defined for morphology.
resource MorphoDan = CommonScand, ResDan ** open Prelude, Predef in {
oper
-- type synonyms
Subst : Type = {s : Number => Species => Case => Str} ;
Adj = Adjective ;
-- nouns
mkSubstantive : (_,_,_,_ : Str) -> Subst =
\dreng, drengen, drenger, drengene ->
{s = nounForms dreng drengen drenger drengene} ;
extNGen : Str -> Gender = \s -> case last s of {
"n" => Utr ;
_ => Neutr
} ;
nDreng : Str -> Subst = \dreng ->
mkSubstantive dreng (dreng + "en") (dreng + "e") (dreng + "ene") **
{h1 = Utr} ;
nBil : Str -> Subst = \bil ->
mkSubstantive bil (bil + "en") (bil + "er") (bil + "erne") **
{h1 = Utr} ;
nUge : Str -> Subst = \uge ->
mkSubstantive uge (uge + "n") (uge + "r") (uge + "rne") **
{h1 = Utr} ;
nHus : Str -> Subst = \hus ->
mkSubstantive hus (hus + "et") hus (hus + "ene") **
{h1 = Neutr} ;
-- adjectives
mkAdject : (_,_,_,_,_ : Str) -> Adj =
\stor,stort,store,storre,storst -> {s = table {
AF (APosit (Strong SgUtr )) c => mkCase c stor ;
AF (APosit (Strong SgNeutr)) c => mkCase c stort ;
AF (APosit _) c => mkCase c store ;
AF ACompar c => mkCase c storre ;
AF (ASuperl SupStrong) c => mkCase c storst ;
AF (ASuperl SupWeak) c => mkCase c (storst + "e")
}
} ;
aRod : Str -> Adj = \rod ->
mkAdject rod (rod + "t") (rod + "e") (rod + "ere") (rod + "est") ;
aAbstrakt : Str -> Adj = \abstrakt ->
mkAdject abstrakt abstrakt (abstrakt + "e") (abstrakt + "ere") (abstrakt + "est") ;
aRask : Str -> Adj = \rask ->
mkAdject rask rask (rask + "e") (rask + "ere") (rask + "est") ;
-- verbs
Verbum : Type = {s : VForm => Str} ;
mkVerb6 : (_,_,_,_,_,_ : Str) -> Verbum =
\spise,spiser,spises,spiste,spist,spis -> {s = table {
VI (VInfin v) => mkVoice v spise ;
VF (VPres Act) => spiser ;
VF (VPres Pass) => spises ;
VF (VPret v) => mkVoice v spiste ; --# notpresent
VI (VSupin v) => mkVoice v spist ; --# notpresent
VI (VPtPret (Strong (SgUtr | SgNeutr)) c) => mkCase c spist ;
VI (VPtPret _ c) => mkCase c (spist + "e") ;
VF (VImper v) => mkVoice v spis
}
} ;
irregVerb : (drikke,drakk,drukket : Str) -> Verbum =
\drikke,drakk,drukket ->
let
drikk = init drikke ;
drikker = case last (init drikke) of {
"r" => drikk ;
_ => drikke + "r"
}
in
mkVerb6 drikke drikker (drikke + "s") drakk drukket (mkImper drikk) ;
regVerb : Str -> Str -> Verbum = \spise, spiste ->
let
spis = init spise ;
te = Predef.dp 2 spiste
in
case te of {
"te" => vSpis spis ;
"de" => case last spise of {
"e" => vHusk spis ;
_ => vBo spise
} ;
_ => vHusk spis
} ;
vHusk : Str -> Verbum = \husk ->
mkVerb6 (husk + "e") (husk + "er") (husk + "es") (husk + "ede") (husk + "et")
(mkImper husk) ;
vSpis : Str -> Verbum = \spis ->
mkVerb6 (spis + "e") (spis + "er") (spis + "es") (spis + "te") (spis + "t")
(mkImper spis) ;
vBo : Str -> Verbum = \bo ->
mkVerb6 bo (bo + "r") (bo + "es") (bo + "ede") (bo + "et") (mkImper bo) ;
-- Remove consonant duplication: "passe - pas"
mkImper : Str -> Str = \s ->
if_then_Str (pbool2bool (Predef.eqStr (last s) (last (init s)))) (init s) s ;
-- For $Numeral$.
param DForm = ental | ton | tiotal ;
oper
LinDigit = {s : DForm => CardOrd => Str} ;
cardOrd : Str -> Str -> CardOrd => Str = \tre,tredje ->
table {
NCard _ => tre ;
NOrd a => tredje ---- a
} ;
cardReg : Str -> CardOrd => Str = \syv ->
cardOrd syv (syv + case last syv of {
"n" => "de" ;
"e" => "nde" ;
_ => "ende"
}) ;
mkTal : (x1,_,_,_,x5 : Str) -> LinDigit =
\två, tolv, tjugo, andra, tyvende ->
{s = table {
ental => cardOrd två andra ;
ton => cardReg tolv ;
tiotal => cardOrd tjugo tyvende
}
} ;
numPl : (CardOrd => Str) -> {s : CardOrd => Str ; n : Number} = \n ->
{s = n ; n = Pl} ;
invNum : CardOrd = NCard Neutr ;
}

2
lib/resource-1.4/danish/NounDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete NounDan of Noun = CatDan ** NounScand with
(ResScand = ResDan) ;

83
lib/resource-1.4/danish/NumeralDan.gf Normal file
View File

@@ -0,0 +1,83 @@
concrete NumeralDan of Numeral = CatDan ** open MorphoDan in {
-- AR 12/10/2002 following www.geocities.com/tsca.geo/dansk/dknummer.html
lincat
Digit = {s : DForm => CardOrd => Str} ;
Sub10 = {s : DForm => CardOrd => Str ; n : Number} ;
Sub100, Sub1000, Sub1000000 =
{s : CardOrd => Str ; n : Number} ;
lin num x = x ;
lin n2 = mkTal "to" "tolv" "tyve" "anden" "tyvende" ;
lin n3 = mkTal "tre" "tretten" "tredive" "tredje" "tredivte" ;
lin n4 = mkTal "fire" "fjorten" "fyrre" "fjerde" "fyrretyvende" ;
lin n5 = mkTal "fem" "femten" "halvtreds" "femte" "halvtredsindstyvende" ;
lin n6 = mkTal "seks" "seksten" "tres" "sjette" "tredsindstyvende" ;
lin n7 = mkTal "syv" "sytten" "halvfjerds" "syvende""halvfjerdsindstyvende" ;
lin n8 = mkTal "otte" "atten" "firs" "ottende""firsindstyvende" ;
lin n9 = mkTal "ni" "nitten" "halvfems" "niende" "halvfemsindstyvende" ;
pot01 = {
s = \\f => table {
NCard g => case g of {Neutr => "et" ; _ => "en"} ;
_ => "første"
} ;
n = Sg
} ;
pot0 d = {s = \\f,g => d.s ! f ! g ; n = Pl} ;
pot110 = numPl (cardReg "ti") ;
pot111 = numPl (cardOrd "elleve" "elvte") ;
pot1to19 d = numPl (d.s ! ton) ;
pot0as1 n = {s = n.s ! ental ; n = n.n} ;
pot1 d = numPl (d.s ! tiotal) ;
pot1plus d e = {
s = \\g => e.s ! ental ! invNum ++ "og" ++ d.s ! tiotal ! g ; n = Pl} ;
pot1as2 n = n ;
pot2 d = numPl (\\_ => d.s ! ental ! invNum ++ "hundrede") ;
pot2plus d e =
{s = \\g => d.s ! ental ! invNum ++ "hundrede" ++ "og" ++ e.s ! g ; n = Pl} ;
pot2as3 n = n ;
pot3 n = numPl (\\g => n.s ! invNum ++ cardOrd "tusind" "tusinde" ! g) ;
pot3plus n m = {s = \\g => n.s ! invNum ++ "tusind" ++ "og" ++ m.s ! g ; n =Pl} ;
lincat
Dig = TDigit ;
lin
IDig d = d ;
IIDig d i = {
s = \\o => d.s ! NCard neutrum ++ i.s ! o ;
n = Pl
} ;
D_0 = mkDig "0" ;
D_1 = mk3Dig "1" "1:e" Sg ;
D_2 = mk2Dig "2" "2:e" ;
D_3 = mkDig "3" ;
D_4 = mkDig "4" ;
D_5 = mkDig "5" ;
D_6 = mkDig "6" ;
D_7 = mkDig "7" ;
D_8 = mkDig "8" ;
D_9 = mkDig "9" ;
oper
mk2Dig : Str -> Str -> TDigit = \c,o -> mk3Dig c o Pl ;
mkDig : Str -> TDigit = \c -> mk2Dig c (c + ":e") ;
mk3Dig : Str -> Str -> Number -> TDigit = \c,o,n -> {
s = table {NCard _ => c ; NOrd _ => o} ;
n = n
} ;
TDigit = {
n : Number ;
s : CardOrd => Str
} ;
}

517
lib/resource-1.4/danish/ParadigmsDan.gf Normal file
View File

@@ -0,0 +1,517 @@
--# -path=.:../scandinavian:../common:../abstract:../../prelude
--1 Danish Lexical Paradigms
--
-- Aarne Ranta 2005 - 2006
--
-- This is an API for the user of the resource grammar
-- for adding lexical items. It gives functions for forming
-- expressions of open categories: nouns, adjectives, verbs.
--
-- Closed categories (determiners, pronouns, conjunctions) are
-- accessed through the resource syntax API, $Structural.gf$.
--
-- The main difference with $MorphoDan.gf$ is that the types
-- referred to are compiled resource grammar types. We have moreover
-- had the design principle of always having existing forms, rather
-- than stems, as string arguments of the paradigms.
--
-- The structure of functions for each word class $C$ is the following:
-- first we give a handful of patterns that aim to cover all
-- regular cases. Then we give a worst-case function $mkC$, which serves as an
-- escape to construct the most irregular words of type $C$.
-- However, this function should only seldom be needed: we have a
-- separate module [``IrregDan`` ../../danish/IrregDan.gf],
-- which haves a list of irregular verbs.
resource ParadigmsDan =
open
(Predef=Predef),
Prelude,
CommonScand,
ResDan,
MorphoDan,
CatDan in {
--2 Parameters
--
-- To abstract over gender names, we define the following identifiers.
oper
Gender : Type ;
utrum : Gender ;
neutrum : Gender ;
-- To abstract over number names, we define the following.
Number : Type ;
singular : Number ;
plural : Number ;
-- To abstract over case names, we define the following.
Case : Type ;
nominative : Case ;
genitive : Case ;
-- Prepositions used in many-argument functions are just strings.
mkPrep : Str -> Prep ;
noPrep : Prep ; -- empty string
--2 Nouns
mkN : overload {
-- The regular function takes the singular indefinite form
-- and computes the other forms and the gender by a heuristic.
-- The heuristic is that all nouns are $utrum$ with the
-- plural ending "er" or "r".
mkN : (bil : Str) -> N ;
-- Giving gender manually makes the heuristic more reliable.
mkN : (hus : Str) -> Gender -> N ;
-- This function takes the singular indefinite and definite forms; the
-- gender is computed from the definite form.
mkN : (bil,bilen : Str) -> N ;
-- This function takes the singular indefinite and definite and the plural
-- indefinite
mkN : (bil,bilen,biler : Str) -> N ;
-- Worst case: give all four forms. The gender is computed from the
-- last letter of the second form (if "n", then $utrum$, otherwise $neutrum$).
mkN : (dreng,drengen,drenge,drengene : Str) -> N ;
} ;
--3 Compound nouns
--
-- All the functions above work quite as well to form compound nouns,
-- such as "fodbold".
--3 Relational nouns
--
-- Relational nouns ("datter til x") need a preposition.
mkN2 : N -> Prep -> N2 ;
-- The most common preposition is "af", and the following is a
-- shortcut for regular relational nouns with "af".
regN2 : Str -> Gender -> N2 ;
-- Use the function $mkPrep$ or see the section on prepositions below to
-- form other prepositions.
--
-- Three-place relational nouns ("forbindelse fra x til y")
-- need two prepositions.
mkN3 : N -> Prep -> Prep -> N3 ;
--3 Relational common noun phrases
--
-- In some cases, you may want to make a complex $CN$ into a
-- relational noun (e.g. "tidligere kone til"). However, $N2$ and
-- $N3$ are purely lexical categories. But you can use the $AdvCN$
-- and $PrepNP$ constructions to build phrases like this.
--
--3 Proper names and noun phrases
--
-- Proper names, with a regular genitive, are formed as follows
mkPN : overload {
mkPN : Str -> PN ; -- utrum
mkPN : Str -> Gender -> PN ;
mkPN : N -> PN ;
} ;
--2 Adjectives
-- The regular pattern works for many adjectives, e.g. those ending
-- with "ig". Two, five, or at worst five forms are sometimes needed.
mkA : overload {
mkA : (fin : Str) -> A ;
mkA : (fin,fint : Str) -> A ;
mkA : (galen,galet,galne : Str) -> A ;
mkA : (stor,stort,store,storre,storst : Str) -> A ;
-- If comparison is formed by "mer", "mest", as in general for
-- long adjective, the following pattern is used:
mkA : A -> A ; -- -/mer/mest norsk
} ;
--3 Two-place adjectives
--
-- Two-place adjectives need a preposition for their second argument.
mkA2 : A -> Prep -> A2 ;
--2 Adverbs
-- Adverbs are not inflected. Most lexical ones have position
-- after the verb. Some can be close to the verb like the negation
-- "ikke" (e.g. "altid").
mkAdv : Str -> Adv ;
mkAdV : Str -> AdV ;
-- Adverbs modifying adjectives and sentences can also be formed.
mkAdA : Str -> AdA ;
--2 Verbs
--
mkV : overload {
-- The 'regular verb' function is the first conjugation.
mkV : (snakke : Str) -> V ;
-- The almost regular verb function needs the infinitive and the preteritum.
mkV : (leve,levde : Str) -> V ;
-- There is an extensive list of irregular verbs in the module $IrregDan$.
-- In practice, it is enough to give three forms, as in school books.
mkV : (drikke, drakk, drukket : Str) -> V ;
-- The worst case needs six forms.
mkV : (spise,spiser,spises,spiste,spist,spis : Str) -> V ;
--3 Verbs with a particle.
--
-- The particle, such as in "lukke op", is given as a string.
mkV : V -> Str -> V ;
} ;
--3 Verbs with 'være' as auxiliary
--
-- By default, the auxiliary is "have". This function changes it to "være".
vaereV : V -> V ;
--3 Deponent verbs
--
-- Some words are used in passive forms only, e.g. "undres", some as
-- reflexive e.g. "forestille sig".
depV : V -> V ;
reflV : V -> V ;
--3 Two-place verbs
--
-- Two-place verbs need a preposition, except the special case with direct object.
-- (transitive verbs). Notice that, if a particle is needed, it comes from the $V$.
mkV2 : overload {
mkV2 : Str -> V2 ;
mkV2 : V -> V2 ;
mkV2 : V -> Prep -> V2 ;
} ;
--3 Three-place verbs
--
-- Three-place (ditransitive) verbs need two prepositions, of which
-- the first one or both can be absent.
mkV3 : V -> Prep -> Prep -> V3 ; -- snakke, med, om
dirV3 : V -> Prep -> V3 ; -- give,_,til
dirdirV3 : V -> V3 ; -- give,_,_
--3 Other complement patterns
--
-- Verbs and adjectives can take complements such as sentences,
-- questions, verb phrases, and adjectives.
mkV0 : V -> V0 ;
mkVS : V -> VS ;
mkV2S : V -> Prep -> V2S ;
mkVV : V -> VV ;
mkV2V : V -> Prep -> Prep -> V2V ;
mkVA : V -> VA ;
mkV2A : V -> Prep -> V2A ;
mkVQ : V -> VQ ;
mkV2Q : V -> Prep -> V2Q ;
mkAS : A -> AS ;
mkA2S : A -> Prep -> A2S ;
mkAV : A -> AV ;
mkA2V : A -> Prep -> A2V ;
-- Notice: categories $AS, A2S, AV, A2V$ are just $A$,
-- and the second argument is given as an adverb..
-- $V0$ is just $V$.
V0 : Type ;
AS, A2S, AV, A2V : Type ;
--.
--2 Definitions of the paradigms
--
-- The definitions should not bother the user of the API. So they are
-- hidden from the document.
Gender = MorphoDan.Gender ;
Number = MorphoDan.Number ;
Case = MorphoDan.Case ;
utrum = Utr ;
neutrum = Neutr ;
singular = Sg ;
plural = Pl ;
nominative = Nom ;
genitive = Gen ;
Preposition : Type = Str ; -- obsolete
mkPreposition : Str -> Prep ; -- obsolete
mkPreposition = mkPrep ;
mkPrep p = {s = p ; lock_Prep = <>} ;
noPrep = mkPrep [] ;
mk4N x y z u = mkSubstantive x y z u ** {g = extNGen y ; lock_N = <>} ;
regN x = regGenN x Utr ;
regGenN x g = case last x of {
"e" => case g of {
Utr => mk4N x (x + "n") (x + "r") (x + "rne") ;
Neutr => mk4N x (x + "t") (x + "r") (init x + "ene")
} ;
_ => case g of {
Utr => mk4N x (x + "en") (x + "er") (x + "erne") ;
Neutr => mk4N x (x + "et") (x + "") (x + "ene")
}
} ;
mk2N x y = case last y of {
"n" => mk3N x y (init y + "r") ;
_ => mk3N x y x
} ;
mk3N x y z = let u = ifTok Str x z "ene" "ne" in mk4N x y z (z + u) ;
mkN2 = \n,p -> n ** {lock_N2 = <> ; c2 = p.s} ;
regN2 n g = mkN2 (regGenN n g) (mkPreposition "av") ;
mkN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = p.s ; c3 = q.s} ;
mk2PN n g = {s = \\c => mkCase c n ; g = g} ** {lock_PN = <>} ;
regPN n = mk2PN n utrum ;
nounPN n = {s = n.s ! singular ! Indef ; g = n.g ; lock_PN = <>} ;
-- To form a noun phrase that can also be plural and have an irregular
-- genitive, you can use the worst-case function.
makeNP : Str -> Str -> Number -> Gender -> NP ;
makeNP x y n g =
{s = table {NPPoss _ => x ; _ => y} ; a = agrP3 g n ;
lock_NP = <>} ;
mk3A = mk3ADeg ;
mk2A a b = mk3A a b (a + "e") ;
regA a = (regADeg a) ** {lock_A = <>} ;
mkA2 a p = a ** {c2 = p.s ; lock_A2 = <>} ;
mkADeg a b c d e = mkAdject a b c d e ** {isComp = False ; lock_A = <>} ;
regADeg a = case Predef.dp 2 a of {
"sk" => aRask a ;
_ => case last a of {
"t" => aAbstrakt a ;
_ => aRod a
}} ** {isComp = False ; lock_A = <>} ;
irregADeg a b c = mkAdject a (a + "t") (a + "e") b c **
{isComp = False ; lock_A = <>} ;
mk3ADeg a b c = mkAdject a b c (c + "re") (c + "st") **
{isComp = False ; lock_A = <>} ;
mk2ADeg a b = mkAdject a b (a + "e") (a + "ere") (a + "est") **
{isComp = False ; lock_A = <>} ;
compoundA adj = {s = adj.s ; isComp = True ; lock_A = <>} ;
mkAdv x = ss x ** {lock_Adv = <>} ;
mkAdV x = ss x ** {lock_AdV = <>} ;
mkAdA x = ss x ** {lock_AdA = <>} ;
mk6V a b c d e f = mkVerb6 a b c d e f **
{part = [] ; vtype = VAct ; lock_V = <> ; isVaere = False} ;
regV a = case last a of {
"e" => vHusk (init a) ;
_ => vBo a
} ** {part = [] ; vtype = VAct ; isVaere = False ; lock_V = <>} ;
mk2V a b = regVerb a b **
{part = [] ; vtype = VAct ; isVaere = False ; lock_V = <>} ;
irregV =
\drikke,drakk,drukket ->
let
drikk = case last drikke of {
"e" => init drikke ;
_ => drikke
} ;
drikker = case last (init drikke) of {
"r" => init drikke ;
_ => drikke + "r"
}
in
mk6V drikke drikker (drikke + "s") drakk drukket (mkImper drikk) ;
vaereV v = {
s = v.s ;
part = [] ;
vtype = v.vtype ;
isVaere = True ;
lock_V = <>
} ;
partV v p = {
s = v.s ;
part = p ;
vtype = v.vtype ;
isVaere = v.isVaere ;
lock_V = <>
} ;
depV v = {
s = v.s ; part = v.part ; vtype = VPass ; isVaere = False ; lock_V = <>
} ;
reflV v = {
s = v.s ; part = v.part ; vtype = VRefl ; isVaere = False ; lock_V = <>
} ;
mk2V2 v p = v ** {c2 = p.s ; lock_V2 = <>} ;
dirV2 v = mk2V2 v (mkPrep []) ;
mkV3 v p q = v ** {c2 = p.s ; c3 = q.s ; lock_V3 = <>} ;
dirV3 v p = mkV3 v noPrep p ;
dirdirV3 v = dirV3 v noPrep ;
mkV0 v = v ** {lock_V0 = <>} ;
mkVS v = v ** {lock_VS = <>} ;
mkV2S v p = mk2V2 v p ** {lock_V2S = <>} ;
mkVV v = v ** {c2 = "å" ; lock_VV = <>} ;
mkV2V v p t = mk2V2 v p ** {c3 = "att" ; lock_V2V = <>} ;
mkVA v = v ** {lock_VA = <>} ;
mkV2A v p = mk2V2 v p ** {lock_V2A = <>} ;
mkVQ v = v ** {lock_VQ = <>} ;
mkV2Q v p = mk2V2 v p ** {lock_V2Q = <>} ;
mkAS v = v ** {lock_A = <>} ;
mkA2S v p = mkA2 v p ** {lock_A = <>} ;
mkAV v = v ** {lock_A = <>} ;
mkA2V v p = mkA2 v p ** {lock_A = <>} ;
V0 : Type = V ;
AS, A2S, AV : Type = A ;
A2V : Type = A2 ;
---------------
mkN = overload {
mkN : Str -> N = regN ;
mkN : Str -> Gender -> N = regGenN ;
mkN : (bil,bilen : Str) -> N = mk2N ;
mkN : (bil,bilen,biler : Str) -> N = mk3N ;
mkN : (dreng,drengen,drenge,drengene : Str) -> N = mk4N ;
} ;
regN : Str -> N ;
regGenN : Str -> Gender -> N ;
mk2N : (bil,bilen : Str) -> N ;
mk3N : (bil,bilen,biler : Str) -> N ;
mk4N : (dreng,drengen,drenge,drengene : Str) -> N ;
mkPN = overload {
mkPN : Str -> PN = regPN ; -- masculine
mkPN : Str -> Gender -> PN = mk2PN ;
mkPN : N -> PN = nounPN ;
} ;
regPN : Str -> PN ; -- utrum
mk2PN : Str -> Gender -> PN ;
nounPN : N -> PN ;
mkA = overload {
mkA : (fin : Str) -> A = regADeg ;
mkA : (fin,fint : Str) -> A = mk2ADeg ;
mkA : (galen,galet,galne : Str) -> A = mk3ADeg ;
mkA : (stor,stort,store,storre,storst : Str) -> A = mkADeg ;
mkA : A -> A = compoundA ; -- -/mer/mest norsk
} ;
mk3A : (galen,galet,galne : Str) -> A ;
regA : Str -> A ;
mk2A : (stor,stort : Str) -> A ;
mkADeg : (stor,stort,store,storre,storst : Str) -> A ;
regADeg : Str -> A ;
irregADeg : (tung,tyngre,tyngst : Str) -> A ;
mk3ADeg : (galen,galet,galne : Str) -> A ;
mk2ADeg : (bred,bredt : Str) -> A ;
compoundA : A -> A ; -- -/mer/mest norsk
mkV = overload {
mkV : (snakke : Str) -> V = regV ;
mkV : (leve,levde : Str) -> V = mk2V ;
mkV : (drikke, drakk, drukket : Str) -> V = irregV ;
mkV : (spise,spiser,spises,spiste,spist,spis : Str) -> V = mk6V ;
mkV : V -> Str -> V = partV ;
} ;
regV : (snakke : Str) -> V ;
mk2V : (leve,levde : Str) -> V ;
irregV : (drikke, drakk, drukket : Str) -> V ;
mk6V : (spise,spiser,spises,spiste,spist,spis : Str) -> V ;
partV : V -> Str -> V ;
mkV2 = overload {
mkV2 : Str -> V2 = \s -> dirV2 (regV s) ;
mkV2 : V -> V2 = dirV2 ;
mkV2 : V -> Prep -> V2 = mk2V2 ;
} ;
mk2V2 : V -> Prep -> V2 ;
dirV2 : V -> V2 ;
} ;

2
lib/resource-1.4/danish/PhraseDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete PhraseDan of Phrase = CatDan ** PhraseScand with
(ResScand = ResDan) ;

2
lib/resource-1.4/danish/QuestionDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete QuestionDan of Question = CatDan ** QuestionScand with
(ResScand = ResDan) ;

2
lib/resource-1.4/danish/RelativeDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete RelativeDan of Relative = CatDan ** RelativeScand with
(ResScand = ResDan) ;

3
lib/resource-1.4/danish/ResDan.gf Normal file
View File

@@ -0,0 +1,3 @@
instance ResDan of ResScand = DiffDan ** open CommonScand, Prelude in {
} ;

2
lib/resource-1.4/danish/SentenceDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete SentenceDan of Sentence = CatDan ** SentenceScand with
(ResScand = ResDan) ;

128
lib/resource-1.4/danish/StructuralDan.gf Normal file
View File

@@ -0,0 +1,128 @@
concrete StructuralDan of Structural = CatDan **
open MorphoDan, ParadigmsDan, Prelude in {
flags optimize=all ;
lin
above_Prep = ss "ovenfor" ;
after_Prep = ss "efter" ;
by8agent_Prep = ss "af" ;
all_Predet = {s = gennumForms "all" "alt" "alle"} ;
almost_AdA, almost_AdN = ss "næsten" ;
although_Subj = ss ["selv om"] ;
always_AdV = ss "altid" ;
and_Conj = {s1 = [] ; s2 = "og" ; n = Pl} ;
because_Subj = ss "fordi" ;
before_Prep = ss "før" ;
behind_Prep = ss "bag" ;
between_Prep = ss "mellem" ;
both7and_DConj = sd2 "både" "og" ** {n = Pl} ;
but_PConj = ss "men" ;
by8means_Prep = ss "med" ;
can8know_VV, can_VV =
mkV "kunne" "kan" "kan" "kunne" "kunnet" "kan" **
{c2 = [] ; lock_VV = <>} ;
during_Prep = ss "under" ;
either7or_DConj = sd2 "enten" "eller" ** {n = Sg} ;
everybody_NP = regNP "alle" "alles" Plg ;
every_Det = {s = \\_,_ => "hver" ; n = Sg ; det = DDef Indef} ;
everything_NP = regNP "alt" "alts" SgNeutr ;
everywhere_Adv = ss "overalt" ;
few_Det = {s = \\_,_ => "få" ; n = Pl ; det = DDef Indef} ;
--- first_Ord = {s = "første" ; isDet = True} ;
for_Prep = ss "for" ;
from_Prep = ss "fra" ;
he_Pron = MorphoDan.mkNP "han" "ham" "hans" "hans" "hans" SgUtr P3 ;
here_Adv = ss "her" ;
here7to_Adv = ss "hit" ;
here7from_Adv = ss "herfra" ;
how_IAdv = ss "hvor" ;
how8many_IDet = {s = \\_ => ["hur mange"] ; n = Pl ; det = DDef Indef} ;
if_Subj = ss "hvis" ;
in8front_Prep = ss "foran" ;
i_Pron =
MorphoDan.mkNP "jeg" "mig" "min" "mit" "mine" SgUtr P1 ;
in_Prep = ss "i" ;
it_Pron = MorphoDan.regNP "det" "dets" SgNeutr ;
less_CAdv = ss "mindre" ;
many_Det = {s = \\_,_ => "mange" ; n = Pl ; det = DDef Indef} ;
more_CAdv = ss "mer" ;
most_Predet = {s = gennumForms ["den meste"] ["det meste"] ["de fleste"]} ;
much_Det = {s = \\_,_ => "meget" ; n = Pl ; det = DDef Indef} ;
must_VV =
mkV "måtte" "må" "må" "måtte" "måttet" "mått" ** {c2 = [] ; lock_VV = <>} ;
no_Utt = ss ["nej"] ;
on_Prep = ss "på" ;
--- one_Quant = {s = \\_ => genderForms ["en"] ["et"] ; n = Sg ; det = DIndef} ; --- ei
only_Predet = {s = \\_ => "kun"} ;
or_Conj = {s1 = [] ; s2 = "eller" ; n = Pl} ;
otherwise_PConj = ss "anderledes" ;
part_Prep = ss "af" ;
please_Voc = ss "tak" ; ---
possess_Prep = ss "af" ;
quite_Adv = ss "temmelig" ;
she_Pron = MorphoDan.mkNP "hun" "hende" "hendes" "hendes" "hendes" SgUtr P3 ;
so_AdA = ss "så" ;
someSg_Det = {s = \\_ => genderForms "nogen" "noget" ; n = Sg ; det = DIndef} ;
somePl_Det = {s = \\_,_ => "nogle" ; n = Pl ; det = DIndef} ;
somebody_NP = regNP "nogen" "nogens" SgUtr ;
something_NP = regNP "noget" "nogets" SgNeutr ;
somewhere_Adv = ss ["et eller annet sted"] ; ---- ?
that_Quant =
{s = table {
Sg => \\_ => genderForms ["den der"] ["det der"] ;
Pl => \\_,_ => ["de der"]
} ;
det = DDef Indef
} ;
there_Adv = ss "der" ;
there7to_Adv = ss "dit" ;
there7from_Adv = ss "derfra" ;
therefore_PConj = ss "derfor" ;
they_Pron = MorphoDan.mkNP "de" "dem" "deres" "deres" "deres" Plg P1 ;
this_Quant =
{s = table {
Sg => \\_ => genderForms ["denne"] ["dette"] ;
Pl => \\_,_ => ["disse"]
} ;
det = DDef Indef
} ;
through_Prep = ss "gennem" ;
too_AdA = ss "for" ;
to_Prep = ss "til" ;
under_Prep = ss "under" ;
very_AdA = ss "meget" ;
want_VV =
mkV "ville" "vil" "vil" "ville" "villet" "villed" **
{c2 = [] ; lock_VV = <>} ;
we_Pron = MorphoDan.mkNP "vi" "os" "vores" "vores" "vores" Plg P1 ;
whatSg_IP = {s = \\_ => "hvad" ; gn = SgUtr} ; ---- infl
whatPl_IP = {s = \\_ => "hvilke" ; gn = Plg} ; ---- infl
when_IAdv = ss "hvornår" ;
when_Subj = ss "når" ;
where_IAdv = ss "hver" ;
which_IQuant = {
s = table {
Sg => genderForms "hvilken" "hvilket" ;
Pl => \\_ => "hvilke"
} ;
det = DIndef
} ;
whoSg_IP = {s = vem.s ; gn = SgUtr} ;
whoPl_IP = {s = \\_ => "hvilke" ; gn = Plg} ;
why_IAdv = ss "hvorfor" ;
without_Prep = ss "uden" ;
with_Prep = ss "med" ;
yes_Utt = ss ["ja"] ;
youSg_Pron =
MorphoDan.mkNP "du" "dig" "din" "dit" "dine" SgUtr P2 ; ----
youPl_Pron = MorphoDan.mkNP "i" "jer" "jeres" "jeres" "jeres" Plg P2 ;
youPol_Pron = MorphoDan.mkNP "Dere" "Dere" "Deres" "Deres" "Deres" SgUtr P2 ; --- wrong in refl
-- Auxiliaries that are used repeatedly.
oper
vem = MorphoDan.mkNP "hvem" "hvem" "hvis" "hvis" "hvis" SgUtr P3 ;
}

2
lib/resource-1.4/danish/VerbDan.gf Normal file
View File

@@ -0,0 +1,2 @@
concrete VerbDan of Verb = CatDan ** VerbScand with
(ResScand = ResDan) ;