Close to finishing new verisons of Finnish and GErman.

lib/resource-0.6/german/CombinationsGer.gf

@@ -0,0 +1,198 @@
+--# -path=.:../abstract:../../prelude
+
+--1 The Top-Level German Resource Grammar
+--
+-- Aarne Ranta 2002 -- 2003
+--
+-- This is the German concrete syntax of the multilingual resource
+-- grammar. Most of the work is done in the file $syntax.Deu.gf$.
+-- However, for the purpose of documentation, we make here explicit the
+-- linearization types of each category, so that their structures and
+-- dependencies can be seen.
+-- Another substantial part are the linearization rules of some
+-- structural words.
+--
+-- The users of the resource grammar should not look at this file for the
+-- linearization rules, which are in fact hidden in the document version.
+-- They should use $resource.Abs.gf$ to access the syntactic rules.
+-- This file can be consulted in those, hopefully rare, occasions in which
+-- one has to know how the syntactic categories are
+-- implemented. The parameter types are defined in $TypesGer.gf$.
+
+concrete CombinationsGer of Combinations = open Prelude, SyntaxGer in {
+
+flags 
+  startcat=Phr ; 
+  parser=chart ;
+
+lincat 
+  CN     = CommNounPhrase ; 
+      -- = {s : Adjf => Number => Case => Str ; g : Gender} ;
+  N      = CommNoun ;
+      -- = {s : Number => Case => Str ; g : Gender} ; 
+  NP     = NounPhrase ;
+      -- = {s : NPForm => Str ; n : Number ; p : Person ; pro : Bool} ;
+  PN     = ProperName ;
+      -- = {s : Case => Str} ;
+  Det    = {s : Gender => Case => Str ; n : Number ; a : Adjf} ;
+  Fun    = Function ;
+      -- = CommNounPhrase ** {s2 : Preposition ; c : Case} ;
+  Fun2   = Function ** {s3 : Preposition ; c2 : Case} ;
+  Num    = {s : Str} ;
+  Prep   = {s : Str ; c : Case} ;
+
+  Adj1   = Adjective ;
+      -- = {s : AForm => Str} ;
+  Adj2   = Adjective ** {s2 : Preposition ; c : Case} ;
+  AdjDeg = {s : Degree => AForm => Str} ;
+  AP     = Adjective ** {p : Bool} ;
+
+  V      = Verb ; 
+      -- = {s : VForm => Str ; s2 : Particle} ;
+  VG     = {s : VForm => Str ; s2 : Str ; s3 : Bool => Number => Str ; s4 : Str} ;
+  VP     = Verb ** {s3 : Number => Str ; s4 : Str} ; 
+  TV     = TransVerb ; 
+      -- = Verb ** {s3 : Preposition ; c : Case} ;
+  V3     = TransVerb ** {s4 : Preposition ; c2 : Case} ;
+  VS     = Verb ;
+  VV     = Verb ** {isAux : Bool} ;
+  AdV    = {s : Str} ;
+
+  S      = Sentence ;
+      -- = {s : Order => Str} ; 
+  Slash  = Sentence ** {s2 : Preposition ; c : Case} ;
+
+  RP     = {s : GenNum => Case => Str} ;
+  RC     = {s : GenNum => Str} ;
+
+  IP     = ProperName ** {n : Number} ;
+  Qu     = {s : QuestForm => Str} ;
+  Imp    = {s : Number => Str} ;
+  Phr    = {s : Str} ;
+  Text   = {s : Str} ;
+
+  Conj   = {s : Str ; n : Number} ;
+  ConjD  = {s1,s2 : Str ; n : Number} ;
+
+  ListS  = {s1,s2 : Order => Str} ; 
+  ListAP = {s1,s2 : AForm => Str ; p : Bool} ;
+  ListNP = {s1,s2 : NPForm => Str ; n : Number ; p : Person ; pro : Bool} ;
+
+--.
+
+lin 
+  UseN = noun2CommNounPhrase ;
+  ModAdj = modCommNounPhrase ;
+  ModGenOne = npGenDet singular noNum ;
+  ModGenMany = npGenDet plural ;
+  UsePN = nameNounPhrase ;
+  UseFun = funAsCommNounPhrase ;
+  AppFun = appFunComm ;
+  AppFun2 = appFun2 ;
+  AdjP1 = adj2adjPhrase ;
+  ComplAdj = complAdj ;
+  PositAdjP = positAdjPhrase ;
+  ComparAdjP = comparAdjPhrase ;
+  SuperlNP = superlNounPhrase ;
+
+  DetNP = detNounPhrase ;
+  IndefOneNP = indefNounPhrase singular ;
+  IndefManyNP = plurDetNum ;
+  DefOneNP = defNounPhrase singular ;
+  DefManyNP nu = defNounPhraseNum nu plural ;
+  MassNP = massNounPhrase ;
+  UseInt i = i ;
+  NoNum = noNum ;
+
+  CNthatS = nounThatSentence ;
+  PredVP = predVerbPhrase ;
+  PosVG  = predVerbGroup True ;
+  NegVG  = predVerbGroup False ;
+
+  PredV  = predVerb ;
+  PredAP = predAdjective ;
+  PredCN = predCommNoun ;
+  PredTV = complTransVerb ;
+  PredV3 = complDitransVerb ;
+  PredPassV = passVerb ;
+  PredNP = predNounPhrase ;
+  PredAdV = predAdverb ;
+  PredVS = complSentVerb ;
+  PredVV = complVerbVerb ;
+  VTrans = transAsVerb ;
+
+  AdjAdv a = ss (a.s ! APred) ;
+  PrepNP = prepPhrase ;
+  AdvVP = adVerbPhrase ;
+  AdvCN = advCommNounPhrase ;
+  AdvAP = advAdjPhrase ;
+
+  ThereNP A = predVerbPhrase (pronNounPhrase pronEs) 
+    (predVerbGroup True (complTransVerb (transDir verbGeben) A)) ;
+  IsThereNP A = questVerbPhrase (pronNounPhrase pronEs) 
+    (predVerbGroup True (complTransVerb (transDir verbGeben) A)) ;
+
+  PosSlashTV = slashTransVerb True ;
+  NegSlashTV = slashTransVerb False ;
+  OneVP = predVerbPhrase (nameNounPhrase {s = \\_ => "man"}) ;
+
+  IdRP = identRelPron ;
+  FunRP = funRelPron ;
+  RelVP = relVerbPhrase ;
+  RelSlash = relSlash ;
+  ModRC = modRelClause ;
+  RelSuch = relSuch ;
+
+  WhoOne = intPronWho singular ;
+  WhoMany = intPronWho plural ;
+  WhatOne = intPronWhat singular ;
+  WhatMany = intPronWhat plural ;
+  FunIP = funIntPron ;
+  NounIPOne = nounIntPron singular ;
+  NounIPMany = nounIntPron plural ;
+
+  QuestVP = questVerbPhrase ;
+  IntVP = intVerbPhrase ;
+  IntSlash = intSlash ;
+  QuestAdv = questAdverbial ;
+
+  ImperVP = imperVerbPhrase ;
+
+  IndicPhrase = indicUtt ;
+  QuestPhrase = interrogUtt ;
+  ImperOne = imperUtterance singular ;
+  ImperMany = imperUtterance plural ;
+
+  AdvS = advSentence ;
+
+lin
+  TwoS = twoSentence ;
+  ConsS = consSentence ;
+  ConjS = conjunctSentence ;
+  ConjDS = conjunctDistrSentence ;
+
+  TwoAP = twoAdjPhrase ;
+  ConsAP = consAdjPhrase ;
+  ConjAP = conjunctAdjPhrase ;
+  ConjDAP = conjunctDistrAdjPhrase ;
+
+  TwoNP = twoNounPhrase ;
+  ConsNP = consNounPhrase ;
+  ConjNP = conjunctNounPhrase ;
+  ConjDNP = conjunctDistrNounPhrase ;
+
+  SubjS = subjunctSentence ;
+  SubjImper = subjunctImperative ;
+  SubjQu = subjunctQuestion ;
+  SubjVP = subjunctVerbPhrase ;
+
+  PhrNP = useNounPhrase ;
+  PhrOneCN = useCommonNounPhrase singular ;
+  PhrManyCN = useCommonNounPhrase plural ;
+  PhrIP ip = ip ;
+  PhrIAdv ia = ia ;
+
+  OnePhr p = p ;
+  ConsPhr = cc2 ;
+
+} ;

