{ mkCljBin
, doerg
, babashka
, callPackage
, test-emacs ? callPackage ./test-emacs.nix {}
, fake-git
, breakpointHook
, doerg-temml-worker
, doerg-parser
}:

let
  # 이 mkCljBin에는 fake-git가 포함되지 않는다. 그것 불필요해서 dev
  # shell에 없고 싶는다.
  mkCljBin' = args: (mkCljBin args).overrideAttrs (final: prev: {
    nativeBuildInputs =
      builtins.filter
        # A possibly-sketchy predicate, lol.
        (x: x != fake-git)
        prev.nativeBuildInputs;
  });
in mkCljBin' {
  name = "net.deertopia/publisher";
  version = "0.1.0";
  projectSrc = ./.;
  lockfile = ../deps-lock.json;
  main-ns = "net.deertopia.publisher.main";
  buildInputs = [
    doerg
  ];
  nativeBuildInputs = [
    babashka
    breakpointHook
  ];
  nativeCheckInputs = [
    doerg-parser
    doerg-temml-worker
    test-emacs
    doerg
    doerg.our-tex
    doerg.plex
  ];
  postPatch = ''
    mv deps.edn deps.edn.old
    bb -cp . -m override-deps < deps.edn.old > deps.edn \
      net.deertopia/doerg '{:local/root "${doerg.lib}/${doerg.name}.jar"}'
  '';
  doCheck = true;
  checkPhase = ''
    export \
      EMACS=test-emacs \
      XDG_STATE_HOME=$(mktemp -d "state-home-XXXXXX")
    clojure -M:test
  '';
  passthru = { inherit test-emacs; };
}