diff --git a/examples/query/small/Query.gf b/examples/query/small/Query.gf
new file mode 100644
index 000000000..532dc6a8e
--- /dev/null
+++ b/examples/query/small/Query.gf
@@ -0,0 +1,111 @@
+abstract Query = {
+
+flags
+  startcat = Move ;
+
+-- general query language, which can be specialized with any lexicon
+
+cat
+  Move ;     -- top-level utterance,    e.g. "give me all Bulgarian persons that work at Google"
+  Query ;
+  Answer ;
+  Set ;      -- the set requested,      e.g. "all persons"
+  Relation ; -- something of something, e.g. "subregion of Bulgaria"
+  Kind ;     -- type of things,         e.g. "person"
+  Property ; -- property of things,     e.g. "employed at Google"
+  Individual ; -- one entity,           e.g. "Google"
+  Activity ;   -- action property,      e.g. "work at Google"
+  Name ;       -- person, company...    e.g. "Eric Schmidt"
+  Loc ;
+  Org ;
+  Pers ;
+  [Individual] {2} ; -- list of entities, e.g. "Larry Page, Sergey Brin"
+
+fun
+  MQuery  : Query -> Move ;
+  MAnswer : Answer -> Move ;
+
+  QSet    : Set  -> Query ;  -- (give me | what are | which are | ) (S | the names of S | S's names)
+  QWhere  : Set  -> Query ;  -- where are S
+  QInfo   : Set  -> Query ;  -- (give me | ) (information about | all about) S
+  QCalled : Individual -> Query ; -- how is X (also | otherwise) (called | named | known) ;
+
+  AKind  : Set  -> Kind     -> Answer ; -- S is a K
+  AProp  : Set  -> Property -> Answer ; -- S is P
+  AAct   : Set  -> Activity -> Answer ; -- S As
+
+  SAll   : Kind -> Set ;  -- all Ks | the Ks
+  SOne   : Kind -> Set ;  -- one K
+  SIndef : Kind -> Set ;  -- a K
+  SPlural : Kind -> Set ;  -- Ks
+  SOther : Kind -> Set ;  -- other Ks
+  SInd   : Individual  -> Set ;  -- X
+  SInds  : [Individual] -> Set ; -- X and Y
+
+  KRelSet  : Relation -> Set -> Kind ; -- R of S | S's R
+  KRelsSet : Relation -> Relation -> Set -> Kind ; -- R and Q of S
+  KRelKind : Kind -> Relation -> Set -> Kind ; -- K that is R of S
+  KRelPair : Kind -> Relation -> Kind ; -- S's with their R's
+  KProp    : Property -> Kind -> Kind ; -- P K | K that is P
+  KAct     : Activity -> Kind -> Kind ; -- K that Ps
+  KRel     : Relation -> Kind ; -- R ---??
+
+  IName    : Name -> Individual ;
+
+  NLoc : Loc -> Name ;
+  NOrg : Org -> Name ;
+  NPers : Pers -> Name ;
+
+  ACalled  : [Individual] -> Activity ;
+
+
+-- the test lexicon
+
+cat
+  Country ;
+  JobTitle ;
+fun
+  NCountry : Country -> Name ;
+  PCountry : Country -> Property ;
+
+  Located : Loc -> Property ;
+  Employed : Org -> Property ;
+
+  Work : Org -> Activity ;
+  HaveTitle : JobTitle -> Org -> Activity ;
+
+  Organization : Kind ;
+  Place : Kind ;
+  Person : Kind ;
+
+  Location : Relation ;
+  Region : Relation ;
+  Subregion : Relation ;
+
+  RName     : Relation ;
+  RNickname : Relation ;
+
+-- JobTitles
+   JobTitle1 : JobTitle ;
+   JobTitle2 : JobTitle ;
+   JobTitle3 : JobTitle ;
+   JobTitle4 : JobTitle ;
+
+-- Locations
+   Location1 : Loc ;
+   Location2 : Loc ;
+   Location3 : Loc ;
+   Location4 : Loc ;
+
+-- Organizations
+   Organization1 : Org ;
+   Organization2 : Org ;
+   Organization3 : Org ;
+   Organization4 : Org ;
+
+-- Persons
+   Person1 : Pers ;
+   Person2 : Pers ;
+   Person3 : Pers ;
+   Person4 : Pers ;
+}
diff --git a/examples/query/small/QueryEng.gf b/examples/query/small/QueryEng.gf
new file mode 100644
index 000000000..bce50ffce
--- /dev/null
+++ b/examples/query/small/QueryEng.gf
@@ -0,0 +1,179 @@
+--# -path=.:alltenses
+
+concrete QueryEng of Query = open
+  ParadigmsEng,
+  IrregEng,
+  SyntaxEng,
+  ExtraEng,
+  (L = LangEng),
+  Prelude
+in {
+
+lincat
+  Move = Utt ; ---- Text ;
+  Query = Utt ;
+  Answer = Utt ;
+  Set = NP ;
+  Relation = {cn : CN ; prep : Prep} ;
+  Kind = CN ;
+  Property = AP ; ---- {vp : VP ; typ : PropTyp} ;
+  Individual = NP ;
+  Activity = VP ;
+  Name = NP ;
+  Loc = NP ;
+  Org = NP ;
+  Pers = NP ;
+  [Individual] = [NP] ;
+
+lin
+  MQuery  q = q ; ---- mkText (mkPhr q) questMarkPunct ;
+  MAnswer a = a ; ---- mkText (mkPhr a) fullStopPunct ;
+
+  QSet s =
+    let
+     ss : NP = s
+        | mkNP (mkNP thePl_Det L.name_N) (mkAdv possess_Prep s)
+        ---- s's names
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP whatSg_IP) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP (L.IdetIP (mkIDet which_IQuant))) ss))
+    | mkUtt ss ;
+
+  QWhere s = mkUtt (mkQS (mkQCl where_IAdv s)) ;
+  QInfo  s =
+    let
+      info : NP = mkNP (all_NP | (mkNP information_N)) (mkAdv about_Prep s) ;
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) info))
+    | mkUtt info ;
+
+  QCalled i = mkUtt (mkQS (mkQCl how_IAdv (mkCl i (mkVP also_AdV (mkVP called_A))))) ;
+
+  AKind s k = mkUtt (mkCl s (mkNP aPl_Det k)) ; ---- a, fun of s
+  AProp s p = mkUtt (mkCl s p) ;
+  AAct s p = mkUtt (mkCl s p) ;
+
+  SAll k = mkNP all_Predet (mkNP aPl_Det k) | mkNP thePl_Det k ;
+  SOne k = mkNP n1_Numeral k ;
+  SIndef k = mkNP a_Det k ;
+  SPlural k = mkNP aPl_Det k ;
+  SOther k = mkNP aPl_Det (mkCN other_A k) ;
+  SInd i = i ;
+  SInds is = mkNP and_Conj is ;
+
+  KRelSet r s =
+     mkCN r.cn (mkAdv r.prep s) ;
+     ---- | S's R
+
+----  KRelsSet r q s =
+----     mkCN r.cn (mkAdv r.prep s) ;
+
+  KRelKind k r s =
+    mkCN k (mkRS (mkRCl that_RP (mkVP (mkNP aPl_Det (mkCN r.cn (mkAdv r.prep s)))))) ;
+
+  KRelPair k r = mkCN k (mkAdv with_Prep (mkNP (mkQuant they_Pron) plNum r.cn)) ;
+  KProp p k =
+     mkCN p k
+   | mkCN k (mkRS (mkRCl that_RP (mkVP p))) ;
+  KAct p k =
+     mkCN k (mkRS (mkRCl that_RP p)) ;
+  KRel r = r.cn ;
+
+  IName n = n ;
+  NLoc n = n ;
+  NOrg n = n ;
+  NPers n = n;
+
+  ACalled is = mkVP also_AdV (mkVP (mkAP (mkA2 called_A []) (mkNP or_Conj is))) ;
+
+  BaseIndividual = mkListNP ;
+  ConsIndividual = mkListNP ;
+
+oper
+-- structural words
+  about_Prep = mkPrep "about" ;
+  all_NP = mkNP (mkPN "all") ; ---
+  also_AdV = mkAdV "also" | mkAdV "otherwise" ;
+  as_Prep = mkPrep "as" ;
+  at_Prep = mkPrep "at" ;
+  called_A = mkA "called" | mkA "named" ;
+  give_V3 = mkV3 give_V ;
+  information_N = mkN "information" ;
+  other_A = mkA "other" ;
+
+-- lexical constructors
+  mkName : Str -> NP =
+    \s -> mkNP (mkPN s) ;
+  mkRelation : Str -> {cn : CN ; prep : Prep} =
+    \s -> {cn = mkCN (mkN s) ; prep = possess_Prep} ;
+
+-- lexicon
+
+lincat
+  Country = {np : NP ; a : A} ;
+  JobTitle = CN ;
+lin
+  NCountry c = c.np ;
+  PCountry c = mkAP c.a ;
+
+  Located i =
+      mkAP (mkA2 (mkA "located") in_Prep) i
+    | mkAP (mkA2 (mkA "situated") in_Prep) i ;
+
+  Employed i =
+      mkAP (mkA2 (mkA "employed") by8agent_Prep) i
+    | mkAP (mkA2 (mkA "paid") by8agent_Prep) i
+    | mkAP (mkA2 (mkA "active") at_Prep) i
+    | mkAP (mkA2 (mkA "professionally active") at_Prep) i ;
+
+  Work i =
+      mkVP (mkV2 (mkV "work") at_Prep) i
+    | mkVP (mkV2 (mkV "collaborate") in_Prep) i ;
+
+  HaveTitle t i =
+      mkVP (mkVP (mkAP (mkA2 (mkA "employed") as_Prep) (mkNP t))) (mkAdv at_Prep i)
+    | mkVP (mkVP (mkV2 (mkV "work") as_Prep) (mkNP t)) (mkAdv at_Prep i) ;
+--    | mkVP (mkVP have_V2 (mkNP the_Det (mkCN (mkN2 (mkN "title")) (mkNP t)))) (mkAdv at_Prep i) ;
+
+  Organization = mkCN (mkN "organization") ;
+  Place = mkCN (mkN "place") ;
+  Person =
+      mkCN (mkN "person" "people")
+    | mkCN (mkN "person") ;
+
+  Location = mkRelation "location" ;
+  Region = mkRelation "region" ;
+  Subregion = mkRelation "subregion" ;
+  RName = mkRelation "name" ;
+  RNickname = mkRelation "nickname" ;
+
+-- JobTitles
+  JobTitle1 = mkCN (mkN "'JobTitle1") ;
+  JobTitle2 = mkCN (mkN "'JobTitle2") ;
+  JobTitle3 = mkCN (mkN "'JobTitle3") ;
+  JobTitle4 = mkCN (mkN "'JobTitle4") ;
+
+-- Locations
+  Location1 = mkName "'Location1" ;
+  Location2 = mkName "'Location2" ;
+  Location3 = mkName "'Location3" ;
+  Location4 = mkName "'Location4" ;
+
+-- Organizations
+  Organization1 = mkName "'Organization1" ;
+  Organization2 = mkName "'Organization2" ;
+  Organization3 = mkName "'Organization3" ;
+  Organization4 = mkName "'Organization4" ;
+
+-- Persons
+  Person1 = mkName "'Person1" ;
+  Person2 = mkName "'Person2" ;
+  Person3 = mkName "'Person3" ;
+  Person4 = mkName "'Person4" ;
+
+oper
+  mkCountry : Str -> Str -> {np : NP ; a : A} =
+    \n,a -> {np = mkNP (mkPN n) ; a = mkA a} ;
+
+}
diff --git a/examples/query/small/QueryFin.gf b/examples/query/small/QueryFin.gf
new file mode 100644
index 000000000..8d8b6c426
--- /dev/null
+++ b/examples/query/small/QueryFin.gf
@@ -0,0 +1,172 @@
+--# -path=.:alltenses
+
+concrete QueryFin of Query = open
+  ParadigmsFin,
+  SyntaxFin,
+  ExtraFin,
+  (L = LangFin),
+  Prelude
+in {
+
+lincat
+  Move = Utt ; ---- Text ;
+  Query = Utt ;
+  Answer = Utt ;
+  Set = NP ;
+  Relation = {cn : CN ; prep : Prep} ;
+  Kind = CN ;
+  Property = AP ; ---- {vp : VP ; typ : PropTyp} ;
+  Individual = NP ;
+  Activity = VP ;
+  Name = NP ;
+  Loc = NP ;
+  Org = NP ;
+  Pers = NP ;
+  [Individual] = [NP] ;
+
+lin
+  MQuery  q = q ; ---- mkText (mkPhr q) questMarkPunct ;
+  MAnswer a = a ; ---- mkText (mkPhr a) fullStopPunct ;
+
+  QSet s =
+    let
+     ss : NP = s
+        | mkNP (mkNP thePl_Det L.name_N) (mkAdv possess_Prep s)
+        ---- s's names
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP whatSg_IP) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP (L.IdetIP (mkIDet which_IQuant))) ss))
+    | mkUtt ss ;
+
+  QWhere s = mkUtt (mkQS (mkQCl where_IAdv s)) ;
+  QInfo  s =
+    let
+      info : NP = mkNP (all_NP | (mkNP information_N)) (mkAdv about_Prep s) ;
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) info))
+    | mkUtt info ;
+
+  QCalled i = mkUtt (mkQS (mkQCl how_IAdv (mkCl i (mkVP also_AdV (mkVP called_A))))) ;
+
+  AKind s k = mkUtt (mkCl s (mkNP aPl_Det k)) ; ---- a, fun of s
+  AProp s p = mkUtt (mkCl s p) ;
+  AAct s p = mkUtt (mkCl s p) ;
+
+  SAll k = mkNP all_Predet (mkNP aPl_Det k) | mkNP thePl_Det k ;
+  SOne k = mkNP n1_Numeral k ;
+  SIndef k = mkNP a_Det k ;
+  SPlural k = mkNP aPl_Det k ;
+  SOther k = mkNP aPl_Det (mkCN other_A k) ;
+  SInd i = i ;
+  SInds is = mkNP and_Conj is ;
+
+  KRelSet r s =
+     mkCN r.cn (mkAdv r.prep s) ;
+     ---- | S's R
+
+----  KRelsSet r q s =
+----     mkCN r.cn (mkAdv r.prep s) ;
+
+  KRelKind k r s =
+    mkCN k (mkRS (mkRCl that_RP (mkVP (mkNP aPl_Det (mkCN r.cn (mkAdv r.prep s)))))) ;
+
+  KRelPair k r = mkCN k (mkAdv with_Prep (mkNP (mkQuant they_Pron) plNum r.cn)) ;
+  KProp p k =
+     mkCN p k
+   | mkCN k (mkRS (mkRCl that_RP (mkVP p))) ;
+  KAct p k =
+     mkCN k (mkRS (mkRCl that_RP p)) ;
+  KRel r = r.cn ;
+
+  IName n = n ;
+  NLoc n = n ;
+  NOrg n = n ;
+  NPers n = n;
+
+  ACalled is = mkVP also_AdV (mkVP (mkAP (mkA2 called_A (casePrep translative)) (mkNP or_Conj is))) ;
+
+  BaseIndividual = mkListNP ;
+  ConsIndividual = mkListNP ;
+
+oper
+-- structural words
+  about_Prep = casePrep elative ;
+  all_NP = mkNP (mkPN (mkN "kaikki" "kaiken")) ; ---
+  also_AdV = ss "myös" ;
+  as_Prep = casePrep essive ;
+  at_Prep = casePrep adessive ;
+  called_A = mkA "kutsuttu" ;
+  give_V3 = mkV3 (mkV "antaa") (casePrep allative) (casePrep nominative) ;
+  information_N = mkN "tieto" ;
+  other_A = mkA "muu" ;
+  that_RP = which_RP ;
+
+-- lexical constructors
+  mkName : Str -> NP =
+    \s -> mkNP (mkPN s) ;
+  mkRelation : Str -> {cn : CN ; prep : Prep} =
+    \s -> {cn = mkCN (mkN s) ; prep = possess_Prep} ;
+
+-- lexicon
+
+lincat
+  Country = {np : NP ; a : A} ;
+  JobTitle = CN ;
+lin
+  NCountry c = c.np ;
+  PCountry c = mkAP c.a ;
+
+  Located i =
+      mkAP (mkA2 (mkA "sijaitseva") in_Prep) i ;
+
+  Employed i = mkAP (mkA2 (mkA "töissä") at_Prep) i ;
+
+  Work i =
+      mkVP (mkV2 (mkV "työskennellä") at_Prep) i ;
+
+  HaveTitle t i =
+      mkVP (mkVP (mkNP t)) (mkAdv at_Prep i) ;
+--    | mkVP (mkVP (mkV2 (mkV "work") as_Prep) (mkNP t)) (mkAdv at_Prep i) ;
+--    | mkVP (mkVP have_V2 (mkNP the_Det (mkCN (mkN2 (mkN "title")) (mkNP t)))) (mkAdv at_Prep i) ;
+
+  Organization = mkCN (mkN "organisaatio" "organisaatioita") ;
+  Place = mkCN (mkN "paikka") ;
+  Person =
+      mkCN (mkN "henkilö" "henkilöitä") ;
+
+  Location = mkRelation "sijainti" ;
+  Region = mkRelation "alue" ;
+  Subregion = mkRelation "alue" ;
+  RName = mkRelation "nimi" ;
+  RNickname = mkRelation "lempinimi" ;
+
+-- JobTitles
+  JobTitle1 = mkCN (mkN "'JobTitle1") ;
+  JobTitle2 = mkCN (mkN "'JobTitle2") ;
+  JobTitle3 = mkCN (mkN "'JobTitle3") ;
+  JobTitle4 = mkCN (mkN "'JobTitle4") ;
+
+-- Locations
+  Location1 = mkName "'Location1" ;
+  Location2 = mkName "'Location2" ;
+  Location3 = mkName "'Location3" ;
+  Location4 = mkName "'Location4" ;
+
+-- Organizations
+  Organization1 = mkName "'Organization1" ;
+  Organization2 = mkName "'Organization2" ;
+  Organization3 = mkName "'Organization3" ;
+  Organization4 = mkName "'Organization4" ;
+
+-- Persons
+  Person1 = mkName "'Person1" ;
+  Person2 = mkName "'Person2" ;
+  Person3 = mkName "'Person3" ;
+  Person4 = mkName "'Person4" ;
+
+oper
+  mkCountry : Str -> Str -> {np : NP ; a : A} =
+    \n,a -> {np = mkNP (mkPN n) ; a = mkA a} ;
+
+}
diff --git a/examples/query/small/QuerySwe.gf b/examples/query/small/QuerySwe.gf
new file mode 100644
index 000000000..17f89352c
--- /dev/null
+++ b/examples/query/small/QuerySwe.gf
@@ -0,0 +1,185 @@
+--# -path=.:alltenses
+
+concrete QuerySwe of Query = open
+  ParadigmsSwe,
+  IrregSwe,
+  SyntaxSwe,
+  ExtraSwe,
+  (M = MakeStructuralSwe),
+  (L = LangSwe),
+  Prelude
+in {
+
+flags coding = utf8 ;
+
+lincat
+  Move = Utt ; ---- Text ;
+  Query = Utt ;
+  Answer = Utt ;
+  Set = NP ;
+  Relation = {cn : CN ; prep : Prep} ;
+  Kind = CN ;
+  Property = AP ; ---- {vp : VP ; typ : PropTyp} ;
+  Individual = NP ;
+  Activity = VP ;
+  Name = NP ;
+  Loc = NP ;
+  Org = NP ;
+  Pers = NP ;
+  [Individual] = [NP] ;
+
+lin
+  MQuery  q = q ; ---- mkText (mkPhr q) questMarkPunct ;
+  MAnswer a = a ; ---- mkText (mkPhr a) fullStopPunct ;
+
+  QSet s =
+    let
+     ss : NP = s
+        | mkNP (mkNP thePl_Det L.name_N) (mkAdv on_Prep s)
+        ---- s's names
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP whatSg_IP) ss))
+    | mkUtt (mkQS (mkQCl (L.CompIP (L.IdetIP (mkIDet which_IQuant))) ss))
+    | mkUtt ss ;
+
+  QWhere s = mkUtt (mkQS (mkQCl where_IAdv s)) ;
+  QInfo  s =
+    let
+      info : NP = mkNP (all_NP | (mkNP information_N)) (mkAdv about_Prep s) ;
+    in
+      mkUtt (mkImp (mkVP give_V3 (mkNP i_Pron) info))
+    | mkUtt info ;
+
+  QCalled i = mkUtt (mkQS (mkQCl how_IAdv (mkCl i (mkVP also_AdV (mkVP called_A))))) ;
+
+  AKind s k = mkUtt (mkCl s (mkNP aPl_Det k)) ; ---- a, fun of s
+  AProp s p = mkUtt (mkCl s p) ;
+  AAct s p = mkUtt (mkCl s p) ;
+
+  SAll k = mkNP all_Predet (mkNP aPl_Det k) | mkNP thePl_Det k ;
+  SOne k = mkNP n1_Numeral k ;
+  SIndef k = mkNP a_Det k ;
+  SPlural k = mkNP aPl_Det k ;
+  SOther k = mkNP aPl_Det (mkCN other_A k) ;
+  SInd i = i ;
+  SInds is = mkNP and_Conj is ;
+
+  KRelSet r s =
+     mkCN r.cn (mkAdv r.prep s) ;
+     ---- | S's R
+
+----  KRelsSet r q s =
+----     mkCN r.cn (mkAdv r.prep s) ;
+
+  KRelKind k r s =
+    mkCN k (mkRS (mkRCl that_RP (mkVP (mkNP aPl_Det (mkCN r.cn (mkAdv r.prep s)))))) ;
+
+  KRelPair k r = mkCN k (mkAdv with_Prep (sina r.cn)) ;
+  KProp p k =
+     mkCN p k
+   | mkCN k (mkRS (mkRCl that_RP (mkVP p))) ;
+  KAct p k =
+     mkCN k (mkRS (mkRCl that_RP p)) ;
+  KRel r = r.cn ;
+
+  IName n = n ;
+  NLoc n = n ;
+  NOrg n = n ;
+  NPers n = n;
+
+  ACalled is = mkVP also_AdV (mkVP (mkAP (mkA2 called_A for_Prep) (mkNP or_Conj is))) ;
+
+  BaseIndividual = mkListNP ;
+  ConsIndividual = mkListNP ;
+
+oper
+-- structural words
+  about_Prep = mkPrep "om" ;
+  all_NP = mkNP (mkPN "allt" neutrum) ; ---
+  also_AdV = mkAdV "också" | mkAdV "annars" ;
+  as_Prep = mkPrep "som" ;
+  at_Prep = mkPrep "på" ;
+  called_A = mkA "kallad" "kallat" "kallade" ;
+  give_V3 = mkV3 giva_V ;
+  information_N = mkN "information" "informationer" ;
+  other_A = compoundA (mkA "annan" "annat" "andra" "andra" "andra") ;
+  that_RP = which_RP ;
+
+  sina : CN -> NP = \cn -> mkNP (M.mkPredet "sin" "sitt" "sina") (mkNP a_Quant plNum cn) ; ---- should be in ExtraSwe
+
+-- lexical constructors
+  mkName : Str -> NP =
+    \s -> mkNP (mkPN s) ;
+  mkRelation : N -> Prep -> {cn : CN ; prep : Prep} =
+    \s,p -> {cn = mkCN s ; prep = p} ;
+
+-- lexicon
+
+lincat
+  Country = {np : NP ; a : A} ;
+  JobTitle = CN ;
+lin
+  NCountry c = c.np ;
+  PCountry c = mkAP c.a ;
+
+  Located i =
+      mkAP (mkA2 (mkA "belägen" "beläget") in_Prep) i ;
+--    | mkAP (mkA2 (mkA "situated") in_Prep) i ;
+
+  Employed i =
+      mkAP (mkA2 (mkA "anställd") by8agent_Prep) i
+--    | mkAP (mkA2 (mkA "paid") by8agent_Prep) i
+--    | mkAP (mkA2 (mkA "aktiv") at_Prep) i
+    | mkAP (mkA2 (mkA "professionellt aktiv") at_Prep) i ;
+
+  Work i =
+      mkVP (mkV2 (mkV "jobba") at_Prep) i
+    | mkVP (mkV2 (mkV "arbeta") in_Prep) i ;
+
+  HaveTitle t i =
+      mkVP (mkVP (mkAP (mkA2 (mkA "anställd") as_Prep) (mkNP t))) (mkAdv at_Prep i)
+    | mkVP (mkVP (mkV2 (mkV "jobba") as_Prep) (mkNP t)) (mkAdv at_Prep i) ;
+--    | mkVP (mkVP have_V2 (mkNP the_Det (mkCN (mkN2 (mkN "titel" "titlar") po) (mkNP t)))) (mkAdv at_Prep i) ;
+
+  Organization = mkCN (mkN "organisation" "organisationer") ;
+  Place = mkCN (mkN "plats" "platser") ;
+  Person =
+      mkCN (mkN "person" "personer") ;
+--    | mkCN (mkN "person" "folk") ;
+
+  Location = mkRelation (mkN "läge" "lägen") possess_Prep ;
+  Region = mkRelation (mkN "region" "regioner") in_Prep ;
+  Subregion = mkRelation (mkN "delregion" "delregioner") in_Prep ;
+  RName = mkRelation (mkN "namn" "namn") on_Prep ;
+  RNickname = mkRelation (mkN "tilläggsnamn" "tilläggsnamn")  on_Prep ;
+
+-- JobTitles
+  JobTitle1 = mkCN (mkN "'JobTitle1") ;
+  JobTitle2 = mkCN (mkN "'JobTitle2") ;
+  JobTitle3 = mkCN (mkN "'JobTitle3") ;
+  JobTitle4 = mkCN (mkN "'JobTitle4") ;
+
+-- Locations
+  Location1 = mkName "'Location1" ;
+  Location2 = mkName "'Location2" ;
+  Location3 = mkName "'Location3" ;
+  Location4 = mkName "'Location4" ;
+
+-- Organizations
+  Organization1 = mkName "'Organization1" ;
+  Organization2 = mkName "'Organization2" ;
+  Organization3 = mkName "'Organization3" ;
+  Organization4 = mkName "'Organization4" ;
+
+-- Persons
+  Person1 = mkName "'Person1" ;
+  Person2 = mkName "'Person2" ;
+  Person3 = mkName "'Person3" ;
+  Person4 = mkName "'Person4" ;
+
+oper
+  mkCountry : Str -> Str -> {np : NP ; a : A} =
+    \n,a -> {np = mkNP (mkPN n neutrum) ; a = mkA a} ;
+
+}