# Italian Lexical Paradigms

Last update: 2007-07-06 09:18:06 CEST

- Parameters
- Nouns
  - Relational nouns
  - Relational common noun phrases
  - Proper names and noun phrases
- Adjectives
  - Two-place adjectives
- Adverbs
- Verbs
  - Two-place verbs
  - Three-place verbs
  - Other complement patterns

Produced by gfdoc - a rudimentary GF document generator. (c) Aarne Ranta (aarne@cs.chalmers.se) 2002 under GNU GPL.

Aarne Ranta 2003

This is an API for the user of the resource grammar for adding lexical items. It gives functions for forming expressions of open categories: nouns, adjectives, verbs.

Closed categories (determiners, pronouns, conjunctions) are accessed through the resource syntax API, `Structural.gf`.

The main difference with `MorphoIta.gf` is that the types referred to are compiled resource grammar types. We have moreover had the design principle of always having existing forms, rather than stems, as string arguments of the paradigms.

The structure of functions for each word class `C` is the following: first we give a handful of patterns that aim to cover all regular cases. Then we give a worst-case function `mkC`, which serves as an escape to construct the most irregular words of type `C`. However, this function should only seldom be needed. For verbs, we have a separate module `BeschIta`, which covers the Bescherelle verb conjugations.

        resource ParadigmsIta =
          open
            (Predef=Predef),
            Prelude,
            CommonRomance,
            ResIta,
            MorphoIta,
            BeschIta,
            CatIta in {

          flags optimize=all ;

## Parameters

To abstract over gender names, we define the following identifiers.

        oper
          Gender : Type ;

          masculine : Gender ;
          feminine  : Gender ;

To abstract over number names, we define the following.

          Number : Type ;

          singular : Number ;
          plural   : Number ;

Prepositions used in many-argument functions are either strings (including the 'accusative' empty string) or strings that amalgamate with the following word (the 'genitive' di and the 'dative' a).

          Prep : Type ;

          accusative : Prep ;
          genitive   : Prep ;
          dative     : Prep ;

          mkPrep : Str -> Prep ;

The following prepositions also have special contracted forms.

          con_Prep, da_Prep, in_Prep, su_Prep : Prep ;

## Nouns

          mkN : overload {

The regular function takes the singular form and the gender, and computes the plural and the gender by a heuristic. The heuristic says that the gender is feminine for nouns ending with a, and masculine for all other words.

            mkN : (cane : Str) -> N ;

To force a different gender, give it explicitly.

            mkN : (carne : Str) -> Gender -> N ;

Worst case: give both two forms and the gender.

            mkN : (uomo,uomini : Str) -> Gender -> N ;

In compound nouns, the first part is inflected as a noun but the second part is not inflected. e.g. numero di telefono. They could be formed in syntax, but we give a shortcut here since they are frequent in lexica.

            mkN : N -> Str -> N
            } ;

### Relational nouns

Relational nouns (figlio di x) need a case and a preposition. The default is regular nouns with the genitive di.

          mkN2 : overload {
            mkN2 : Str -> N2 ;
            mkN2 : N -> Prep -> N2
          } ;

Three-place relational nouns (la connessione di x a y) need two prepositions.

          mkN3 : N -> Prep -> Prep -> N3 ;

### Relational common noun phrases

In some cases, you may want to make a complex `CN` into a relational noun (e.g. la vecchia chiesa di). However, `N2` and `N3` are purely lexical categories. But you can use the `AdvCN` and `PrepNP` constructions to build phrases like this.

### Proper names and noun phrases

Proper names need a string and a gender. The gender is by default feminine if the name ends with an a, and masculine otherwise.

          mkPN : overload {
            mkPN : Str -> PN ;
            mkPN : Str -> Gender -> PN
          } ;

## Adjectives

          mkA : overload {

For regular adjectives, all forms are derived from the masculine singular. Comparison is formed by pił.

            mkA : (bianco : Str) -> A ;

Five forms are needed in the worst case (masc and fem singular, masc plural, adverbial), given that comparison is formed by pił.

            mkA : (solo,sola,soli,sole,solamente : Str) -> A ;

With irregular comparison, there are as it were two adjectives: the positive (buono) and the comparative (migliore).

            mkA : A -> A -> A
            } ;

All the functions above create postfix adjectives. To switch them to prefix ones (i.e. ones placed before the noun in modification, as in vecchia chiesa), the following function is provided.

            prefixA : A -> A = prefA ;

### Two-place adjectives

Two-place adjectives need a preposition for their second argument.

          mkA2 : A -> Prep -> A2 ;

## Adverbs

Adverbs are not inflected. Most lexical ones have position after the verb.

          mkAdv : Str -> Adv ;

Some appear next to the verb (e.g. sempre).

          mkAdV : Str -> AdV ;

Adverbs modifying adjectives and sentences can also be formed.

          mkAdA : Str -> AdA ;

## Verbs

          mkV : overload {

Regular verbs are ones with the infinitive are or ire, the latter with singular present indicative forms as finisco. The regular verb function is the first conjugation recognizes these endings, as well as the variations among amare, cominciare, mangiare, legare, cercare.

            mkV : Str -> V ;

The module `BeschIta` gives (almost) all the patterns of the Bescherelle book. To use them in the category `V`, wrap them with the function

            mkV : Verbo -> V ;

If `BeschIta` does not give the desired result or feels difficult to consult, here is a worst-case function for -ire and -ere verbs, taking 11 arguments.

            mkV : (udire,odo,ode,udiamo,udiro,udii,udisti,udi,udirono,odi,udito : Str) -> V
            } ;

The function `regV` gives all verbs the compound auxiliary avere. To change it to essere, use the following function. Reflexive implies essere.

          essereV : V -> V ;
          reflV : V -> V ;

### Two-place verbs

Two-place verbs need a preposition, except the special case with direct object. (transitive verbs). Notice that a particle comes from the `V`.

          mkV2 : overload {
            mkV2 : Str -> V2 ;
            mkV2 : V -> V2 ;
            mkV2 : V -> Prep -> V2
            } ;

You can reuse a `V2` verb in `V`.

          v2V : V2 -> V ;

### Three-place verbs

Three-place (ditransitive) verbs need two prepositions, of which the first one or both can be absent.

          mkV3     : V -> Prep -> Prep -> V3 ; -- parlare, a, di
          dirV3    : V -> Prep -> V3 ;         -- dare,_,a
          dirdirV3 : V -> V3 ;                 -- dare,_,_

### Other complement patterns

Verbs and adjectives can take complements such as sentences, questions, verb phrases, and adjectives.

          mkV0  : V -> V0 ;
          mkVS  : V -> VS ;
          mkV2S : V -> Prep -> V2S ;
          mkVV  : V -> VV ;  -- plain infinitive: "voglio parlare"
          deVV  : V -> VV ;  -- "cerco di parlare"
          aVV   : V -> VV ;  -- "arrivo a parlare"
          mkV2V : V -> Prep -> Prep -> V2V ;
          mkVA  : V -> VA ;
          mkV2A : V -> Prep -> Prep -> V2A ;
          mkVQ  : V -> VQ ;
          mkV2Q : V -> Prep -> V2Q ;

          mkAS  : A -> AS ;
          mkA2S : A -> Prep -> A2S ;
          mkAV  : A -> Prep -> AV ;
          mkA2V : A -> Prep -> Prep -> A2V ;

Notice: categories `V2S, V2V, V2Q` are in v 1.0 treated just as synonyms of `V2`, and the second argument is given as an adverb. Likewise `AS, A2S, AV, A2V` are just `A`. `V0` is just `V`.

          V0, V2S, V2V, V2Q : Type ;
          AS, A2S, AV, A2V : Type ;