lib/resource-0.6/german/MorphoGer.gf

@@ -0,0 +1,399 @@
+--1 A Simple German Resource Morphology
+--
+-- Aarne Ranta 2002
+--
+-- This resource morphology contains definitions needed in the resource
+-- syntax. It moreover contains the most usual inflectional patterns.
+--
+-- We use the parameter types and word classes defined in $types.Deu.gf$.
+
+resource MorphoGer = TypesGer ** open (Predef=Predef), Prelude in {
+
+--2 Nouns
+--
+-- For conciseness and abstraction, we define a method for
+-- generating a case-dependent table from a list of four forms.
+
+oper
+  caselist : (_,_,_,_ : Str) -> Case => Str = \n,a,d,g -> table {
+    Nom => n ; Acc => a ; Dat => d ; Gen => g} ;
+
+-- The *worst-case macro* for common nouns needs six forms: all plural forms
+-- are always the same except for the dative.
+
+  mkNoun  : (_,_,_,_,_,_ : Str) -> Gender -> CommNoun = 
+    \mann, mannen, manne, mannes, männer, männern, g -> {s = table {
+       Sg => caselist mann mannen manne mannes ;
+       Pl => caselist männer männer männern männer
+       } ; g = g} ;
+
+-- But we never need all the six forms at the same time. Often
+-- we need just two, three, or four forms.
+
+  mkNoun4 : (_,_,_,_ : Str) -> Gender -> CommNoun = \kuh,kuhes,kühe,kühen ->
+      mkNoun kuh kuh kuh kuhes kühe kühen ;
+
+  mkNoun3 : (_,_,_ : Str) -> Gender -> CommNoun = \kuh,kühe,kühen ->
+      mkNoun kuh kuh kuh kuh kühe kühen ;
+
+  mkNoun2n : (_,_ : Str) -> Gender -> CommNoun = \zahl, zahlen -> 
+      mkNoun3 zahl zahlen zahlen ;
+
+  mkNoun2es : (_,_ : Str) -> Gender -> CommNoun = \wort, wörter -> 
+      mkNoun wort wort wort (wort + "es") wörter (wörter + "n") ;
+
+  mkNoun2s : (_,_ : Str) -> Gender -> CommNoun = \vater, väter -> 
+      mkNoun vater vater vater (vater + "s") väter (väter + "n") ;
+
+  mkNoun2ses : (_,_ : Str) -> Gender -> CommNoun = \wort,wörter -> 
+      mkNoun wort wort wort (wort + variants {"es" ; "s"}) wörter (wörter + "n") ;
+
+-- Here are the school grammar declensions with their commonest variations.
+-- Unfortunately we cannot define *Umlaut* in GF, but have to give two forms.
+--
+-- First declension, with plural "en"/"n", including weak masculins:
+
+  declN1  : Str -> CommNoun = \zahl  -> 
+    mkNoun2n zahl  (zahl + "en") Fem ;
+
+  declN1e : Str -> CommNoun = \stufe -> 
+    mkNoun2n stufe (stufe + "n") Fem ;  
+
+  declN1M : Str -> CommNoun = \junge -> let {jungen = junge + "n"} in
+    mkNoun junge jungen jungen jungen jungen jungen Masc ;
+
+  declN1eM : Str -> CommNoun = \soldat -> let {soldaten = soldat + "en"} in
+    mkNoun soldat soldaten soldaten soldaten soldaten soldaten Masc ;
+
+-- Second declension, with plural "e":
+
+  declN2  : Str -> CommNoun = \punkt -> 
+    mkNoun2es punkt (punkt+"e") Masc ;
+
+  declN2i  : Str -> CommNoun = \onkel -> 
+    mkNoun2s onkel onkel Masc ;
+
+  declN2u : (_,_ : Str) -> CommNoun = \raum,räume -> 
+    mkNoun2es raum räume Masc ;
+
+  declN2uF : (_,_ : Str) -> CommNoun = \kuh,kühe -> 
+    mkNoun3 kuh kühe (kühe + "n") Fem ;
+
+-- Third declension, with plural "er":
+
+  declN3  : Str -> CommNoun = \punkt -> 
+    mkNoun2es punkt (punkt+"er") Neut ;
+
+  declN3u : (_,_ : Str) -> CommNoun = \buch,bücher -> 
+    mkNoun2ses buch bücher Neut ;
+
+  declN3uS : (_,_ : Str) -> CommNoun = \haus,häuser -> 
+    mkNoun2es haus häuser Neut ;
+
+-- Plural with "s":
+
+  declNs : Str -> CommNoun = \restaurant -> 
+    mkNoun3 restaurant (restaurant+"s") (restaurant+"s") Neut ;
+
+
+--2 Pronouns
+--
+-- Here we define personal and relative pronouns.
+-- All personal pronouns, except "ihr", conform to the simple
+-- pattern $mkPronPers$.
+
+  ProPN = {s : NPForm => Str ; n : Number ; p : Person} ;
+
+  mkPronPers : (_,_,_,_,_ : Str) -> Number -> Person -> ProPN = 
+    \ich,mich,mir,meines,mein,n,p -> {
+      s = table {
+        NPCase c    => caselist ich mich mir meines ! c ;
+        NPPoss gn c => mein + pronEnding ! gn ! c
+        } ;
+      n = n ;
+      p = p
+      } ;
+
+  pronEnding : GenNum => Case => Str = table {
+    GSg Masc => caselist ""  "en" "em" "es" ;
+    GSg Fem  => caselist "e" "e"  "er" "er" ;
+    GSg Neut => caselist ""  ""   "em" "es" ;
+    GPl      => caselist "e"  "e" "en" "er"
+    } ;
+
+  pronIch  = mkPronPers "ich" "mich" "mir"   "meines" "mein"  Sg P1 ;
+  pronDu   = mkPronPers "du"  "dich" "dir"   "deines" "dein"  Sg P2 ;
+  pronEr   = mkPronPers "er"  "ihn"  "ihm"   "seines" "sein"  Sg P3 ;
+  pronSie  = mkPronPers "sie" "sie"  "ihr"   "ihres"  "ihr"   Sg P3 ;
+  pronEs   = mkPronPers "es"  "es"   "ihm"   "seines" "sein"  Sg P3 ;
+  pronWir  = mkPronPers "wir" "uns"  "uns"   "unser"  "unser" Pl P1 ;
+
+  pronSiePl = mkPronPers "sie" "sie"  "ihnen" "ihrer"  "ihr"   Pl P3 ;
+  pronSSie  = mkPronPers "Sie" "Sie"  "Ihnen" "Ihrer"  "Ihr"   Pl P3 ; ---
+
+-- We still have wrong agreement with the complement of the polite "Sie":
+-- it is in plural, like the verb, although it should be in singular.
+
+-- The peculiarity with "ihr" is the presence of "e" in forms without an ending.
+
+  pronIhr  = 
+     {s = table {
+        NPPoss (GSg Masc) Nom => "euer" ;
+        NPPoss (GSg Neut) Nom => "euer" ;
+        NPPoss (GSg Neut) Acc => "euer" ;
+        pf => (mkPronPers "ihr" "euch" "euch"  "euer"  "eur"  Pl P2).s ! pf
+        } ;
+      n = Pl ;
+      p = P2
+      } ;
+
+-- Relative pronouns are like the definite article, except in the genitive and
+-- the plural dative. The function $artDef$ will be defined right below.
+
+  RelPron : Type = {s : GenNum => Case => Str} ;
+
+  relPron : RelPron = {s = \\gn,c => 
+    case <gn,c> of {
+      <GSg Fem,Gen> => "deren" ;
+      <GSg g,Gen>   => "dessen" ;
+      <GPl,Dat>     => "denen" ;
+      <GPl,Gen>     => "deren" ;
+      _ => artDef ! gn ! c
+    } 
+  } ;
+
+
+--2 Articles
+--
+-- Here are all forms the indefinite and definite article.
+-- The indefinite article is like a large class of pronouns.
+-- The definite article is more peculiar; we don't try to
+-- subsume it to any general rule.
+
+  artIndef : Gender => Case => Str = \\g,c => "ein" + pronEnding ! GSg g ! c ;
+
+  artDef : GenNum => Case => Str = table {
+    GSg Masc => caselist "der" "den" "dem" "des" ;
+    GSg Fem  => caselist "die" "die" "der" "der" ;
+    GSg Neut => caselist "das" "das" "dem" "des" ;
+    GPl      => caselist "die" "die" "den" "der"
+    } ;
+
+
+--2 Adjectives
+--
+-- As explained in $types.Deu.gf$, it
+-- would be superfluous to use the cross product of gender and number,
+-- since there is no gender distinction in the plural. But it is handy to have
+-- a function that constructs gender-number complexes.
+  
+  gNumber : Gender -> Number -> GenNum = \g,n -> 
+    case n of {
+      Sg => GSg g ;
+      Pl => GPl
+      } ;
+
+-- It's also handy to have a function that finds out the number from such a complex.
+
+  numGenNum : GenNum -> Number = \gn -> 
+    case gn of {
+      GSg _ => Sg ;
+      GPl => Pl
+      } ;
+
+-- This function costructs parameters in the complex type of adjective forms.
+
+  aMod : Adjf -> Gender -> Number -> Case -> AForm = \a,g,n,c -> 
+    AMod a (gNumber g n) c ;
+
+-- The worst-case macro for adjectives (positive degree) only needs
+-- two forms.
+  
+  mkAdjective : (_,_ : Str) -> Adjective = \böse,bös -> {s = table {
+    APred => böse ;
+    AMod Strong (GSg Masc) c => 
+      caselist (bös+"er") (bös+"en") (bös+"em") (bös+"es") ! c ;
+    AMod Strong (GSg Fem) c => 
+      caselist (bös+"e") (bös+"e") (bös+"er") (bös+"er") ! c ;
+    AMod Strong (GSg Neut) c => 
+      caselist (bös+"es") (bös+"es") (bös+"em") (bös+"es") ! c ;
+    AMod Strong GPl c => 
+      caselist (bös+"e") (bös+"e") (bös+"en") (bös+"er") ! c ;
+    AMod Weak (GSg g) c => case <g,c> of {
+      <_,Nom>    => bös+"e" ;
+      <Masc,Acc> => bös+"en" ;
+      <_,Acc>    => bös+"e" ;
+      _          => bös+"en" } ;
+    AMod Weak GPl c => bös+"en"
+    }} ;
+
+-- Here are some classes of adjectives:
+ 
+  adjReg   : Str -> Adjective = \gut -> mkAdjective gut gut ;
+  adjE     : Str -> Adjective = \bös -> mkAdjective (bös+"e") bös ;
+  adjEr    : Str -> Adjective = \teu -> mkAdjective (teu+"er") (teu+"r") ;
+  adjInvar : Str -> Adjective = \prima -> {s = table {_ => prima}} ;
+
+-- The first three classes can be recognized from the end of the word, depending
+-- on if it is "e", "er", or something else.
+
+  adjGen : Str -> Adjective = \gut -> let {
+    er  = Predef.dp 2 gut ;
+    teu = Predef.tk 2 gut ;
+    e   = Predef.dp 1 gut ;
+    bös = Predef.tk 1 gut
+  } in
+  ifTok Adjective er "er" (adjEr  teu) (
+  ifTok Adjective e  "e"  (adjE   bös) (
+                          (adjReg gut))) ;
+
+
+-- The comparison of adjectives needs three adjectives in the worst case.
+
+  mkAdjComp : (_,_,_ : Adjective) -> AdjComp = \gut,besser,best -> 
+    {s = table {Pos => gut.s ; Comp => besser.s ; Sup => best.s}} ;
+
+-- It can be done by just three strings, if each of the comparison
+-- forms taken separately is a regular adjective.
+
+  adjCompReg3 : (_,_,_ : Str) -> AdjComp = \gut,besser,best ->
+    mkAdjComp (adjReg gut) (adjReg besser) (adjReg best) ;
+
+-- If also the comparison forms are regular, one string is enough.
+
+  adjCompReg : Str -> AdjComp = \billig ->
+    adjCompReg3 billig (billig+"er") (billig+"st") ;
+
+
+--2 Verbs
+--
+-- We limit ourselves to verbs in present tense infinitive, indicative, 
+-- and imperative, and past participle. Other forms will be introduced later.
+--
+-- The worst-case macro needs three forms: the infinitive, the third person
+-- singular indicative, and the second person singular imperative. 
+-- We take care of the special cases "ten", "sen", "ln", "rn".
+--
+-- A famous law about Germanic languages says that plural first and third person
+-- are similar.
+
+  mkVerbum : (_,_,_,_ : Str) -> Verbum = \geben, gib, gb, gegeben -> 
+    let {
+       en = Predef.dp 2 geben ;
+       geb = ifTok Tok (Predef.tk 1 en) "e" (Predef.tk 2 geben)(Predef.tk 1 geben) ;
+       gebt = ifTok Tok (Predef.dp 1 geb) "t" (geb + "et") (geb + "t") ;
+       gibst = ifTok Tok (Predef.dp 1 gib) "s" (gib + "t") (gib + "st") ;
+       gegebener = (adjReg gegeben).s
+    } in table {
+           VInf       => geben ;
+           VInd Sg P1 => geb + "e" ;
+           VInd Sg P2 => gibst ;
+           VInd Sg P3 => gib + "t" ;
+           VInd Pl P2 => gebt ;
+           VInd Pl _  => geben ; -- the famous law
+           VImp Sg    => gb ;
+           VImp Pl    => gebt ;
+           VPart a    => gegebener ! a
+           } ;
+
+-- Regular verbs:
+
+  regVerb : Str -> Verbum = \legen ->
+    let {lege = ifTok Tok (Predef.dp 3 legen) "ten" (Predef.tk 1 legen) (
+                ifTok Tok (Predef.dp 2 legen) "en"  (Predef.tk 2 legen) (
+                                                     Predef.tk 1 legen))} in
+    mkVerbum legen lege lege ("ge" + (lege + "t")) ;
+
+-- Verbs ending with "t"; now recognized in $mkVerbum$.
+
+  verbWarten : Str -> Verbum = regVerb ;
+
+-- Verbs with Umlaut in the second and third person singular and imperative:
+
+  verbSehen : Str -> Str -> Str -> Verbum = \sehen, sieht, gesehen -> 
+    let {sieh = Predef.tk 1 sieht} in mkVerbum sehen sieh sieh gesehen ;
+
+-- Verbs with Umlaut in the second and third person singular but not imperative:
+
+  verbLaufen : Str -> Str -> Str -> Verbum = \laufen, läuft, gelaufen -> 
+    let {läuf = Predef.tk 1 läuft ; laufe = Predef.tk 1 laufen} 
+    in mkVerbum laufen läuf laufe gelaufen ;
+
+-- The verb "be":
+
+  verbumSein : Verbum = let {
+    gewesen = (adjReg "gewesen").s
+  } in
+  table {
+    VInf       => "sein" ;
+    VInd Sg P1 => "bin" ;
+    VInd Sg P2 => "bist" ;
+    VInd Sg P3 => "ist" ;
+    VInd Pl P2 => "seid" ;
+    VInd Pl _  => "sind" ;
+    VImp Sg    => "sei" ;
+    VImp Pl    => "seiet" ;
+    VPart a    => gewesen ! a
+    } ;
+
+-- The verb "have":
+
+  verbumHaben :  Verbum = let {
+    haben = (regVerb "haben")
+    } in 
+    table {
+      VInd Sg P2 => "hast" ;
+      VInd Sg P3 => "hat" ;
+      v          => haben ! v
+      } ;
+
+-- The verb "become", used as the passive auxiliary:
+
+  verbumWerden :  Verbum = let {
+    werden = regVerb "werden" ;
+    geworden = (adjReg "geworden").s
+    } in 
+    table {
+      VInd Sg P2 => "wirst" ;
+      VInd Sg P3 => "wird" ;
+      VPart a    => geworden ! a ;
+      v          => werden ! v
+      } ;
+
+-- A *full verb* ($Verb$) consists of the inflection forms ($Verbum$) and
+-- a *particle* (e.g. "aus-sehen"). Simple verbs are the ones that have no 
+-- such particle.
+
+  mkVerb : Verbum -> Particle -> Verb = \v,p -> {s = v ; s2 = p} ;
+
+  mkVerbSimple : Verbum -> Verb = \v -> mkVerb v [] ;
+
+  verbSein = mkVerbSimple verbumSein ;
+  verbHaben = mkVerbSimple verbumHaben ;
+  verbWerden = mkVerbSimple verbumWerden ;
+  verbGeben = mkVerbSimple (verbSehen "geben" "gibt" "gegeben") ;
+
+{-
+  -- tests for optimizer
+  verbumSein2 : Verbum = 
+  table {
+    VInf       => "sein" ;
+    VInd Sg P1 => "bin" ;
+    VInd Sg P2 => "bist" ;
+    VInd Sg P3 => "ist" ;
+    VInd Pl P2 => "seid" ;
+    VInd Pl _  => "sind" ;
+    VImp Sg    => "sei" ;
+    VImp Pl    => "seiet" ;
+    VPart a    => (adjReg "gewesen").s ! a
+    } ;
+
+  verbumHaben2 :  Verbum = 
+    table {
+      VInd Sg P2 => "hast" ;
+      VInd Sg P3 => "hat" ;
+      v          => regVerb "haben" ! v
+      } ;
+-}
+
+} ;

