mirror of
https://github.com/GrammaticalFramework/gf-core.git
synced 2026-04-20 10:19:32 -06:00
ab3cc77656
This patch fixes a problem introduced last year when the GF shell was
refactored to allow more commands to be treated uniformly and be part
of pipes. The cc command was one of those commands, but unfortunately this
introduced a parsing problem, e.g.
> cc "last"
constant not found: last
> cc "last"++"year"
command not parsed: cc "last"++"year"
This happened because the generic command line parser in
GF.Command.{Abstract,Parse} assumes that all commands have an argument of
type PGF.Expr. Commands that expect other types of arguments have to
use PGF.showExpr combined with other conversion to the argument type they
expect. The cc command excpets a GF.Grammar.Term, and unfortunately not
all terms survice the roundtrip through PGF.Expr, in part because of
an additional hack to allow strings to be roundtripped through PGF.Expr
without adding superfluous double quotes.
To solve the problem, this patch
+ makes room for arguments of type Term in the Argument type in
GF.Command.Abstract.
+ makes a special case for the cc command in GF.Command.Parse, by
calling the partial parser 'runPartial pTerm' recently added in
GF.Grammar.Lexer and GF.Grammar.Parser. Care was taken so that
that "|" and ";" can be used both inside terms and as separators between
commands in the shell, e.g. things like the following now work:
> cc ("a"|"b") | ps -lexcode
variants { "a" ; "b" }
+ introduces a type CommandArgument that replaces [Expr] as the
type of values passed between commands in pipes. It has room for
values of type [Expr], [String] and Term, thus eliminating the need
to roundtrip through the Expr type all the time.
The hack to avoid adding superfluous quotes when strings are
roundtripped through Expr has been left in place for now,
but can probably be removed.
73 lines
1.7 KiB
Haskell
73 lines
1.7 KiB
Haskell
module GF.Command.Parse(readCommandLine, pCommand) where
|
|
|
|
import PGF(pExpr,pIdent)
|
|
import GF.Grammar.Parser(runPartial,pTerm)
|
|
import GF.Command.Abstract
|
|
|
|
import Data.Char(isDigit,isSpace)
|
|
import Control.Monad(liftM2)
|
|
import Text.ParserCombinators.ReadP
|
|
|
|
readCommandLine :: String -> Maybe CommandLine
|
|
readCommandLine s =
|
|
case [x | (x,cs) <- readP_to_S pCommandLine s, all isSpace cs] of
|
|
[x] -> Just x
|
|
_ -> Nothing
|
|
|
|
pCommandLine =
|
|
(skipSpaces >> char '-' >> char '-' >> pTheRest >> return []) -- comment
|
|
<++
|
|
(sepBy (skipSpaces >> pPipe) (skipSpaces >> char ';'))
|
|
|
|
pPipe = sepBy1 (skipSpaces >> pCommand) (skipSpaces >> char '|')
|
|
|
|
pCommand = (do
|
|
cmd <- pIdent <++ (char '%' >> fmap ('%':) pIdent)
|
|
skipSpaces
|
|
opts <- sepBy pOption skipSpaces
|
|
arg <- if getCommandOp cmd == "cc" then pArgTerm else pArgument
|
|
return (Command cmd opts arg)
|
|
)
|
|
<++ (do
|
|
char '?'
|
|
skipSpaces
|
|
c <- pSystemCommand
|
|
return (Command "sp" [OFlag "command" (VStr c)] ANoArg)
|
|
)
|
|
|
|
pOption = do
|
|
char '-'
|
|
flg <- pIdent
|
|
option (OOpt flg) (fmap (OFlag flg) (char '=' >> pValue))
|
|
|
|
pValue = do
|
|
fmap VInt (readS_to_P reads)
|
|
<++
|
|
fmap VStr (readS_to_P reads)
|
|
<++
|
|
fmap VId pFilename
|
|
|
|
pFilename = liftM2 (:) (satisfy isFileFirst) (munch (not . isSpace)) where
|
|
isFileFirst c = not (isSpace c) && not (isDigit c)
|
|
|
|
pArgument =
|
|
option ANoArg
|
|
(fmap AExpr pExpr
|
|
<++
|
|
(skipSpaces >> char '%' >> fmap AMacro pIdent))
|
|
|
|
pArgTerm = ATerm `fmap` readS_to_P sTerm
|
|
where
|
|
sTerm s = case runPartial pTerm s of
|
|
Right (s,t) -> [(t,s)]
|
|
_ -> []
|
|
|
|
pSystemCommand =
|
|
(char '"' >> (manyTill (pEsc <++ get) (char '"')))
|
|
<++
|
|
pTheRest
|
|
where
|
|
pEsc = char '\\' >> get
|
|
|
|
pTheRest = munch (const True)
|