factored Query by taking our Proton parts and introducing an interface

examples/query/small/patentsQuery/LexQuery.gf

@@ -0,0 +1,22 @@
+interface LexQuery = open Syntax in {
+
+oper
+-- structural words
+  about_Prep : Prep ;
+  all_NP : NP ;
+  also_AdV : AdV ;
+  as_Prep : Prep ;
+  at_Prep : Prep ;
+  called_A : A ;
+  give_V3 : V3 ;
+  information_N : N ;
+  other_A : A ;
+  name_N : N ;
+
+  mkName : Str -> NP ;
+
+oper  
+  mkRelation : Str -> {cn : CN ; prep : Prep} ;
+  that_RP : RP ;
+
+}

examples/query/small/patentsQuery/LexQueryEng.gf

@@ -0,0 +1,26 @@
+instance LexQueryEng of LexQuery = open ParadigmsEng, SyntaxEng, ExtraEng, IrregEng in {
+
+oper
+-- structural words
+  about_Prep = mkPrep "about" ;
+  all_NP = mkNP (mkPN "all") ; ---
+  also_AdV = mkAdV "also" | mkAdV "otherwise" ;
+  as_Prep = mkPrep "as" ;
+  at_Prep = mkPrep "at" ;
+  called_A = mkA "called" | mkA "named" ;
+  give_V3 = mkV3 give_V ;
+  information_N = mkN "information" ;
+  other_A = mkA "other" ;
+  name_N = mkN "name" ;
+
+-- lexical constructors
+  mkName : Str -> NP =
+    \s -> mkNP (mkPN s) ;
+
+oper  
+  mkRelation : Str -> {cn : CN ; prep : Prep} =
+    \s -> {cn = mkCN (mkN s) ; prep = possess_Prep} ;
+
+  that_RP = ExtraEng.that_RP ; 
+
+}

examples/query/small/patentsQuery/Query.gf

@@ -0,0 +1,50 @@
+abstract Query = {
+
+flags
+  startcat = Move ;
+
+-- general query language, which can be specialized with any lexicon
+
+cat
+  Move ;       -- top-level utterance,    e.g. "give me all Bulgarian persons that work at Google"
+  Query ;
+  Answer ;
+  Set ;        -- the set requested,      e.g. "all persons"
+  Relation ;   -- something of something, e.g. "subregion of Bulgaria"
+  Kind ;       -- type of things,         e.g. "person"
+  Property ;   -- property of things,     e.g. "employed at Google"
+  Individual ; -- one entity,             e.g. "Google"
+  Activity ;   -- action property,        e.g. "work at Google"
+  Name ;       -- person, company...      e.g. "Eric Schmidt"
+  Loc ;
+  Org ;
+  Pers ;
+  [Individual] {2} ; -- list of entities, e.g. "Larry Page, Sergey Brin"
+
+fun
+  MQuery  : Query -> Move ;
+  MAnswer : Answer -> Move ;
+
+  QSet    : Set  -> Query ;  -- (give me | what are | which are | ) (S | the names of S | S's names)
+  QWhere  : Set  -> Query ;  -- where are S
+  QInfo   : Set  -> Query ;  -- (give me | ) (information about | all about) S
+
+  AKind  : Set  -> Kind     -> Answer ; -- S is a K
+  AProp  : Set  -> Property -> Answer ; -- S is P
+  AAct   : Set  -> Activity -> Answer ; -- S As
+
+  SAll    : Kind -> Set ;  -- all Ks | the Ks
+  SOne    : Kind -> Set ;  -- one K
+  SIndef  : Kind -> Set ;  -- a K
+  SPlural : Kind -> Set ;  -- Ks
+  SOther  : Kind -> Set ;  -- other Ks
+  SInd    : Individual  -> Set ;  -- X
+  SInds   : [Individual] -> Set ; -- X and Y
+
+  KRelSet  : Relation -> Set -> Kind ; -- R of S | S's R
+  KRelKind : Kind -> Relation -> Set -> Kind ; -- K that is R of S
+  KRelPair : Kind -> Relation -> Kind ; -- S's with their R's
+  KProp    : Property -> Kind -> Kind ; -- P K | K that is P
+  KAct     : Activity -> Kind -> Kind ; -- K that Ps
+  KRel     : Relation -> Kind ; -- R ---??
+}

examples/query/small/patentsQuery/QueryEng.gf

@@ -0,0 +1,4 @@
+concrete QueryEng of Query = QueryI with
+  (LexQuery = LexQueryEng),
+  (Syntax = SyntaxEng),
+  (Lang = LangEng) ;

examples/query/small/patentsQuery/QueryProton.gf

@@ -0,0 +1,59 @@
+abstract QueryProton = Query ** {
+
+fun
+  QCalled : Individual -> Query ; -- how is X (also | otherwise) (called | named | known) ;
+
+  NLoc : Loc -> Name ;
+  NOrg : Org -> Name ;
+  NPers : Pers -> Name ;
+
+  IName    : Name -> Individual ;
+  ACalled  : [Individual] -> Activity ;
+
+-- the test lexicon
+
+cat
+  JobTitle ;
+fun
+  Located : Loc -> Property ;
+  Employed : Org -> Property ;
+
+  Work : Org -> Activity ;
+  HaveTitle : JobTitle -> Activity ;
+  HaveTitleOrg : JobTitle -> Org -> Activity ;
+
+  Organization : Kind ;
+  Place : Kind ;
+  Person : Kind ;
+
+  Location : Relation ;
+  Region : Relation ;
+  Subregion : Relation ;
+
+  RName     : Relation ;
+  RNickname : Relation ;
+
+-- JobTitles
+   JobTitle1 : JobTitle ;
+   JobTitle2 : JobTitle ;
+   JobTitle3 : JobTitle ;
+   JobTitle4 : JobTitle ;
+
+-- Locations
+   Location1 : Loc ;
+   Location2 : Loc ;
+   Location3 : Loc ;
+   Location4 : Loc ;
+
+-- Organizations
+   Organization1 : Org ;
+   Organization2 : Org ;
+   Organization3 : Org ;
+   Organization4 : Org ;
+
+-- Persons
+   Person1 : Pers ;
+   Person2 : Pers ;
+   Person3 : Pers ;
+   Person4 : Pers ;
+}