lib/resource-0.6/german/ParadigmsGer.gf

@@ -0,0 +1,310 @@
+--# -path=.:../abstract:../../prelude
+
+--1 German Lexical Paradigms
+--
+-- Aarne Ranta 2003
+--
+-- This is an API to the user of the resource grammar 
+-- for adding lexical items. It give shortcuts for forming
+-- expressions of basic categories: nouns, adjectives, verbs.
+-- 
+-- Closed categories (determiners, pronouns, conjunctions) are
+-- accessed through the resource syntax API, $resource.Abs.gf$. 
+--
+-- The main difference with $morpho.Deu.gf$ is that the types
+-- referred to are compiled resource grammar types. We have moreover
+-- had the design principle of always having existing forms as string
+-- arguments of the paradigms, not stems.
+--
+-- The following modules are presupposed:
+
+resource Paradigms = open (Predef=Predef), Prelude, (Morpho=Morpho), Syntax, Deutsch in {
+
+
+--2 Parameters 
+--
+-- To abstract over gender names, we define the following identifiers.
+
+oper
+  masculine : Gender ;
+  feminine  : Gender ;
+  neuter    : Gender ;
+
+-- To abstract over case names, we define the following.
+
+  nominative : Case ;
+  accusative : Case ;
+  dative     : Case ;
+  genitive   : Case ;
+
+-- To abstract over number names, we define the following.
+
+  singular : Number ;
+  plural   : Number ;
+
+
+--2 Nouns
+
+-- Worst case: give all four singular forms, two plural forms (others + dative),
+-- and the gender.
+
+  mkN  : (_,_,_,_,_,_ : Str) -> Gender -> N ; 
+                                 -- mann, mann, manne, mannes, männer, männern
+
+-- Often it is enough with singular and plural nominatives, and singular
+-- genitive. The plural dative
+-- is computed by the heuristic that it is the same as the nominative this
+-- ends with "n" or "s", otherwise "n" is added.
+
+  nGen : Str -> Str -> Str ->  Gender -> N ; -- punkt,punktes,punkt
+  
+-- Here are some common patterns. Singular nominative or two nominatives are needed.
+-- Two forms are needed in case of Umlaut, which would be complicated to define.
+-- For the same reason, we have separate patterns for multisyllable stems.
+-- 
+-- The weak masculine pattern $nSoldat$ avoids duplicating the final "e".
+
+  nRaum   : (_,_ : Str) -> N ;    -- Raum, (Raumes,) Räume (masc)
+  nTisch  : Str -> N ;            -- Tisch, (Tisches, Tische) (masc)
+  nVater  : (_,_ : Str) -> N ;    -- Vater, (Vaters,) Väter (masc)
+  nFehler : Str -> N ;            -- Fehler, (fehlers, Fehler) (masc)
+  nSoldat : Str -> N ;            -- Soldat (, Soldaten) ; Kunde (, Kunden) (masc)
+
+-- Neuter patterns. 
+
+  nBuch   : (_,_ : Str) -> N ;    -- Buch, (Buches, Bücher) (neut)
+  nMesser : Str -> N ;            -- Messer, (Messers, Messer) (neut)
+  nAuto   : Str -> N ;            -- Auto, (Autos, Autos) (neut)
+
+-- Feminine patterns. Duplicated "e" is avoided in $nFrau$.
+
+  nHand   : (_,_ : Str) -> N ;    -- Hand, Hände; Mutter, Mütter (fem)
+  nFrau   : Str -> N ;            -- Frau (, Frauen) ; Wiese (, Wiesen) (fem)
+
+
+-- Nouns used as functions need a preposition. The most common is "von".
+
+  mkFun  : N -> Preposition -> Case -> Fun ;
+  funVon : N -> Fun ;
+
+-- Proper names, with their possibly
+-- irregular genitive. The regular genitive is  "s", omitted after "s".
+
+  mkPN  : (karolus, karoli : Str) -> PN ; -- karolus, karoli
+  pnReg : (Johann : Str) -> PN ;          -- Johann, Johanns ; Johannes, Johannes
+
+-- On the top level, it is maybe $CN$ that is used rather than $N$, and
+-- $NP$ rather than $PN$.
+
+  mkCN  : N -> CN ;
+  mkNP  : (karolus,karoli : Str) -> NP ;
+
+  npReg : Str -> NP ;   -- Johann, Johanns
+
+-- In some cases, you may want to make a complex $CN$ into a function.
+
+  mkFunCN  : CN -> Preposition -> Case -> Fun ;
+  funVonCN : CN -> Fun ;
+
+
+--2 Adjectives
+
+-- Non-comparison one-place adjectives need two forms in the worst case:
+-- the one in predication and the one before the ending "e".
+
+  mkAdj1 : (teuer,teur : Str) -> Adj1 ;
+
+-- Invariable adjective are a special case.
+
+  adjInvar : Str -> Adj1 ;          -- prima
+
+-- The following heuristic recognizes the the end of the word, and builds
+-- the second form depending on if it is "e", "er", or something else.
+-- N.B. a contraction is made with "er", which works for "teuer" but not
+-- for "bitter".
+
+  adjGen : Str -> Adj1 ;            -- gut; teuer; böse
+
+-- Two-place adjectives need a preposition and a case as extra arguments.
+
+  mkAdj2 : Adj1 -> Str -> Case -> Adj2 ;  -- teilbar, durch, acc
+
+-- Comparison adjectives may need three adjective, corresponding to the
+-- three comparison forms. 
+
+  mkAdjDeg : (gut,besser,best : Adj1) -> AdjDeg ;
+
+-- In many cases, each of these adjectives is itself regular. Then we only
+-- need three strings. Notice that contraction with "er" is not performed
+-- ("bessere", not "bessre").
+
+  aDeg3 : (gut,besser,best : Str) -> AdjDeg ;
+
+-- In the completely regular case, the comparison forms are constructed by
+-- the endings "er" and "st".
+
+  aReg : Str -> AdjDeg ;    -- billig, billiger, billigst
+
+-- The past participle of a verb can be used as an adjective.
+
+  aPastPart : V -> Adj1 ;   -- gefangen
+
+-- On top level, there are adjectival phrases. The most common case is
+-- just to use a one-place adjective. The variation in $adjGen$ is taken
+-- into account.
+
+  apReg : Str -> AP ;
+
+
+--2 Verbs
+--
+-- The fragment only has present tense so far, but in all persons.
+-- It also has the infinitive and the past participles.
+-- The worst case macro needs four forms: : the infinitive and 
+-- the third person singular (where Umlaut may occur), the singular imperative,
+-- and the past participle.
+-- 
+-- The function recognizes if the stem ends with "s" or "t" and performs the
+-- appropriate contractions.
+
+  mkV : (_,_,_,_ : Str) -> V ;   -- geben, gibt, gib, gegeben
+
+-- Regular verbs are those where no Umlaut occurs.
+
+  vReg  : Str -> V ;         -- kommen
+
+-- The verbs 'be' and 'have' are special.
+
+  vSein  : V ;
+  vHaben : V ;
+
+-- Verbs with a detachable particle, with regular ones as a special case.
+
+  vPart    :  (_,_,_,_,_ : Str) -> V ;     -- sehen, sieht, sieh, gesehen, aus
+  vPartReg :  (_,_     : Str) -> V ;       -- bringen, um
+
+-- Two-place verbs, and the special case with direct object. Notice that
+-- a particle can be included in a $V$.
+
+  mkTV     : V   -> Str -> Case -> TV ;  -- hören, zu, dative
+
+  tvReg    : Str -> Str -> Case -> TV ;  -- hören, zu, dative
+  tvDir    : V -> TV ;                   -- umbringen
+  tvDirReg : Str -> TV ;                 -- lieben
+
+-- Three-place verbs require two prepositions and cases.
+
+  mkV3 : V -> Str -> Case -> Str -> Case -> V3 ;  -- geben,[],dative,[],accusative
+
+
+--2 Adverbials
+--
+-- Adverbials for modifying verbs, adjectives, and sentences can be formed 
+-- from strings.
+
+  mkAdV : Str -> AdV ;
+  mkAdA : Str -> AdA ;
+  mkAdS : Str -> AdS ;
+
+-- Prepositional phrases are another productive form of adverbials.
+
+  mkPP : Case -> Str -> NP -> AdV ;
+
+-- The definitions should not bother the user of the API. So they are
+-- hidden from the document.
+--.
+
+
+  masculine = Masc ;
+  feminine  = Fem ;
+  neuter = Neut ;
+  nominative = Nom ;
+  accusative = Acc ;
+  dative = Dat ;
+  genitive = Gen ;
+  -- singular defined in Types
+  -- plural defined in Types
+
+  mkN a b c d e f g = mkNoun a b c d e f g ** {lock_N = <>} ;
+
+  nGen = \punkt, punktes, punkte, g -> let {
+      e   = Predef.dp 1 punkte ; 
+      eqy = ifTok N e ;
+      noN = mkNoun4 punkt punktes punkte punkte g ** {lock_N = <>}
+    } in
+    eqy "n" noN (
+    eqy "s" noN (
+            mkNoun4 punkt punktes punkte (punkte+"n") g ** {lock_N = <>})) ;
+
+  nRaum = \raum, räume -> nGen raum (raum + "es") räume masculine ;
+  nTisch = \tisch -> 
+    mkNoun4 tisch (tisch + "es") (tisch + "e") (tisch +"en") masculine ** 
+    {lock_N = <>};
+  nVater = \vater, väter -> nGen vater (vater + "s") väter masculine ;
+  nFehler = \fehler -> nVater fehler fehler ;
+
+  nSoldat = \soldat -> let {
+     e = Predef.dp 1 soldat ; 
+     soldaten = ifTok Tok e "e" (soldat + "n") (soldat + "en")
+    } in
+    mkN soldat soldaten soldaten soldaten soldaten soldaten masculine ;
+
+  nBuch = \buch, bücher -> nGen buch (buch + "es") bücher neuter ;
+  nMesser = \messer -> nGen messer (messer + "s") messer neuter ;
+  nAuto = \auto -> let {autos = auto + "s"} in 
+          mkNoun4 auto autos autos autos neuter ** {lock_N = <>} ;
+
+  nHand = \hand, hände -> nGen hand hand hände feminine ;
+
+  nFrau = \frau -> let {
+     e = Predef.dp 1 frau ; 
+     frauen = ifTok Tok e "e" (frau + "n") (frau + "en")
+    } in
+    mkN frau frau frau frau frauen frauen feminine ;
+
+  mkFun n = mkFunCN (UseN n) ;
+  funVon n = funVonCN (UseN n) ;
+
+  mkPN = \karolus, karoli -> 
+    {s = table {Gen => karoli ; _ => karolus} ; lock_PN = <>} ;
+  pnReg = \horst -> 
+    mkPN horst (ifTok Tok (Predef.dp 1 horst) "s" horst (horst + "s")) ;
+
+  mkCN = UseN ;
+  mkNP = \x,y -> UsePN (mkPN x y) ;
+  npReg = \s -> UsePN (pnReg s) ;
+
+  mkFunCN n p c = mkFunC n p c ** {lock_Fun = <>} ;
+  funVonCN n = funVonC n ** {lock_Fun = <>} ;
+
+  mkAdj1 x y = mkAdjective x y ** {lock_Adj1 = <>} ;
+  adjInvar a = Morpho.adjInvar a ** {lock_Adj1 = <>} ;
+  adjGen a = Morpho.adjGen a ** {lock_Adj1 = <>} ;
+  mkAdj2 = \a,p,c -> a ** {s2 = p ; c = c ; lock_Adj2 = <>} ;
+
+  mkAdjDeg a b c = mkAdjComp a b c ** {lock_AdjDeg = <>} ;
+  aDeg3 a b c = adjCompReg3 a b c ** {lock_AdjDeg = <>} ;
+  aReg a = adjCompReg a ** {lock_AdjDeg = <>} ;
+  aPastPart = \v -> {s = table AForm {a => v.s ! VPart a} ; lock_Adj1 = <>} ; 
+  apReg = \s -> AdjP1 (adjGen s) ;
+
+  mkV = \sehen, sieht, sieh, gesehen -> 
+    mkVerbSimple (mkVerbum sehen (Predef.tk 1 sieht) sieh gesehen) ** {lock_V = <>} ;
+  vReg = \s -> mkVerbSimple (regVerb s) ** {lock_V = <>} ;
+  vSein = verbSein ** {lock_V = <>} ;
+  vHaben = verbHaben ** {lock_V = <>} ;
+  vPart = \sehen, sieht, sieh, gesehen, aus -> 
+    mkVerb (mkVerbum sehen sieht sieh gesehen) aus ** {lock_V = <>} ;
+  vPartReg = \sehen, aus -> mkVerb (regVerb sehen) aus ** {lock_V = <>} ;
+
+  mkTV v p c = mkTransVerb v p c  ** {lock_TV = <>} ;
+  tvReg = \hören, zu, dat -> mkTV (vReg hören) zu dat ;
+  tvDir = \v -> mkTV v [] accusative ;
+  tvDirReg = \v -> tvReg v [] accusative ; 
+  mkV3 v s c t d = mkDitransVerb v s c t d ** {lock_V3 = <>} ;
+
+  mkAdV a = ss a ** {lock_AdV = <>} ;
+  mkPP x y z = prepPhrase x y z ** {lock_AdV = <>};
+  mkAdA a = ss a ** {lock_AdA = <>} ;
+  mkAdS a = ss a ** {lock_AdS = <>} ;
+} ;

