{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    crane.url = "github:ipetkov/crane";
  };

  outputs = { self, nixpkgs, ... }@inputs:
    let
      supportedSystems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];

      each-system = f: nixpkgs.lib.genAttrs supportedSystems (system: f rec {
	pkgs = import nixpkgs {
	  inherit system;
	};
	inherit (pkgs) lib;
        inherit system;
      });
    in {
      # Exposed as a REPL convenience.
      _pkgs = each-system ({ pkgs, ... }: pkgs);

      packages = each-system ({ pkgs, lib, ... }: (lib.fix (p: {
        default = p.wiktlarp;
        wiktlarp = pkgs.callPackage ./default.nix {
          crane-lib = inputs.crane.mkLib pkgs;
        };
        db = pkgs.callPackage ./db {};
      })));

      devShells = each-system ({ pkgs, system, ... }: {
	default = pkgs.mkShell {
          inputsFrom = [
            self.packages.${system}.db
            self.packages.${system}.default
          ];
          DATABASE_URL = "db/words.db";
	  packages = with pkgs; [
            (sqlite.override { interactive = true; })
            python314Packages.wiktextract
            sqlite-web
            jq
            rust-analyzer
            diesel-cli
            cargo-flamegraph
	  ];
	};
      });
    };
}