{ config, lib, pkgs, ... }:

let cfg = config.sydnix.deertopia.servarr.jellyfin;
in {
  options.sydnix.deertopia.servarr.jellyfin = {
    enable = lib.mkEnableOption "Jellyfin (via Nixarr)";
  };

  config = lib.mkIf cfg.enable {
    sydnix.deertopia.nginx.vhosts."watch".vhost =
      # Currently no (convenient) way to specify Jellyfin's port from Nix.
      let port = builtins.toString 8096;
      in {
        forceSSL = true;
        enableACME = true;
        locations."/".extraConfig = ''
          # Proxy main Jellyfin traffic.
          proxy_pass $jellyfin;
          proxy_set_header Host $host;
          proxy_set_header X-Real-IP $remote_addr;
          proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
          proxy_set_header X-Forwarded-Proto $scheme;
          proxy_set_header X-Forwarded-Protocol $scheme;
          proxy_set_header X-Forwarded-Host $http_host;

          # Disable buffering when the nginx proxy gets very resource heavy upon
          # streaming.
          proxy_buffering off;
        '';
        locations."/socket".extraConfig = ''
          # Proxy Jellyfin Websockets traffic
          proxy_pass $jellyfin;
          proxy_http_version 1.1;
          proxy_set_header Upgrade $http_upgrade;
          proxy_set_header Connection "upgrade";
          proxy_set_header Host $host;
          proxy_set_header X-Real-IP $remote_addr;
          proxy_set_header X-Forwarded-For $proxy_add_x_forwarded_for;
          proxy_set_header X-Forwarded-Proto $scheme;
          proxy_set_header X-Forwarded-Protocol $scheme;
          proxy_set_header X-Forwarded-Host $http_host;
        '';
        extraConfig = ''
          set $jellyfin http://127.0.0.1:${port};
        '';
      };

    nixarr.jellyfin = {
      enable = true;
      openFirewall = true;
    };

    sydnix.deertopia.nginx.vhosts."jellyseer".vhost =
      # Currently no (convenient) way to specify Jellyfin's port from Nix.
      let port = builtins.toString 8096;
      in {
        forceSSL = true;
        enableACME = true;
        locations."/".proxyPass = "http://127.0.0.1:5055";
      };

    nixarr.jellyseerr = {
      enable = true;
      openFirewall = true;
    };
  };
}