lib/resource-0.6/german/StructuralGer.gf

@@ -0,0 +1,105 @@
+--1 The Top-Level German Resource Grammar
+--
+-- Aarne Ranta 2002 -- 2003
+--
+-- This is the German concrete syntax of the multilingual resource
+-- grammar. Most of the work is done in the file $syntax.Deu.gf$.
+-- However, for the purpose of documentation, we make here explicit the
+-- linearization types of each category, so that their structures and
+-- dependencies can be seen.
+-- Another substantial part are the linearization rules of some
+-- structural words.
+--
+-- The users of the resource grammar should not look at this file for the
+-- linearization rules, which are in fact hidden in the document version.
+-- They should use $resource.Abs.gf$ to access the syntactic rules.
+-- This file can be consulted in those, hopefully rare, occasions in which
+-- one has to know how the syntactic categories are
+-- implemented. The parameter types are defined in $Types.gf$.
+
+concrete StructuralGer of Structural = CombinationsGer ** open Prelude, SyntaxGer in {
+
+lin
+  INP    = pronNounPhrase pronIch ;
+  ThouNP = pronNounPhrase pronDu ;
+  HeNP   = pronNounPhrase pronEr ;
+  SheNP  = pronNounPhrase pronSie ; 
+  WeNP n = pronNounPhrase (pronWithNum pronWir n) ;
+  YeNP n = pronNounPhrase (pronWithNum pronIhr n) ;
+  TheyNP = pronNounPhrase pronSiePl ;
+
+  YouNP  = pronNounPhrase pronSSie ;
+
+  ItNP   = pronNounPhrase pronEs ; 
+  ThisNP = nameNounPhrase {s = dieserDet.s ! Neut} ; ---
+  ThatNP = nameNounPhrase {s = jenerDet.s ! Neut} ; ---
+
+  EveryDet = jederDet ; 
+  AllDet   = allesDet ; 
+  AllsDet  = alleDet ; 
+  WhichDet = welcherDet ;
+  WhichsDet = welcheDet ;
+  MostDet  = meistDet ;
+
+  HowIAdv   = ss "wie" ;
+  WhenIAdv  = ss "wann" ;
+  WhereIAdv = ss "war" ;
+  WhyIAdv   = ss "warum" ;
+
+  AndConj  = ss "und" ** {n = Pl} ;
+  OrConj   = ss "oder" ** {n = Sg} ;
+  BothAnd  = sd2 "sowohl" ["als auch"] ** {n = Pl} ;
+  EitherOr = sd2 "entweder" "oder" ** {n = Sg} ;
+  NeitherNor = sd2 "weder" "noch" ** {n = Sg} ;
+  IfSubj   = ss "wenn" ;
+  WhenSubj = ss "wenn" ;
+
+  PhrYes = ss ["Ja ."] ;
+  PhrNo = ss ["Nein ."] ;
+
+  VeryAdv = ss "sehr" ;
+  TooAdv = ss "zu" ;
+  OtherwiseAdv = ss "sonst" ;
+  ThereforeAdv = ss "deshalb" ;
+
+
+
+  CanVV     = 
+    mkVerbSimple (verbSehen "können" "kann" "gekonnt")  ** {isAux = True} ; ---
+  CanKnowVV = 
+    mkVerbSimple (verbSehen "können" "kann" "gekonnt")  ** {isAux = True} ; ---
+  MustVV    = 
+    mkVerbSimple (verbSehen "müssen" "muss" "gemusst")  ** {isAux = True} ; ---
+  WantVV    = 
+    mkVerbSimple (verbSehen "wollen" "will" "gewollt")  ** {isAux = True} ; ---
+
+
+  EverywhereNP = ss "überall" ;
+  SomewhereNP = ss "irgendwo" ;
+  NowhereNP = ss "nirgends" ;
+
+  AlthoughSubj = ss "obwohl" ;
+
+  AlmostAdv = ss "fast" ;
+  QuiteAdv = ss "ziemlich" ;
+
+  InPrep = mkPrep "in" Dat ;
+  OnPrep = mkPrep "auf" Dat ;
+  ToPrep = mkPrep "nach" Dat ;
+  ThroughPrep = mkPrep "durch" Acc ;
+  AbovePrep = mkPrep "über" Dat ;
+  UnderPrep = mkPrep "unter" Dat ;
+  InFrontPrep = mkPrep "vor" Dat ;
+  BehindPrep = mkPrep "hinter" Dat ;
+  BetweenPrep = mkPrep "zwischen" Dat ;
+  FromPrep = mkPrep "aus" Dat ;
+  BeforePrep = mkPrep "vor" Dat ;
+  DuringPrep = mkPrep "während" Gen ;
+  AfterPrep = mkPrep "nach" Dat ;
+  WithPrep = mkPrep "mit" Dat ;
+  WithoutPrep = mkPrep "ohne" Acc ;
+  ByMeansPrep = mkPrep "mit" Dat ;
+  PartPrep = mkPrep "von" Dat ;
+  AgentPrep = mkPrep "durch" Acc ;
+
+} ;

