added Afrikaans (draft, direct adaptation from Dutch)

2011-01-12 08:07:30 +00:00
parent 5661ecde18
commit 578591806f
24 changed files with 2960 additions and 0 deletions
--- a/lib/src/afrikaans/IdiomAfr.gf
+++ b/lib/src/afrikaans/IdiomAfr.gf
@@ -0,0 +1,50 @@
+concrete IdiomAfr of Idiom = CatAfr ** 
+  open MorphoAfr, (P = ParadigmsAfr), IrregAfr, Prelude in {
+
+  flags optimize=all_subs ;
+
+  lin
+    ImpersCl vp = mkClause "'t" (agrP3 Sg) vp ;
+    GenericCl vp = mkClause "men" (agrP3 Sg) vp ;
+
+    CleftNP np rs = mkClause "'t" (agrP3 Sg) 
+      (insertExtrapos (rs.s ! np.a.g ! np.a.n) ----
+        (insertObj (\\_ => np.s ! NPNom) (predV zijn_V))) ;
+
+    CleftAdv ad s = mkClause "'t" (agrP3 Sg) 
+      (insertExtrapos (conjThat ++ s.s ! Sub)
+        (insertObj (\\_ => ad.s) (predV zijn_V))) ;
+
+    ExistNP np = 
+      mkClause "er" (agrP3 np.a.n) 
+        (insertObj (\\_ => np.s ! NPNom) 
+          (predV zijn_V)) ;
+
+    ExistIP ip = {
+      s = \\t,a,p => 
+            let 
+              cls = 
+                (mkClause "er" (agrP3 ip.n)  (predV zijn_V)).s ! t ! a ! p ;
+              who = ip.s ! NPNom
+            in table {
+              QDir   => who ++ cls ! Inv ;
+              QIndir => who ++ cls ! Sub
+              }
+      } ;
+
+    ProgrVP vp = insertAdv ("aan" ++ "het" ++ useInfVP True vp) (predV zijn_V) ;
+
+    ImpPl1 vp =
+      let 
+        v   = v2vv (regVerb "laat") ;
+        vpi = infVP True vp ;
+        vvp = insertExtrapos vpi.p3 (
+                insertInf vpi.p2 (
+                  insertObj vpi.p1 (
+                    predVGen True v))) ;
+      in 
+      {s = (mkClause "we" {g = Utr ; n = Pl ; p = P1} vvp).s ! 
+                           Pres ! Simul ! Pos ! Inv 
+      } ;
+
+}