# Spanish Lexical Paradigms

Last update: 2007-07-06 09:19:56 CEST

- Parameters
- Nouns
  - Compound nouns
  - Relational nouns
  - Relational common noun phrases
  - Proper names and noun phrases
- Adjectives
  - Two-place adjectives
- Adverbs
- Verbs
  - Two-place verbs
  - Three-place verbs
  - Other complement patterns

Produced by gfdoc - a rudimentary GF document generator. (c) Aarne Ranta (aarne@cs.chalmers.se) 2002 under GNU GPL.

Aarne Ranta 2004 - 2006

This is an API for the user of the resource grammar for adding lexical items. It gives functions for forming expressions of open categories: nouns, adjectives, verbs.

Closed categories (determiners, pronouns, conjunctions) are accessed through the resource syntax API, `Structural.gf`.

The main difference with `MorphoSpa.gf` is that the types referred to are compiled resource grammar types. We have moreover had the design principle of always having existing forms, rather than stems, as string arguments of the paradigms.

The structure of functions for each word class `C` is the following: first we give a handful of patterns that aim to cover all regular cases. Then we give a worst-case function `mkC`, which serves as an escape to construct the most irregular words of type `C`. For verbs, there is a fairly complete list of irregular verbs in `IrregSpa`.

        resource ParadigmsSpa =
          open
            (Predef=Predef),
            Prelude,
            CommonRomance,
            ResSpa,
            MorphoSpa,
            BeschSpa,
            CatSpa in {

          flags optimize=all ;

## Parameters

To abstract over gender names, we define the following identifiers.

        oper
          Gender : Type ;

          masculine : Gender ;
          feminine  : Gender ;

To abstract over number names, we define the following.

          Number : Type ;

          singular : Number ;
          plural   : Number ;

Prepositions used in many-argument functions are either strings (including the 'accusative' empty string) or strings that amalgamate with the following word (the 'genitive' de and the 'dative' a).

          Prep : Type ;

          accusative : Prep ;
          genitive   : Prep ;
          dative     : Prep ;

          mkPrep : Str -> Prep ;

## Nouns

          mkN : overload {

The regular function takes the singular form and the gender, and computes the plural and the gender by a heuristic. The heuristic says that the gender is feminine for nouns ending with a or z, and masculine for all other words. Nouns ending with a, o, e have the plural with s, those ending with z have ces in plural; all other nouns have es as plural ending. The accent is not dealt with.

            mkN : (luz : Str) -> N ;

A different gender can be forced.

            mkN : Str -> Gender -> N ;

The worst case has two forms (singular + plural) and the gender.

            mkN : (baston,bastones : Str) -> Gender -> N
            } ;

### Compound nouns

Some nouns are ones where the first part is inflected as a noun but the second part is not inflected. e.g. número de teléfono. They could be formed in syntax, but we give a shortcut here since they are frequent in lexica.

          compN : N -> Str -> N ;

### Relational nouns

Relational nouns (fille de x) need a case and a preposition.

          mkN2 : N -> Prep -> N2 ;

The most common cases are the genitive de and the dative a, with the empty preposition.

          deN2 : N -> N2 ;
          aN2  : N -> N2 ;

Three-place relational nouns (la connessione di x a y) need two prepositions.

          mkN3 : N -> Prep -> Prep -> N3 ;

### Relational common noun phrases

In some cases, you may want to make a complex `CN` into a relational noun (e.g. the old town hall of). However, `N2` and `N3` are purely lexical categories. But you can use the `AdvCN` and `PrepNP` constructions to build phrases like this.

### Proper names and noun phrases

Proper names need a string and a gender. The default gender is feminine for names ending with a, otherwise masculine.

          mkPN : overload {
            mkPN : (Anna : Str) -> PN ;
            mkPN : (Pilar : Str) -> Gender -> PN
            } ;

## Adjectives

          mkA : overload {

For regular adjectives, all forms are derived from the masculine singular. The types of adjectives that are recognized are alto, fuerte, util. Comparison is formed by mas.

            mkA : (util : Str) -> A ;

One-place adjectives compared with mas need five forms in the worst case (masc and fem singular, masc plural, adverbial).

            mkA : (solo,sola,solos,solas,solamiento : Str) -> A ;

In the worst case, two separate adjectives are given: the positive (bueno), and the comparative (mejor).

            mkA : (bueno : A) -> (mejor : A) -> A
            } ;

The functions above create postfix adjectives. To switch them to prefix ones (i.e. ones placed before the noun in modification, as in bueno vino), the following function is provided.

          prefixA : A -> A ;

### Two-place adjectives

Two-place adjectives need a preposition for their second argument.

          mkA2 : A -> Prep -> A2 ;

## Adverbs

Adverbs are not inflected. Most lexical ones have position after the verb.

          mkAdv : Str -> Adv ;

Some appear next to the verb (e.g. siempre).

          mkAdV : Str -> AdV ;

Adverbs modifying adjectives and sentences can also be formed.

          mkAdA : Str -> AdA ;

## Verbs

          mkV : overload {

Regular verbs are ones inflected like cortar, deber, or vivir. The regular verb function is the first conjugation (ar) recognizes the variations corresponding to the patterns actuar, cazar, guiar, pagar, sacar. The module `BeschSpa` gives the complete set of Bescherelle conjugations.

            mkV : (pagar : Str) -> V ;

Verbs with vowel alternatition in the stem - easiest to give with two forms, e.g. mostrar///muestro//.

            mkV : (mostrar,muestro : Str) -> V ;

Most irreguler verbs are found in `IrregSpa`. If this is not enough, the module `BeschSpa` gives all the patterns of the Bescherelle book. To use them in the category `V`, wrap them with the function

            mkV : Verbum -> V
            } ;

To form reflexive verbs:

          reflV : V -> V ;

Verbs with a deviant passive participle: just give the participle in masculine singular form as second argument.

          special_ppV : V -> Str -> V ;

### Two-place verbs

Two-place verbs need a preposition, except the special case with direct object. (transitive verbs).

          mkV2 : overload {
            mkV2 : Str -> V2 ;
            mkV2 : V -> V2 ;
            mkV2 : V -> Prep -> V2
            } ;

You can reuse a `V2` verb in `V`.

          v2V : V2 -> V ;

### Three-place verbs

Three-place (ditransitive) verbs need two prepositions, of which the first one or both can be absent.

          mkV3     : V -> Prep -> Prep -> V3 ;   -- hablar, a, di
          dirV3    : V -> Prep -> V3 ;           -- dar,(accusative),a
          dirdirV3 : V -> V3 ;                   -- dar,(dative),(accusative)

### Other complement patterns

Verbs and adjectives can take complements such as sentences, questions, verb phrases, and adjectives.

          mkV0  : V -> V0 ;
          mkVS  : V -> VS ;
          mkV2S : V -> Prep -> V2S ;
          mkVV  : V -> VV ;  -- plain infinitive: "quiero hablar"
          deVV  : V -> VV ;  -- "terminar de hablar"
          aVV   : V -> VV ;  -- "aprender a hablar"
          mkV2V : V -> Prep -> Prep -> V2V ;
          mkVA  : V -> VA ;
          mkV2A : V -> Prep -> Prep -> V2A ;
          mkVQ  : V -> VQ ;
          mkV2Q : V -> Prep -> V2Q ;

          mkAS  : A -> AS ;
          mkA2S : A -> Prep -> A2S ;
          mkAV  : A -> Prep -> AV ;
          mkA2V : A -> Prep -> Prep -> A2V ;

Notice: categories `V2S, V2V, V2Q` are in v 1.0 treated just as synonyms of `V2`, and the second argument is given as an adverb. Likewise `AS, A2S, AV, A2V` are just `A`. `V0` is just `V`.

          V0, V2S, V2V, V2Q : Type ;
          AS, A2S, AV, A2V  : Type ;