lib/resource-0.6/german/TestResourceGer.gf

@@ -0,0 +1,54 @@
+-- use this path to read the grammar from the same directory
+--# -path=.:../abstract:../../prelude
+
+concrete TestResourceGer of TestResource = StructuralGer ** open SyntaxGer in {
+
+flags startcat=Phr ; lexer=text ; parser=chart ; unlexer=text ;
+
+-- a random sample from the lexicon
+
+lin
+  Big = adjCompReg3 "gross" "grösser" "grösst";
+  Small = adjCompReg "klein" ;
+  Happy = adjCompReg "glücklich" ;
+  Old = adjCompReg3 "alt" "älter" "ältest";
+  Young = adjCompReg3 "jung" "jünger" "jüngst";
+  American = adjReg "Amerikanisch" ;
+  Finnish = adjReg "Finnisch" ;
+  Married = adjReg "verheiratet" ** {s2 = "mit" ; c = Dat} ;
+  Man = declN2u "Mann" "Männer" ;
+  Woman = declN1 "Frau" ;
+  Bottle = declN1e "Flasche" ;
+  Wine = declN2 "Wein" ;
+  Car = declNs "Auto" ;
+  House = declN3uS "Haus" "Häuser" ;
+  Light = declN3 "Licht" ;
+  Bar = declNs "Bar" ;
+  Walk = mkVerbSimple (verbLaufen "gehen" "geht" "gegangen") ;
+  Run = mkVerbSimple (verbLaufen "laufen" "läuft" "gelaufen") ; 
+  Say = mkVerbSimple (regVerb "sagen") ;
+  Prove = mkVerbSimple (regVerb "beweisen") ;
+  Send = mkTransVerb (mkVerbSimple (verbLaufen "senden" "sendet" "gesandt")) [] Acc;
+  Drink = transDir (mkVerbSimple (verbLaufen "trinken" "trinkt" "getrunken")) ;
+  Love = mkTransVerb (mkVerbSimple (regVerb "lieben")) [] Acc ;
+  Wait = mkTransVerb (mkVerbSimple (verbWarten "warten")) "auf" Acc ;
+  Give = mkDitransVerb 
+           (mkVerbSimple (verbLaufen "geben" "gibt" "gegeben")) [] Dat [] Acc ;
+  Prefer = mkDitransVerb 
+           (mkVerb (verbLaufen "ziehen" "zieht" "gezogen") "vor") [] Acc "vor" Dat ;
+  Mother = mkFunC (n2n (declN2uF "Mutter" "Mütter")) "von" Dat ;
+  Uncle = mkFunC (n2n (declN2i "Onkel")) "von" Dat ;
+  Connection = mkFunC (n2n (declN1 "Verbindung")) "von" Dat ** 
+                                     {s3 = "nach" ; c2 = Dat} ;
+
+  Always = mkAdverb "immer" ;
+  Well = mkAdverb "gut" ;
+
+  SwitchOn  = mkTransVerb (mkVerb (verbWarten "schalten") "auf") [] Acc  ;
+  SwitchOff = mkTransVerb (mkVerb (verbWarten "schalten") "aus") [] Acc  ;
+
+  John = mkProperName "Johann" ;
+  Mary = mkProperName "Maria" ;
+
+} ;
+

