mirror of
https://github.com/GrammaticalFramework/gf-core.git
synced 2026-04-10 13:29:32 -06:00
42 lines
1.3 KiB
Plaintext
42 lines
1.3 KiB
Plaintext
--1 Question: Questions and Interrogative Pronouns
|
|
|
|
abstract Question = Cat ** {
|
|
|
|
-- A question can be formed from a clause ('yes-no question') or
|
|
-- with an interrogative.
|
|
|
|
fun
|
|
QuestCl : Cl -> QCl ; -- does John walk
|
|
QuestVP : IP -> VP -> QCl ; -- who walks
|
|
QuestSlash : IP -> ClSlash -> QCl ; -- whom does John love
|
|
QuestIAdv : IAdv -> Cl -> QCl ; -- why does John walk
|
|
QuestIComp : IComp -> NP -> QCl ; -- where is John
|
|
|
|
-- Interrogative pronouns can be formed with interrogative
|
|
-- determiners, with or without a noun.
|
|
|
|
IdetCN : IDet -> CN -> IP ; -- which five songs
|
|
IdetIP : IDet -> IP ; -- which five
|
|
|
|
-- They can be modified with adverbs.
|
|
|
|
AdvIP : IP -> Adv -> IP ; -- who in Paris
|
|
|
|
-- Interrogative quantifiers have number forms and can take number modifiers.
|
|
|
|
IdetQuant : IQuant -> Num -> IDet ; -- which (five)
|
|
|
|
-- Interrogative adverbs can be formed prepositionally.
|
|
|
|
PrepIP : Prep -> IP -> IAdv ; -- with whom
|
|
|
|
-- Interrogative complements to copulas can be both adverbs and
|
|
-- pronouns.
|
|
|
|
CompIAdv : IAdv -> IComp ; -- where (is it)
|
|
CompIP : IP -> IComp ; -- who (is it)
|
|
|
|
-- More $IP$, $IDet$, and $IAdv$ are defined in $Structural$.
|
|
|
|
}
|