completed Translate grammars for all 8 languages; a Makefile entry for them; updated doc/translation.html. What remains to do is to make the new documentation facilities (GF-driven, in the Documentation modules) available in the Android app, so that the Parse* modules can be retired from translation tasks.

2026-04-25 20:42:50 -06:00 · 2014-01-21 08:20:46 +00:00
parent 370296c0ba
commit 9b986255bf
9 changed files with 63552 additions and 14 deletions
--- a/lib/src/translator/TranslateFre.gf
+++ b/lib/src/translator/TranslateFre.gf
@@ -0,0 +1,59 @@
+--# -path=.:../French:../abstract:../romance:alltenses
+concrete TranslateFre of Translate = 
+  TenseFre,
+  NounFre - [PPartNP],
+  AdjectiveFre,
+  NumeralFre,
+  SymbolFre [PN, Symb, String, CN, Card, NP, MkSymb, SymbPN, CNNumNP],
+  ConjunctionFre,
+  VerbFre - [SlashV2V, PassV2, UseCopula, ComplVV],
+  AdverbFre,
+  PhraseFre,
+  SentenceFre,
+  QuestionFre - [QuestCl, QuestIAdv], -- more variants here
+  RelativeFre,
+  IdiomFre [NP, VP, Tense, Cl, ProgrVP, ExistNP, SelfAdvVP, SelfAdVVP, SelfNP],
+  ConstructionFre,
+  DocumentationFre,
+  ExtensionsFre,
+  DictionaryFre ** 
+open PhonoFre, MorphoFre, ResFre, CommonRomance, ParadigmsFre, SyntaxFre, Prelude, (G = GrammarFre) in {
+
+flags
+  literal=Symb ;
+  coding = utf8 ;
+
+-- overrides from Lang
+
+lin
+  QuestCl cl = 
+    {s = \\t,a,p =>                             -- est-ce qu'il dort ?
+            let cls = cl.s ! DDir ! t ! a ! p 
+            in table {
+              QDir   => "est-ce" ++ elisQue ++ cls ! Indic ;
+              QIndir => subjIf ++ cls ! Indic
+              }
+      }
+  | {s = \\t,a,p =>                             -- dort-il ?
+            let cls = cl.s ! DInv ! t ! a ! p 
+            in table {
+              QDir   => cls ! Indic ;
+              QIndir => subjIf ++ cls ! Indic
+              }
+      }
+  | G.QuestCl cl                                -- il dort ?
+  ;
+
+
+  QuestIAdv iadv cl = 
+     G.QuestIAdv iadv cl                       -- où dort-il
+   | {s = \\t,a,p,q =>                         -- où est-ce qu'il dort        
+            let 
+              ord = DDir ;
+              cls = cl.s ! ord ! t ! a ! p ! Indic ;
+              why = iadv.s
+            in why ++ "est-ce" ++ elisQue ++ cls
+      } ;
+
+
+}