lib/resource-0.6/german/TypesGer.gf

@@ -0,0 +1,98 @@
+--1 German Word Classes and Morphological Parameters
+--
+-- This is a resource module for German morphology, defining the
+-- morphological parameters and word classes of German. It is so far only
+-- complete w.r.t. the syntax part of the resource grammar.
+-- It does not include those parameters that are not needed for
+-- analysing individual words: such parameters are defined in syntax modules.
+--
+
+resource TypesGer = open Prelude in {
+
+--2 Enumerated parameter types 
+--
+-- These types are the ones found in school grammars.
+-- Their parameter values are atomic.
+
+param 
+  Number = Sg | Pl ;
+  Gender = Masc | Fem | Neut ;
+  Person = P1 | P2 | P3 ;
+  Case   = Nom | Acc | Dat | Gen ;
+  Adjf   = Strong | Weak ;          -- the main division in adjective declension
+  Order  = Main | Inv | Sub ;       -- word order: direct, indirect, subordinate
+
+-- For abstraction and API compatibility, we define two synonyms:
+
+oper 
+  singular = Sg ; 
+  plural = Pl ;
+
+--2 Word classes and hierarchical parameter types
+--
+-- Real parameter types (i.e. ones on which words and phrases depend) 
+-- are mostly hierarchical. The alternative is cross-products of
+-- simple parameters, but this cannot be always used since it overgenerates.
+--
+
+--3 Common nouns
+--
+-- Common nouns are inflected in number and case and they have an inherent gender.
+
+  CommNoun : Type = {s : Number => Case => Str ; g : Gender} ;
+
+--3 Pronouns
+--
+-- Pronouns are an example - the worst-case one of noun phrases,
+-- which are properly defined in $syntax.Deu.gf$.
+-- Their inflection tables has, in addition to the normal genitive,
+-- the possessive forms, which are inflected like determiners.
+
+param
+  NPForm = NPCase Case | NPPoss GenNum Case ;
+
+--3 Adjectives
+--
+-- Adjectives are a very complex class, and the full table has as many as
+-- 99 different forms. The major division is between the comparison degrees.
+-- There is no gender distinction in the plural, 
+-- and the predicative forms ("X ist Adj") are not inflected.
+
+param
+  GenNum = GSg Gender | GPl ;
+  AForm  = APred | AMod Adjf GenNum Case ;  
+
+oper
+  Adjective : Type = {s : AForm => Str} ;
+  AdjComp : Type = {s : Degree => AForm => Str} ;
+
+-- Comparison of adjectives:
+
+param Degree = Pos | Comp | Sup ;
+
+--3 Verbs 
+--
+-- We have a reduced conjugation with only the present tense infinitive, 
+-- indicative, and imperative forms, and past participles.
+
+param VForm = VInf | VInd Number Person | VImp Number | VPart AForm ;
+
+oper Verbum : Type = VForm => Str ;
+
+-- On the general level, we have to account for composite verbs as well, 
+-- such as "aus" + "sehen" etc.
+
+  Particle = Str ;
+
+  Verb = {s : Verbum ; s2 : Particle} ;
+
+
+--2 Prepositions
+--
+-- We define prepositions simply as strings. Thus we do not capture the
+-- contractions "vom", "ins", etc. To define them in GF grammar we would need
+-- to introduce a parameter system, which we postpone.
+
+  Preposition = Str ;
+
+} ;