Italian added (first version, to be tested more)

lib/resource-1.0/french/MorphoFre.gf

@@ -78,8 +78,6 @@ oper
 -- Adjectives are conveniently seen as gender-dependent nouns.
 -- Here are some patterns. First one that describes the worst case.
 
-  Adj = {s : AForm => Str} ;
-
   mkAdj : (_,_,_,_ : Str) -> Adj = \vieux,vieuxs,vieille,vieillement ->
     {s = table {
        AF Masc n => numForms vieux vieuxs ! n ;

lib/resource-1.0/french/ParadigmsFre.gf

@@ -214,9 +214,10 @@ oper
   reg3V : (jeter,jette,jettera : Str) -> V ;
 
 -- The function $regV$ gives all verbs the compound auxiliary "avoir".
--- To change it to "être", use the following function.
+-- To change it to "être", use the following function. Reflexive implies "être".
 
   etreV : V -> V ;
+  reflV : V -> V ;
 
 --3 Two-place verbs
 --
@@ -300,7 +301,7 @@ oper
   mkN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = p ; c3 = q} ;
 
   mkPN x g = {s = x ; g = g} ** {lock_PN = <>} ;
-  mkNP x g n = {s = (pn2np (mkPN x g)).s ; a = agrP3 g n ; c = Clit0} ** {lock_NP = <>} ;
+  mkNP x g n = {s = (pn2np (mkPN x g)).s; a = agrP3 g n ; c = Clit0} ** {lock_NP = <>} ;
 
   mkA a b c d = compADeg {s = \\_ => (mkAdj a c b d).s ; isPre = False ; lock_A = <>} ;
   regA a = compADeg {s = \\_ => (mkAdjReg a).s ; isPre = False ; lock_A = <>} ;
@@ -311,8 +312,9 @@ oper
   mkADeg a b = 
     {s = table {Posit => a.s ! Posit ; _ => b.s ! Posit} ; isPre = a.isPre ; lock_A = <>} ;
   compADeg a = 
-    {s = table {Posit => a.s ! Posit ; _ => \\f => "plus" ++ a.s ! Posit ! f} ; isPre = a.isPre ;
-               lock_A = <>} ;
+    {s = table {Posit => a.s ! Posit ; _ => \\f => "plus" ++ a.s ! Posit ! f} ; 
+     isPre = a.isPre ;
+     lock_A = <>} ;
   prefA a = {s = a.s ; isPre = True ; lock_A = <>} ;
 
 
@@ -323,6 +325,7 @@ oper
   regV x = let v = vvf (mkVerbReg x) in {s = v ; vtyp = VHabere ; lock_V = <>} ;
   reg3V x y z = let v = vvf (mkVerb3Reg x y z) in {s = v ; vtyp = VHabere ; lock_V = <>} ;
   etreV v = {s = v.s ; vtyp = VEsse ; lock_V = <>} ;
+  reflV v = {s = v.s ; vtyp = VRefl ; lock_V = <>} ;
 
   mkV2 v p = v ** {c2 = p ; lock_V2 = <>} ;
   dirV2 v = mkV2 v accusative ;

lib/resource-1.0/italian/AdjectiveIta.gf

@@ -0,0 +1,2 @@
+concrete AdjectiveIta of Adjective = CatIta ** AdjectiveRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/AdverbIta.gf

@@ -0,0 +1,2 @@
+concrete AdverbIta of Adverb = CatIta ** AdverbRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/CatIta.gf

@@ -0,0 +1,4 @@
+--# -path=.:../romance:../abstract:../common:prelude
+
+concrete CatIta of Cat = TenseX ** CatRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/ConjunctionIta.gf

@@ -0,0 +1,2 @@
+concrete ConjunctionIta of Conjunction = CatIta ** ConjunctionRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/DiffIta.gf

@@ -0,0 +1,318 @@
+--# -path=.:../romance:../abstract:../common:prelude
+
+instance DiffIta of DiffRomance = open CommonRomance, PhonoIta, BeschIta, Prelude in {
+
+  param 
+    Prep = P_di | P_a | P_da | P_in | P_su | P_con ;
+    VType = VHabere | VEsse | VRefl ;
+
+  oper
+    dative   : Case = CPrep P_a ;
+    genitive : Case = CPrep P_di ;
+
+    prepCase = \c -> case c of {
+      Nom | Acc => [] ;
+      CPrep p => case p of {
+        P_di => "di" ;
+        P_a  => "a" ;
+        P_da => "da" ;
+        P_in => "in" ;
+        P_su => "su" ;
+        P_con => "con"
+        }
+      } ;
+
+    artDef : Gender -> Number -> Case -> Str = \g,n,c ->
+      case <g,n,c> of {
+        <_, _, CPrep P_di>  => prepArt "de" ;
+        <_, _, CPrep P_da>  => prepArt "da" ;
+        <_, _, CPrep P_a>   => prepArt "a" ;
+        <_, _, CPrep P_in>  => prepArt "ne" ;
+        <_, _, CPrep P_su>  => prepArt "su" ;
+        <_, _, CPrep P_con> => prepArt "co" ;
+        <Masc,Sg, Nom| Acc> => elision "il" "l'" "lo" ;
+        <Fem ,Sg, _>        => elision "la" "l'" "la" ;
+        <Masc,Pl, _>        => elision "i" "gli" "gli" ;
+        <Fem ,Pl, _>        => "le"
+        } 
+       where {
+         prepArt : Tok -> Tok = \de -> case <g,n> of {
+           <Masc,Sg> => elision (de + "l")   (de + "ll'") (de + "llo") ;
+           <Masc,Pl> => elision (de + "i")   (de + "gli") (de + "gli") ;
+           <Fem, Sg> => elision (de + "lla") (de + "ll'") (de + "lla") ;
+           <Fem, Pl> => de + "lle"
+           }
+         } ;
+
+
+-- In these two, "de de/du/des" becomes "de".
+
+    artIndef = \g,n,c -> case <n,c> of {
+      <Sg,_>   => prepCase c ++ 
+                  genForms (elision "un" "un" "uno") (elision "una" "un'" "una") ! g ;
+      _        => prepCase c 
+      } ;
+
+    partitive = \g,c -> case c of {
+      CPrep P_de => "di" ;
+      _ => prepCase c ++ artDef g Sg (CPrep P_di)
+      } ;
+
+    conjunctCase : NPForm -> NPForm = \c -> case c of {
+      Ton Nom | Aton Nom => Ton Nom ;
+      _ => Ton Acc 
+      } ;
+
+    auxVerb : VType -> (VF => Str) = \vtyp -> case vtyp of {
+      VHabere => avere_V.s ;
+      _ => copula.s
+      } ;
+
+    partAgr : VType -> VPAgr = \vtyp -> case vtyp of {
+      VHabere => vpAgrNone ;
+      _ => VPAgrSubj
+      } ;
+
+    vpAgrClit : Agr -> VPAgr = \a ->
+      vpAgrNone ;
+
+    negation : Polarity => (Str * Str) = table {
+      Pos => <[],[]> ;
+      Neg => <"non",[]>
+      } ;
+
+    conjThan = "che" ; --- di
+    conjThat = "che" ;
+
+    clitInf cli inf = inf ++ cli ; --- contraction of inf
+
+    relPron : Bool => AAgr => Case => Str = \\b,a,c => 
+      case c of {
+        Nom => "che" ;
+        CPrep P_de => "cui" ;
+        _ => prepCase c ++ "cui" --- ilquale
+        } ;
+
+    pronSuch : AAgr => Str = aagrForms "tale" "tale" "tali" "tali" ;
+
+    quelPron : AAgr => Str = aagrForms "quale" "quale" "quali" "quali" ;
+
+    partQIndir = "ciò" ;
+
+    reflPron : Number => Person => Case => Str = 
+      let 
+        cases : (x,y : Str) -> (Case => Str) = \me,moi -> table {
+          Acc | CPrep P_a => me ;
+          _ => moi
+          } ;
+      in 
+      \\n,p => case <n,p> of { 
+        <Sg,P1> => cases "mi" "me" ;
+        <Sg,P2> => cases "ti" "te" ;
+        <Pl,P1> => cases "ci" "noi" ; -- unlike French with just one alt!
+        <Pl,P2> => cases "vi" "voi" ;
+        _ => cases "si" "se"
+        } ;
+
+    vRefl   : VType = VRefl ;
+    isVRefl : VType -> Bool = \ty -> case ty of {
+      VRefl => True ;
+      _ => False
+      } ;
+
+    auxPassive : Verb = venire_V ;
+
+    copula = essere_V ;
+
+-- machine-generated GF code (from Functional Morphology)
+
+  essere_V : Verb = verbBesch
+  {s = table {
+    Inf => "essere" ;
+    InfClit => "essr" ;
+    Indi Pres Sg P1 => "sono" ;
+    Indi Pres Sg P2 => "sei" ;
+    Indi Pres Sg P3 => "è" ;
+    Indi Pres Pl P1 => "siamo" ;
+    Indi Pres Pl P2 => "siete" ;
+    Indi Pres Pl P3 => "sono" ;
+    Indi Imperf Sg P1 => "ero" ;
+    Indi Imperf Sg P2 => "eri" ;
+    Indi Imperf Sg P3 => "era" ;
+    Indi Imperf Pl P1 => "eravamo" ;
+    Indi Imperf Pl P2 => "eravate" ;
+    Indi Imperf Pl P3 => "erano" ;
+    Pass Sg P1 => "fui" ;
+    Pass Sg P2 => "fosti" ;
+    Pass Sg P3 => "fu" ;
+    Pass Pl P1 => "fummo" ;
+    Pass Pl P2 => "foste" ;
+    Pass Pl P3 => "furono" ;
+    Fut Sg P1 => "sarò" ;
+    Fut Sg P2 => "sarai" ;
+    Fut Sg P3 => "sarà" ;
+    Fut Pl P1 => "saremo" ;
+    Fut Pl P2 => "sarete" ;
+    Fut Pl P3 => "saranno" ;
+    Cong Pres Sg P1 => "sia" ;
+    Cong Pres Sg P2 => "sia" ;
+    Cong Pres Sg P3 => "sia" ;
+    Cong Pres Pl P1 => "siamo" ;
+    Cong Pres Pl P2 => "siate" ;
+    Cong Pres Pl P3 => "siano" ;
+    Cong Imperf Sg P1 => "fossi" ;
+    Cong Imperf Sg P2 => "fossi" ;
+    Cong Imperf Sg P3 => "fosse" ;
+    Cong Imperf Pl P1 => "fossimo" ;
+    Cong Imperf Pl P2 => "foste" ;
+    Cong Imperf Pl P3 => "fossero" ;
+    Cond Sg P1 => "sarei" ;
+    Cond Sg P2 => "saresti" ;
+    Cond Sg P3 => "sarebbe" ;
+    Cond Pl P1 => "saremmo" ;
+    Cond Pl P2 => "sareste" ;
+    Cond Pl P3 => "sarebbero" ;
+    Imper SgP2 => "sii" ;
+    --Imper IPs3 => "sia" ;
+    Imper PlP1 => "siamo" ;
+    Imper PlP2 => "siate" ;
+    --Imper IPp3 => "siano" ;
+    Ger => "essendo" ;
+    Part PresP Masc Sg => variants {} ;
+    Part PresP Masc Pl => variants {} ;
+    Part PresP Fem Sg => variants {} ;
+    Part PresP Fem Pl => variants {} ;
+    Part PassP Masc Sg => "stato" ;
+    Part PassP Masc Pl => "stati" ;
+    Part PassP Fem Sg => "stata" ;
+    Part PassP Fem Pl => "state"
+    }} ** {
+    vtyp = VHabere
+  } ;
+
+  avere_V : Verb = verbBesch
+  {s = table {
+    Inf => "avere" ;
+    InfClit => "aver" ;
+    Indi Pres Sg P1 => "ho" ;
+    Indi Pres Sg P2 => "hai" ;
+    Indi Pres Sg P3 => "ha" ;
+    Indi Pres Pl P1 => "abbiamo" ;
+    Indi Pres Pl P2 => "avete" ;
+    Indi Pres Pl P3 => "hanno" ;
+    Indi Imperf Sg P1 => "avevo" ;
+    Indi Imperf Sg P2 => "avevi" ;
+    Indi Imperf Sg P3 => "aveva" ;
+    Indi Imperf Pl P1 => "avevamo" ;
+    Indi Imperf Pl P2 => "avevate" ;
+    Indi Imperf Pl P3 => "avevano" ;
+    Pass Sg P1 => "ebbi" ;
+    Pass Sg P2 => "avesti" ;
+    Pass Sg P3 => "ebbe" ;
+    Pass Pl P1 => "avemmo" ;
+    Pass Pl P2 => "aveste" ;
+    Pass Pl P3 => "ebbero" ;
+    Fut Sg P1 => "avrò" ;
+    Fut Sg P2 => "avrai" ;
+    Fut Sg P3 => "avrà" ;
+    Fut Pl P1 => "avremo" ;
+    Fut Pl P2 => "avrete" ;
+    Fut Pl P3 => "avranno" ;
+    Cong Pres Sg P1 => "abbia" ;
+    Cong Pres Sg P2 => "abbia" ;
+    Cong Pres Sg P3 => "abbia" ;
+    Cong Pres Pl P1 => "abbiamo" ;
+    Cong Pres Pl P2 => "abbiate" ;
+    Cong Pres Pl P3 => "abbiano" ;
+    Cong Imperf Sg P1 => "avessi" ;
+    Cong Imperf Sg P2 => "avessi" ;
+    Cong Imperf Sg P3 => "avesse" ;
+    Cong Imperf Pl P1 => "avessimo" ;
+    Cong Imperf Pl P2 => "aveste" ;
+    Cong Imperf Pl P3 => "avessero" ;
+    Cond Sg P1 => "avrei" ;
+    Cond Sg P2 => "avresti" ;
+    Cond Sg P3 => "avrebbe" ;
+    Cond Pl P1 => "avremmo" ;
+    Cond Pl P2 => "avreste" ;
+    Cond Pl P3 => "avrebbero" ;
+    Imper SgP2 => "abbi" ;
+    --Imper IPs3 => "abbia" ;
+    Imper PlP1 => "abbiamo" ;
+    Imper PlP2 => "abbiate" ;
+    --Imper IPp3 => "abbiano" ;
+    Ger => "avendo" ;
+    Part PresP Masc Sg => "avente" ;
+    Part PresP Masc Pl => "aventi" ;
+    Part PresP Fem Sg => "avente" ;
+    Part PresP Fem Pl => "aventi" ;
+    Part PassP Masc Sg => "avuto" ;
+    Part PassP Masc Pl => "avuti" ;
+    Part PassP Fem Sg => "avuta" ;
+    Part PassP Fem Pl => "avute"
+    }} ** {
+  vtyp = VEsse
+  } ;
+
+  venire_V : Verb = verbBesch
+  {s = table {
+    Inf => "venire" ;
+    InfClit => "venir" ;
+    Indi Pres Sg P1 => "vengo" ;
+    Indi Pres Sg P2 => "vieni" ;
+    Indi Pres Sg P3 => "viene" ;
+    Indi Pres Pl P1 => "veniamo" ;
+    Indi Pres Pl P2 => "venite" ;
+    Indi Pres Pl P3 => "vengono" ;
+    Indi Imperf Sg P1 => "venivo" ;
+    Indi Imperf Sg P2 => "venivi" ;
+    Indi Imperf Sg P3 => "veniva" ;
+    Indi Imperf Pl P1 => "venivamo" ;
+    Indi Imperf Pl P2 => "venivate" ;
+    Indi Imperf Pl P3 => "venivano" ;
+    Pass Sg P1 => "venni" ;
+    Pass Sg P2 => "venisti" ;
+    Pass Sg P3 => "venne" ;
+    Pass Pl P1 => "venimmo" ;
+    Pass Pl P2 => "veniste" ;
+    Pass Pl P3 => "vennero" ;
+    Fut Sg P1 => "verrò" ;
+    Fut Sg P2 => "verrai" ;
+    Fut Sg P3 => "verrà" ;
+    Fut Pl P1 => "verremo" ;
+    Fut Pl P2 => "verrete" ;
+    Fut Pl P3 => "verranno" ;
+    Cong Pres Sg P1 => "venga" ;
+    Cong Pres Sg P2 => "venga" ;
+    Cong Pres Sg P3 => "venga" ;
+    Cong Pres Pl P1 => "veniamo" ;
+    Cong Pres Pl P2 => "veniate" ;
+    Cong Pres Pl P3 => "vengano" ;
+    Cong Imperf Sg P1 => "venissi" ;
+    Cong Imperf Sg P2 => "venissi" ;
+    Cong Imperf Sg P3 => "venisse" ;
+    Cong Imperf Pl P1 => "venissimo" ;
+    Cong Imperf Pl P2 => "veniste" ;
+    Cong Imperf Pl P3 => "venissero" ;
+    Cond Sg P1 => "verrei" ;
+    Cond Sg P2 => "verresti" ;
+    Cond Sg P3 => "verrebbe" ;
+    Cond Pl P1 => "verremmo" ;
+    Cond Pl P2 => "verreste" ;
+    Cond Pl P3 => "verrebbero" ;
+    Imper SgP2 => "vieni" ;
+    Imper PlP1 => "veniamo" ;
+    Imper PlP2 => "venite" ;
+    Ger => "venendo" ;
+    Part PresP Masc Sg => "veniente" ;
+    Part PresP Masc Pl => "venienti" ;
+    Part PresP Fem Sg => "veniente" ;
+    Part PresP Fem Pl => "venienti" ;
+    Part PassP Masc Sg => "venuto" ;
+    Part PassP Masc Pl => "venuti" ;
+    Part PassP Fem Sg => "venuta" ;
+    Part PassP Fem Pl => "venute"
+    }} ** {
+  vtyp = VEsse
+  } ;
+}

lib/resource-1.0/italian/LangIta.gf

@@ -0,0 +1,20 @@
+--# -path=.:../romance:../abstract:../common:prelude
+
+concrete LangIta of Lang = 
+  NounIta, 
+  VerbIta, 
+  AdjectiveIta,
+  AdverbIta,
+  NumeralIta,
+  SentenceIta,
+  QuestionIta,
+  RelativeIta,
+  ConjunctionIta,
+  PhraseIta,
+  StructuralIta,
+  LexiconIta
+  ** {
+
+flags startcat = Phr ;
+
+} ;

lib/resource-1.0/italian/LexiconIta.gf

@@ -0,0 +1,233 @@
+--# -path=.:../romance:../common:../abstract:../../prelude
+
+concrete LexiconIta of Lexicon = CatIta ** open ParadigmsIta, BeschIta in {
+
+flags 
+  optimize=values ;
+
+lin
+  airplane_N = regN "aereo" ;
+  answer_V2S = mkV2S (verboV (rispondere_76 "rispondere")) dative ;
+  apartment_N = regN "apartamento" ;
+  apple_N = regN "mela" ;
+  art_N = femN (regN "arte") ;
+  ask_V2Q = mkV2Q (verboV (rispondere_76 "chiedere")) dative ;
+  baby_N = regN "bambino" ;
+  bad_A = prefA (mkADeg (regA "cattivo") (regA "peggio")) ;
+  bank_N = regN "banca" ;
+  beautiful_A = prefA (regADeg "bello") ;
+  become_VA = essereV (regV "diventare") ;
+  beer_N = regN "birra" ;
+  beg_V2V = mkV2V (regV "pregare") accusative dative ;
+  big_A = prefA (regADeg "grande") ;
+  bike_N = regN "bicicletta" ;
+  bird_N = regN "uccello" ;
+  black_A = regADeg "nero" ;
+  blue_A = regADeg "blù" ;
+  boat_N = regN "batello" ;
+  book_N = regN "libro" ;
+  boot_N = regN "stivale" ;
+  boss_N = regN "capo" ;
+  boy_N = regN "ragazzo" ;
+  bread_N = regN "pane" ;
+  break_V2 = dirV2 (verboV (rompere_77 "rompere")) ;
+  broad_A = regADeg "largo" ;
+  brother_N2 = diN2 (regN "fratello") ;
+  brown_A = regADeg "marrone" ;
+  butter_N = regN "burro" ;
+  buy_V2 = dirV2 (regV "comprare") ;
+  camera_N = mkN ["macchina fotografica"]["macchine fotografiche"] feminine ; ---
+  cap_N = regN "berretta" ;
+  car_N = regN "macchina" ;
+  carpet_N = regN "tappeto" ;
+  cat_N = regN "gatto" ;
+  ceiling_N = regN "soffitto" ;
+  chair_N = regN "sedia" ;
+  cheese_N = regN "formaggio" ;
+  child_N = regN "bambino" ;
+  church_N = regN "chiesa" ;
+  city_N = regN "città" ;
+  clean_A = regADeg "proprio" ;
+  clever_A = regADeg "saggio" ;
+  close_V2 = dirV2 (verboV (chiudere_30 "chiudere")) ;
+  coat_N = regN "cappotto" ;
+  cold_A = regADeg "freddo" ;
+  come_V = essereV (verboV (venire_110 "venire")) ;
+  computer_N = regN "computer"  ;
+  country_N = regN "paese" ;
+  cousin_N = regN "cugino" ; --- cousine
+  cow_N = regN "vacca" ;
+  die_V = verboV (morire_105 "morire") ;
+  dirty_A = regADeg "sporco" ;
+  distance_N3 = mkN3 (regN "distanza") genitive dative ;
+  doctor_N = mkN "medico" "medici" masculine ;
+  dog_N = regN "cane" ;
+  door_N = regN "porta" ;
+  drink_V2 = dirV2 (verboV (bere_27 "bere")) ;
+  easy_A2V = mkA2V (regA "facile") dative genitive ;
+  eat_V2 = dirV2 (regV "mangiare") ;
+  empty_A = regADeg "vuoto" ;
+  enemy_N = regN "nemico" ;
+  factory_N = regN "stabilimento" ;
+  father_N2 = diN2 (regN "padre") ;
+  fear_VS = mkVS (verboV (temere_20 "temere")) ;
+  find_V2 = dirV2 (regV "trovare") ;
+  fish_N = regN "pesca" ;
+  floor_N = regN "pavimento" ;
+  forget_V2 = dirV2 (regV "dimenticare") ;
+  fridge_N = regN "frigorifero" ;
+  friend_N = regN "amico" ;
+  fruit_N = regN "frutta" ;
+  fun_AV = mkAV (regA "divertente") genitive ;
+  garden_N = regN "giardino" ;
+  girl_N = regN "ragazza" ;
+  glove_N = regN "guanto" ;
+  gold_N = regN "oro" ;
+  good_A = prefA (mkADeg (regA "buono") 
+    (mkA "migliore" "migliore" "migliori" "migliori" "meglio")) ;
+  go_V = essereV (verboV (andare_14 "andare")) ;
+  green_A = regADeg "verde" ;
+  harbour_N = regN "porto" ;
+  hate_V2 = dirV2 (regV "odiare") ;
+  hat_N = regN "capello" ;
+  have_V2 = dirV2 (verboV (avere_2 "avere")) ;
+  hear_V2 = dirV2 (verboV (sentire_99 "sentire")) ;
+  hill_N = regN "collina" ;
+  hope_VS = mkVS (regV "sperare") ;
+  horse_N = regN "cavallo" ;
+  hot_A = regADeg "caldo" ;
+  house_N = regN "casa" ;
+  important_A = regADeg "importante" ;
+  industry_N = regN "industria" ;
+  iron_N = regN "ferro" ;
+  king_N = regN "ré" ;
+  know_V2 = dirV2 (verboV (conoscere_37 "conoscere")) ; --- savoir_V2 : VS
+  lake_N = regN "lago" ;
+  lamp_N = regN "lampa" ;
+  learn_V2 = dirV2 (regV "imparare") ;
+  leather_N = regN "cuoio" ;
+  leave_V2 = dirV2 (regV "lasciare") ;
+  like_V2 = dirV2 (regV "amare") ;
+  listen_V2 = dirV2 (regV "ascoltare") ;
+  live_V = verboV (vivere_95 "vivere") ;
+  long_A = regADeg "lungo" ;
+  lose_V2 = dirV2 (verboV (perdere_62 "perdere")) ;
+  love_N = regN "amore" ;
+  love_V2 = dirV2 (regV "amare") ;
+  man_N = regN "uomo" ;
+  married_A2 = mkA2 (regA "sposato") dative ;
+  meat_N = femN (regN "carne") ;
+  milk_N = regN "latte" ;
+  moon_N = regN "luna" ;
+  mother_N2 = diN2 (femN (regN "madre")) ;
+  mountain_N = regN "montagna" ;
+  music_N = regN "musica" ;
+  narrow_A = regADeg "stretto" ;
+  new_A = prefA (regADeg "nuovo") ;
+  newspaper_N = regN "giornale" ;
+  oil_N = regN "olio" ;
+  old_A =  prefA (regADeg "vecchio") ;
+  open_V2 = dirV2 (verboV (aprire_102 "aprire")) ;
+  paint_V2A = mkV2A (verboV (cingere_31 "pingere")) accusative ;
+  paper_N = regN "carta" ;
+  paris_PN = mkPN "Parigi" masculine ;
+  peace_N = femN (regN "pace") ;
+  pen_N = regN "penna" ;
+  planet_N = regN "pianeta" ;
+  plastic_N = regN "plastica" ;
+  play_V2 = dirV2 (regV "giocare") ;
+  policeman_N = regN "carabiniere" ;
+  priest_N = regN "prete" ;
+  probable_AS = mkAS (regA "probabile") ;
+  queen_N = regN "regina" ;
+  radio_N = mkN "radio" "radio" feminine ;
+  rain_V0 = mkV0 (verboV (piovere_66 "piovere")) ;
+  read_V2 = dirV2 (verboV (leggere_56 "leggere")) ;
+  red_A = regADeg "rosso" ;
+  religion_N = femN (regN "religione") ;
+  restaurant_N = regN "ristorante" ;
+  river_N = regN "fiume" ;
+  rock_N = regN "roccia" ;
+  roof_N = regN "tetto" ;
+  rubber_N = regN "gomma" ;
+  run_V = verboV (correre_38 "correre") ;
+  say_VS = mkVS (verboV (dire_41 "dire")) ;
+  school_N = regN "scuola" ;
+  science_N = regN "scienza" ;
+  sea_N = regN "mare" ;
+  seek_V2 = dirV2 (regV "cercare") ;
+  see_V2 = dirV2 (verboV (vedere_93 "vedere")) ;
+  sell_V3 = dirV3 (verboV (scendere_80 "vendere")) dative ; ---- except some forms
+  send_V3 = dirV3 (regV "mandare") dative ;
+  sheep_N = regN "agnello" ;
+  ship_N = femN (regN "nave") ;
+  shirt_N = regN "camicia" ;
+  shoe_N = regN "scarpa" ;
+  shop_N = regN "magazzino" ;
+  short_A = regADeg "corto" ; --- breve
+  silver_N = regN "argento" ;
+  sister_N = regN "sorella" ;
+  sleep_V = verboV (dormire_99b "dormire") ;
+  small_A = prefA (regADeg "piccolo") ;
+  snake_N = regN "serpente" ;
+  sock_N = regN "calza" ;
+  speak_V2 = dirV2 (regV "parlare") ;
+  star_N = regN "stella" ;
+  steel_N = regN "acciaio" ;
+  stone_N = regN "sasso" ;
+  stove_N = regN "forno" ;
+  student_N = regN "studente" ;
+  stupid_A = regADeg "stupido" ;
+  sun_N = regN "sole" ;
+  switch8off_V2 = dirV2 (verboV (cingere_31 "spingere")) ;
+  switch8on_V2 = dirV2 (regV "allumare") ; ----
+  table_N = regN "tavola" ; --- tavolo
+  talk_V3 = mkV3 (regV "parlare") dative genitive ;
+  teacher_N = regN "professore" ;
+  teach_V2 = dirV2 (regV "insegnare") ;
+  television_N = femN (regN "televisione") ;
+  thick_A = regADeg "grosso" ;
+  thin_A = regADeg "sottile" ;
+  train_N = regN "treno" ;
+  travel_V = regV "viaggare" ;
+  tree_N = regN "albero" ;
+ --- trousers_N = regN "pantalon" ;
+  ugly_A = regADeg "brutto" ;
+  understand_V2 = dirV2 (regV "capire") ;
+  university_N = regN "università" ;
+  village_N = regN "paese" ;
+  wait_V2 = mkV2 (regV "aspettare") dative ;
+  walk_V = regV "camminare" ;
+  warm_A = regADeg "caldo" ;
+  war_N = regN "guerra" ;
+  watch_V2 = dirV2 (regV "guardare") ;
+  water_N = regN "acqua" ;
+  white_A = compADeg (regA "bianco") ;
+  window_N = regN "finestra" ;
+  wine_N = regN "vino" ;
+  win_V2 = dirV2 (verboV (vincere_94 "vincere")) ;
+  woman_N = regN "donna" ;
+  wonder_VQ = mkVQ (regV "domandare") ; ---- domandarsi
+  wood_N = regN "legno" ;
+  write_V2 = dirV2 (verboV (scrivere_82 "scrivere")) ;
+  yellow_A = regADeg "giallo" ;
+  young_A = prefA (regADeg "giovane") ;
+
+  do_V2 =  dirV2 (verboV (fare_52 "fare")) ;
+  now_Adv = mkAdv "adesso" ;
+  already_Adv = mkAdv "già" ;
+  song_N = femN (regN "canzone") ;
+  add_V3 = dirV3 (verboV (giungere_55 "aggiungere")) dative ;
+  number_N = regN "numero" ;
+  put_V2 = dirV2 (verboV (mettere_57 "mettere")) ;
+  stop_V = regV "fermare" ; ---- fermarsi
+  jump_V = regV "saltare" ;
+{-
+  here_Adv = mkAdv "quì" ;
+  here7to_Adv = mkAdv "quì" ;
+  here7from_Adv = mkAdv ["da quì"] ;
+  there_Adv = mkAdv "lì" ;
+  there7to_Adv = mkAdv "lì" ;
+  there7from_Adv = mkAdv ["da lì"] ;
+-}
+} ;

lib/resource-1.0/italian/MorphoIta.gf

@@ -0,0 +1,162 @@
+--# -path=.:../romance:../common:../../prelude
+
+--1 A Simple Italian Resource Morphology
+--
+-- Aarne Ranta 2002 -- 2005
+--
+-- This resource morphology contains definitions needed in the resource
+-- syntax. To build a lexicon, it is better to use $ParadigmsIta$, which
+-- gives a higher-level access to this module.
+
+resource MorphoIta = CommonRomance, ResIta ** 
+  open PhonoIta, Prelude, Predef in {
+
+  flags optimize=all ;
+
+
+
+--2 Nouns
+--
+-- The following macro is useful for creating the forms of number-dependent
+-- tables, such as common nouns.
+
+oper
+  numForms : (_,_ : Str) -> Number => Str = \vino, vini ->
+    table {Sg => vino ; Pl => vini} ; 
+
+-- For example:
+
+  nomVino : Str -> Number => Str = \vino -> let {vin = Predef.tk 1 vino} in
+    numForms vino (vin + "i") ;
+
+  nomRana : Str -> Number => Str = \rana -> let {ran = Predef.tk 1 rana} in
+    numForms rana (ran + "e") ;
+
+  nomSale : Str -> Number => Str = \sale -> let {sal = Predef.tk 1 sale} in
+    numForms sale (sal + "i") ;
+
+  nomTram : Str -> Number => Str = \tram ->
+    numForms tram tram ;
+
+-- Common nouns are inflected in number and have an inherent gender.
+
+  mkNoun : (Number => Str) -> Gender -> Noun = \mecmecs,gen -> 
+    {s = mecmecs ; g = gen} ;
+
+  mkNounIrreg : Str -> Str -> Gender -> Noun = \mec,mecs -> 
+    mkNoun (numForms mec mecs) ;
+
+  mkNomReg : Str -> Noun = \vino -> 
+   let
+     o = last vino ;
+     vin = init vino ;
+     n = last vin
+   in
+   case o of {
+     "o" => {s = case n of {
+       "c" | "g" => numForms vino (vin + "hi") ;
+       "i"       => numForms vino vin ;
+       _         => numForms vino (vin + "i")
+       } ; g = Masc} ;
+     "a" => {s = case n of {
+       "c" | "g" => numForms vino (vin + "he") ;
+       _         => numForms vino (vin + "e")
+       } ; g = Fem} ;
+     "e" => {s = numForms vino (vin + "i")
+       ; g = Masc} ;
+     "à" | "ù" => {s = numForms vino vino
+       ; g = Fem} ;
+     _ => {s = numForms vino vino
+       ; g = Masc}
+     } ;
+
+
+
+--2 Adjectives
+--
+-- Adjectives are conveniently seen as gender-dependent nouns.
+-- Here are some patterns. First one that describes the worst case.
+
+  mkAdj : (_,_,_,_,_ : Str) -> Adj = \solo,sola,soli,sole,solamente ->
+    {s = table {
+       AF Masc n => numForms solo soli ! n ;
+       AF Fem  n => numForms sola sole ! n ;
+       AA        => solamente
+       }
+    } ;
+
+-- Then the regular and invariant patterns.
+
+  adjSolo : Str -> Adj = \solo -> 
+    let 
+      sol = Predef.tk 1 solo
+    in
+    mkAdj solo (sol + "a") (sol + "i") (sol + "e") (sol + "amente") ;
+
+  adjTale : Str -> Adj = \tale -> 
+    let 
+      tal  = Predef.tk 1 tale ;
+      tali = tal + "i" ;
+      tala = if_then_Str (pbool2bool (Predef.occur (Predef.dp 1 tal) "lr")) tal tale
+    in
+    mkAdj tale tale tali tali (tala + "mente") ;
+
+  adjBlu : Str -> Adj = \blu -> 
+    mkAdj blu blu blu blu blu ; --- 
+
+
+  mkAdjReg : Str -> Adj = \solo ->
+   let
+     o = last solo ;
+     sol = init solo ;
+     l = last sol ;
+     solamente = (sol + "amente")
+   in
+   case o of {
+     "o" => case l of {
+       "c" | "g" => mkAdj solo (sol + "a") (sol + "hi") (sol + "he") solamente ;
+       "i"       => mkAdj solo (sol + "a") sol (sol + "e") solamente ;
+       _         => mkAdj solo (sol + "a") (sol + "i") (sol + "e") solamente
+       } ;
+     "e" => mkAdj solo solo (sol + "i") (sol + "i") (case l of {
+       "l" => sol + "mente" ;
+       _   => solo + "mente"
+       }) ;
+     _ => mkAdj solo solo solo solo (sol + "mente")
+     } ;
+
+
+--2 Personal pronouns
+--
+-- All the eight personal pronouns can be built by the following macro.
+-- The use of "ne" as atonic genitive is debatable.
+-- We follow the rule that the atonic nominative is empty.
+
+  mkPronoun : (_,_,_,_,_,_,_,_ : Str) -> 
+              Gender -> Number -> Person -> ClitType -> Pronoun =
+    \il,le,lui,Lui,son,sa,ses,see,g,n,p,c ->
+    {s = table {
+       Ton Nom => il ;
+       Ton x => prepCase x ++ Lui ;
+       Aton Nom => il ; ---- [] ;
+       Aton Acc => le ;
+       Aton (CPrep P_di) => "ne" ; --- hmm
+       Aton (CPrep P_a) => lui ;
+       Aton q       => prepCase q ++ Lui ; ---- GF bug with c or p! 
+       Poss {n = Sg ; g = Masc} => son ;
+       Poss {n = Sg ; g = Fem}  => sa ;
+       Poss {n = Pl ; g = Masc} => ses ;
+       Poss {n = Pl ; g = Fem}  => see
+       } ;
+     a = {g = g ; n = n ; p = p} ;
+     c = c
+    } ;
+
+--2 Determiners
+--
+-- Determiners, traditionally called indefinite pronouns, are inflected
+-- in gender and number, like adjectives.
+
+  pronForms : Adj -> Gender -> Number -> Str = \tale,g,n -> tale.s ! AF g n ;
+
+}

lib/resource-1.0/italian/NounIta.gf

@@ -0,0 +1,2 @@
+concrete NounIta of Noun = CatIta ** NounRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/NumeralIta.gf

@@ -0,0 +1,72 @@
+concrete NumeralIta of Numeral = CatIta ** 
+  open CommonRomance, ResRomance, MorphoIta, Prelude in {
+
+lincat 
+  Digit = {s : DForm => CardOrd => Str} ;
+  Sub10 = {s : DForm => CardOrd => Str ; n : Number} ;
+  Sub100 = {s : CardOrd => Str ; n : Number} ;
+  Sub1000 = {s : CardOrd => Str ; n : Number} ;
+  Sub1000000 = {s : CardOrd => Str ; n : Number} ;
+
+lin num x = x ;
+
+lin n2 = mkTal "due"     "dodici"      "venti"     "secondo" ;
+lin n3 = mkTal "tre"     "tredici"     "trenta"    "terzo" ;
+lin n4 = mkTal "quattro" "quattordici" "quaranta"  "quarto" ;
+lin n5 = mkTal "cinque"  "quindici"    "cinquanta" "quinto" ;
+lin n6 = mkTal "sei"     "sedici"      "sessanta"  "sesto" ;
+lin n7 = mkTal "sette"   "diciassette" "settanta"  "settimo" ; --- diciasettesimo?
+lin n8 = mkTal "otto"    "diciotto"    "ottanta"   "ottavo" ;
+lin n9 = mkTal "nove"    "diciannove"  "novanta"   "nono" ;
+
+lin pot01 = 
+  let uno = (mkTal "uno" "undici" "dieci" "primo").s in
+  {s =\\f,g => case f of {
+     ental pred => [] ;
+     _ => uno ! f ! g
+     } ; 
+   n = Pl} ;
+
+lin pot0 d = {s = d.s ; n = Pl} ;
+lin pot110 = spl ((mkTal "dieci" [] [] "decimo").s ! ental indip) ;
+lin pot111 = spl ((mkTal "undici" [] [] "undicesimo").s ! ental indip) ;
+lin pot1to19 d = spl (d.s ! ton) ;
+lin pot0as1 n = {s = n.s ! ental indip ; n = n.n} ;
+lin pot1 d = spl (d.s ! tiotal) ;
+lin pot1plus d e = 
+  {s = \\g => d.s ! tiotal ! NCard Masc ++ e.s ! ental indip ! g ; n = Pl} ;
+lin pot1as2 n = n ;
+lin pot2 d = spl (\\co => d.s ! ental pred ! NCard Masc ++ 
+  (mkTal "cento" [] [] "centesimo").s ! ental indip ! co) ;
+lin pot2plus d e = 
+  {s = \\g => d.s ! ental pred ! NCard Masc ++ "cento" ++ e.s ! g ; n = Pl} ;
+lin pot2as3 n = n ;
+lin pot3 n = spl (\\co => n.s ! NCard Masc ++ 
+  (mkTal (mille ! n.n) [] [] "millesimo").s ! ental indip ! co) ;
+lin pot3plus n m = {s = \\g => n.s ! NCard Masc ++ mille ! n.n ++ m.s ! g ; n = Pl} ;
+
+oper
+  mkTal : (x1,_,_,x4 : Str) -> {s : DForm => CardOrd => Str} =
+    \due,dodici,venti,secondo -> {s = \\d,co => case <d,co> of {
+       <ental _, NCard _>  => due ;
+       <ental _, NOrd g n> => pronForms (adjSolo secondo) g n ;
+       <tiotal,  NCard _>  => venti ;
+       <tiotal,  NOrd g n> => regCard venti g n ;
+       <ton,     NCard _>  => venti ;
+       <ton,     NOrd g n> => regCard venti g n
+       }
+    } ;
+
+  regCard : Str -> Gender -> Number -> Str = \venti ->
+    pronForms (adjSolo (init venti + "esimo")) ;
+
+  spl : (CardOrd => Str) -> {s : CardOrd => Str ; n : Number} = \s -> {
+    s = s ;
+    n = Pl
+    } ;
+
+oper mille : Number => Str = table {Sg => "mille" ; Pl => "mila"} ;
+param DForm = ental Pred | ton | tiotal  ;
+param Pred = pred | indip ;
+
+}

lib/resource-1.0/italian/ParadigmsIta.gf

@@ -0,0 +1,379 @@
+--# -path=.:../romance:../common:../abstract:../../prelude
+
+--1 Italian Lexical Paradigms
+--
+-- Aarne Ranta 2003
+--
+-- This is an API to the user of the resource grammar 
+-- for adding lexical items. It gives functions for forming
+-- expressions of open categories: nouns, adjectives, verbs.
+-- 
+-- Closed categories (determiners, pronouns, conjunctions) are
+-- accessed through the resource syntax API, $Structural.gf$. 
+--
+-- The main difference with $MorphoIta.gf$ is that the types
+-- referred to are compiled resource grammar types. We have moreover
+-- had the design principle of always having existing forms, rather
+-- than stems, as string arguments of the paradigms.
+--
+-- The structure of functions for each word class $C$ is the following:
+-- first we give a handful of patterns that aim to cover all
+-- regular cases. Then we give a worst-case function $mkC$, which serves as an
+-- escape to construct the most irregular words of type $C$.
+-- However, this function should only seldom be needed: we have a
+-- separate module $IrregularEng$, which covers all irregularly inflected
+-- words.
+
+resource ParadigmsIta = 
+  open 
+    (Predef=Predef), 
+    Prelude, 
+    CommonRomance, 
+    ResIta, 
+    MorphoIta, 
+    BeschIta,
+    CatIta in {
+
+  flags optimize=all ;
+
+--2 Parameters 
+--
+-- To abstract over gender names, we define the following identifiers.
+
+oper
+  Gender : Type ; 
+
+  masculine : Gender ;
+  feminine  : Gender ;
+
+-- To abstract over number names, we define the following.
+
+  Number : Type ; 
+
+  singular : Number ;
+  plural   : Number ;
+
+-- Prepositions used in many-argument functions are either strings
+-- (including the 'accusative' empty string) or strings that
+-- amalgamate with the following word (the 'genitive' "de" and the
+-- 'dative' "à").
+
+  Preposition : Type ;
+
+  accusative : Preposition ;
+  genitive   : Preposition ;
+  dative     : Preposition ;
+
+  mkPreposition : Str -> Preposition ;
+
+--2 Nouns
+
+-- Worst case: give both two forms and the gender. 
+
+  mkN  : (uomi,uomini : Str) -> Gender -> N ;
+
+-- The regular function takes the singular form and the gender,
+-- and computes the plural and the gender by a heuristic. 
+-- The heuristic says that the gender is feminine for nouns
+-- ending with "a", and masculine for all other words.
+
+  regN : Str -> N ;
+
+-- To force a different gender, use one of the following functions.
+
+  mascN : N -> N ;
+  femN  : N -> N ;
+
+--3 Compound nouns 
+--
+-- Some nouns are ones where the first part is inflected as a noun but
+-- the second part is not inflected. e.g. "numéro de téléphone". 
+-- They could be formed in syntax, but we give a shortcut here since
+-- they are frequent in lexica.
+
+  compN : N -> Str -> N ;
+
+
+--3 Relational nouns 
+-- 
+-- Relational nouns ("figlio di x") need a case and a preposition. 
+
+  mkN2 : N -> Preposition -> N2 ;
+
+-- The most common cases are the genitive "di" and the dative "a", 
+-- with the empty preposition.
+
+  diN2 : N -> N2 ;
+  aN2  : N -> N2 ;
+
+-- Three-place relational nouns ("la connessione di x a y") need two prepositions.
+
+  mkN3 : N -> Preposition -> Preposition -> N3 ;
+
+
+--3 Relational common noun phrases
+--
+-- In some cases, you may want to make a complex $CN$ into a
+-- relational noun (e.g. "the old town hall of"). However, $N2$ and
+-- $N3$ are purely lexical categories. But you can use the $AdvCN$
+-- and $PrepNP$ constructions to build phrases like this.
+
+-- 
+--3 Proper names and noun phrases
+--
+-- Proper names need a string and a gender.
+
+  mkPN : Str -> Gender -> PN ;          -- Jean
+
+-- To form a noun phrase that can also be plural,
+-- you can use the worst-case function.
+
+  mkNP : Str -> Gender -> Number -> NP ; 
+
+--2 Adjectives
+
+-- Non-comparison one-place adjectives need five forms in the worst
+-- case (masc and fem singular, masc plural, adverbial).
+
+  mkA : (solo,sola,soli,sole, solamente : Str) -> A ;
+
+-- For regular adjectives, all other forms are derived from the
+-- masculine singular. 
+
+  regA : Str -> A ;
+
+-- These functions create postfix adjectives. To switch
+-- them to prefix ones (i.e. ones placed before the noun in
+-- modification, as in "petite maison"), the following function is
+-- provided.
+
+  prefA : A -> A ;
+
+--3 Two-place adjectives
+--
+-- Two-place adjectives need a preposition for their second argument.
+
+  mkA2 : A -> Preposition -> A2 ;
+
+--3 Comparison adjectives 
+
+-- Comparison adjectives are in the worst case put up from two
+-- adjectives: the positive ("buono"), and the comparative ("migliore"). 
+
+  mkADeg : A -> A -> A ;
+
+-- If comparison is formed by "più", as usual in Italian,
+-- the following pattern is used:
+
+  compADeg : A -> A ;
+
+-- The regular pattern is the same as $regA$ for plain adjectives, 
+-- with comparison by "plus".
+
+  regADeg : Str -> A ;
+
+
+--2 Adverbs
+
+-- Adverbs are not inflected. Most lexical ones have position
+-- after the verb. 
+
+  mkAdv : Str -> Adv ;
+
+-- Some appear next to the verb (e.g. "sempre").
+
+  mkAdV : Str -> AdV ;
+
+-- Adverbs modifying adjectives and sentences can also be formed.
+
+  mkAdA : Str -> AdA ;
+
+
+--2 Verbs
+--
+-- Regular verbs are ones with the infinitive "er" or "ir", the
+-- latter with plural present indicative forms as "finissons".
+-- The regular verb function is the first conjugation recognizes
+-- these endings, as well as the variations among
+-- "aimer, céder, placer, peser, jeter, placer, manger, assiéger, payer".
+
+  regV : Str -> V ;
+
+-- The module $BeschIta$ gives all the patterns of the "Bescherelle"
+-- book. To use them in the category $V$, wrap them with the function
+
+  verboV : Verbo -> V ;
+
+-- The function $regV$ gives all verbs the compound auxiliary "avere".
+-- To change it to "essere", use the following function.
+-- Reflexive implies "essere".
+
+  essereV : V -> V ;
+  reflV : V -> V ;
+
+
+--3 Two-place verbs
+--
+-- Two-place verbs need a preposition, except the special case with direct object.
+-- (transitive verbs). Notice that a particle comes from the $V$.
+
+  mkV2  : V -> Preposition -> V2 ;
+
+  dirV2 : V -> V2 ;
+
+-- You can reuse a $V2$ verb in $V$.
+
+  v2V : V2 -> V ;
+
+--3 Three-place verbs
+--
+-- Three-place (ditransitive) verbs need two prepositions, of which
+-- the first one or both can be absent.
+
+  mkV3     : V -> Preposition -> Preposition -> V3 ; -- parler, à, de
+  dirV3    : V -> Preposition -> V3 ;                -- donner,_,à
+  dirdirV3 : V -> V3 ;                               -- donner,_,_
+
+
+--3 Other complement patterns
+--
+-- Verbs and adjectives can take complements such as sentences,
+-- questions, verb phrases, and adjectives.
+
+  mkV0  : V -> V0 ;
+  mkVS  : V -> VS ;
+  mkV2S : V -> Preposition -> V2S ;
+  mkVV  : V -> VV ;  -- plain infinitive: "je veux parler"
+  deVV  : V -> VV ;  -- "j'essaie de parler"
+  aVV   : V -> VV ;  -- "j'arrive à parler"
+  mkV2V : V -> Preposition -> Preposition -> V2V ;
+  mkVA  : V -> VA ;
+  mkV2A : V -> Preposition -> V2A ;
+  mkVQ  : V -> VQ ;
+  mkV2Q : V -> Preposition -> V2Q ;
+
+  mkAS   : A -> AS ;
+  subjAS : A -> AS ;
+  mkA2S : A -> Preposition -> A2S ;
+  mkAV  : A -> Preposition -> AV ;
+  mkA2V : A -> Preposition -> Preposition -> A2V ;
+
+-- Notice: categories $V2S, V2V, V2A, V2Q$ are in v 1.0 treated
+-- just as synonyms of $V2$, and the second argument is given
+-- as an adverb. Likewise $AS, A2S, AV, A2V$ are just $A$.
+-- $V0$ is just $V$.
+
+  V0, V2S, V2V, V2A, V2Q : Type ;
+  AS, A2S, AV, A2V : Type ;
+
+
+--2 The definitions of the paradigms
+--
+-- The definitions should not bother the user of the API. So they are
+-- hidden from the document.
+--.
+
+  Gender = MorphoIta.Gender ; 
+  Number = MorphoIta.Number ;
+  masculine = Masc ;
+  feminine = Fem ;
+  singular = Sg ;
+  plural = Pl ;
+
+  Preposition = Compl ;
+  accusative = complAcc ;
+  genitive = complGen ;
+  dative = complDat ;
+  mkPreposition p = {s = p ; c = Acc ; isDir = False} ;
+
+  mkN x y g = mkNounIrreg x y g ** {lock_N = <>} ;
+  regN x = mkNomReg x ** {lock_N = <>} ;
+  compN x y = {s = \\n => x.s ! n ++ y ; g = x.g ; lock_N = <>} ;
+  femN x = {s = x.s ; g = feminine ; lock_N = <>} ;
+  mascN x = {s = x.s ; g = masculine ; lock_N = <>} ;
+
+
+  mkN2 = \n,p -> n ** {lock_N2 = <> ; c2 = p} ;
+  diN2 n = mkN2 n genitive ;
+  aN2 n = mkN2 n dative ;
+  mkN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = p ; c3 = q} ;
+
+  mkPN x g = {s = x ; g = g} ** {lock_PN = <>} ;
+  mkNP x g n = {s = (pn2np (mkPN x g)).s; a = agrP3 g n ; c = Clit0} ** {lock_NP = <>} ;
+
+  mkA a b c d e = 
+   compADeg {s = \\_ => (mkAdj a b c d e).s ; isPre = False ; lock_A = <>} ;
+  regA a = compADeg {s = \\_ => (mkAdjReg a).s ; isPre = False ; lock_A = <>} ;
+  prefA a = {s = a.s ; isPre = True ; lock_A = <>} ;
+
+  mkA2 a p = a ** {c2 = p ; lock_A2 = <>} ;
+
+  mkADeg a b = 
+   {s = table {Posit => a.s ! Posit ; _ => b.s ! Posit} ; 
+    isPre = a.isPre ; lock_A = <>} ;
+  compADeg a = 
+    {s = table {Posit => a.s ! Posit ; _ => \\f => "più" ++ a.s ! Posit ! f} ; 
+     isPre = a.isPre ;
+     lock_A = <>} ;
+  regADeg a = compADeg (regA a) ;
+
+  mkAdv x = ss x ** {lock_Adv = <>} ;
+  mkAdV x = ss x ** {lock_AdV = <>} ;
+  mkAdA x = ss x ** {lock_AdA = <>} ;
+
+  regV x = 
+    let 
+      are = Predef.dp 3 x ;
+      ci  = Predef.dp 2 (Predef.tk 3 x) ;
+      i   = last ci ;
+      verb = case are of {
+        "ire" =>  finire_100 x ;
+        _ => case i of {
+          "c" => cercare_7 x ;
+          "g" => legare_8 x ;
+          _ => case ci of {
+            "ci" => cominciare_9 x ;
+            "gi" => mangiare_10 x ;
+           _    => amare_6 x
+            }
+          }
+        }
+    in verbBesch verb ** {vtyp = VHabere ; lock_V = <>} ;
+
+  verboV ve = verbBesch ve ** {vtyp = VHabere ; lock_V = <>} ;
+
+  essereV v = {s = v.s ; vtyp = VEsse ; lock_V = <>} ;
+  reflV v = {s = v.s ; vtyp = VRefl ; lock_V = <>} ;
+
+  mkV2 v p = {s = v.s ; vtyp = v.vtyp ; c2 = p ; lock_V2 = <>} ;
+  dirV2 v = mkV2 v accusative ;
+  v2V v = v ** {lock_V = <>} ;
+
+  mkV3 v p q = {s = v.s ; vtyp = v.vtyp ; 
+    c2 = p ; c3 = q ; lock_V3 = <>} ;
+  dirV3 v p = mkV3 v accusative p ;
+  dirdirV3 v = dirV3 v dative ;
+
+  V0 : Type = V ;
+  V2S, V2V, V2Q, V2A : Type = V2 ;
+  AS, AV : Type = A ;
+  A2S, A2V : Type = A2 ;
+
+  mkV0  v = v ** {lock_V0 = <>} ;
+  mkVS  v = v ** {m = \\_ => Indic ; lock_VS = <>} ;  ---- more moods
+  mkV2S v p = mkV2 v p ** {mn,mp = Indic ; lock_V2S = <>} ;
+  mkVV  v = v ** {c2 = complAcc ; lock_VV = <>} ;
+  deVV  v = v ** {c2 = complGen ; lock_VV = <>} ;
+  aVV  v = v ** {c2 = complDat ; lock_VV = <>} ;
+  mkV2V v p t = mkV2 v p ** {c3 = t.p1  ; s3 = p.p2 ; lock_V2V = <>} ;
+  mkVA  v = v ** {lock_VA = <>} ;
+  mkV2A v p = mkV2 v p ** {lock_V2A = <>} ;
+  mkVQ  v = v ** {lock_VQ = <>} ;
+  mkV2Q v p = mkV2 v p ** {lock_V2Q = <>} ;
+
+  mkAS  v = v ** {lock_AS = <>} ; ---- more moods
+  mkA2S v p = mkA2 v p ** {lock_A2S = <>} ;
+  mkAV  v p = v ** {c = p.p1 ; s2 = p.p2 ; lock_AV = <>} ;
+  mkA2V v p q = mkA2 v p ** {s3 = q.p2 ; c3 = q.p1 ; lock_A2V = <>} ;
+
+} ;

lib/resource-1.0/italian/PhonoIta.gf

@@ -0,0 +1,20 @@
+resource PhonoIta = open Prelude in {
+
+--3 Elision
+--
+-- The phonological rule of *elision* can be defined as follows in GF.
+-- In Italian it includes both vowels and the *impure 's'*.
+
+oper 
+  vocale : Strs = strs {
+    "a" ; "e" ; "h" ; "i" ; "o" ; "u"
+    } ;
+
+  sImpuro : Strs = strs {
+    "z" ; "sb" ; "sc" ; "sd" ; "sf" ; "sm" ; "sp" ; "sq" ; "sr" ; "st" ; "sv"
+    } ;
+
+  elision : (_,_,_ : Str) -> Str = \il, l', lo -> 
+    pre {il ; l' / vocale ; lo / sImpuro} ;
+
+}

lib/resource-1.0/italian/PhraseIta.gf

@@ -0,0 +1,2 @@
+concrete PhraseIta of Phrase = CatIta ** PhraseRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/QuestionIta.gf

@@ -0,0 +1,2 @@
+concrete QuestionIta of Question = CatIta ** QuestionRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/RelativeIta.gf

@@ -0,0 +1,2 @@
+concrete RelativeIta of Relative = CatIta ** RelativeRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/ResIta.gf

@@ -0,0 +1,11 @@
+--1 Italian auxiliary operations.
+--
+---- This module contains operations that are needed to make the
+---- resource syntax work. To define everything that is needed to
+---- implement $Test$, it moreover contains regular lexical
+---- patterns needed for $Lex$.
+--
+
+instance ResIta of ResRomance = DiffIta ** open CommonRomance, Prelude in {
+
+} ;

lib/resource-1.0/italian/SentenceIta.gf

@@ -0,0 +1,2 @@
+concrete SentenceIta of Sentence = CatIta ** SentenceRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/StructuralIta.gf

@@ -0,0 +1,128 @@
+concrete StructuralIta of Structural = CatIta ** 
+  open PhonoIta, MorphoIta, ParadigmsIta, BeschIta, Prelude in {
+
+  flags optimize=all ;
+
+lin
+
+  above_Prep = {s = ["sopra"] ; c = MorphoIta.genitive ; isDir = False} ;
+  after_Prep = mkPreposition "dopo" ;
+  all_Predet = {
+    s = \\a,c => prepCase c ++ aagrForms "tutto" "tutta" "tutti" "tutte" ! a ;
+    c = Nom
+    } ;
+  almost_AdA, almost_AdN = ss "quasi" ;
+  always_AdV = ss "sempre" ;
+  although_Subj = ss "benché" ** {m = Conjunct} ;
+  and_Conj = ss "e" ** {n = Pl} ;
+  because_Subj = ss "perché" ** {m = Indic} ;
+  before_Prep = mkPreposition "prima" ;
+  behind_Prep = mkPreposition "dietro" ;
+  between_Prep = mkPreposition "fra" ;
+  both7and_DConj = {s1,s2 = "e" ; n = Pl} ;
+  but_PConj = ss "ma" ;
+  by8agent_Prep = {s = [] ; c = CPrep P_da} ;
+  by8means_Prep = mkPreposition "per" ;
+  can8know_VV = mkVV (verboV (sapere_78 "sapere")) ;
+  can_VV = mkVV (verboV (potere_69 "potere")) ;
+  during_Prep = mkPreposition "durante" ;
+  either7or_DConj = {s1,s2 = "o" ; n = Sg} ;
+  everybody_NP = pn2np (mkPN ["tutto il mondo"] Masc) ;
+  every_Det = {s = \\_,_ => "ogni" ; n = Sg} ;
+  everything_NP = pn2np (mkPN ["tutto"] Masc) ;
+  everywhere_Adv = ss "dappertutto" ;
+  first_Ord = {s = \\ag => (regA "primo").s ! Posit ! AF ag.g ag.n} ;
+  from_Prep = complGen ; ---
+  he_Pron = 
+    mkPronoun
+      "lui" "lo" "gli" "lui" "suo" "sua" "suoi" "sue"
+      Masc Sg P3 Clit2 ;
+  here7from_Adv = ss ["da quì"] ;
+  here7to_Adv = ss "quì" ;
+  here_Adv = ss "quì" ;
+  how_IAdv = ss "come" ;
+  how8many_IDet = {s = \\g,c => prepCase c ++ genForms "quanti" "quante" ! g ; n = Pl} ;
+  if_Subj = ss "se" ** {m = Indic} ;
+  in8front_Prep = mkPreposition "davanti" ;
+  i_Pron = 
+    mkPronoun
+      "io" "mi" "mi" "me" "mio" "mia" "miei" "mie"
+      Fem Sg P1 Clit1 ;
+  in_Prep = {s = [] ; c = CPrep P_in} ;
+  it_Pron = 
+    mkPronoun
+      "lui" "lo" "gli" "lui" "suo" "sua" "suoi" "sue"
+      Masc Sg P3 Clit2 ;
+  less_CAdv = ss "meno" ;
+  many_Det = {s = \\g,c => prepCase c ++ genForms "molti" "molte" ! g ; n = Pl} ;
+  more_CAdv = ss "più" ;
+  most_Predet = {s = \\_,c => prepCase c ++ ["la maggior parte"] ; c = CPrep P_di} ;
+  much_Det = {s = \\g,c => prepCase c ++ genForms "molto" "molta" ! g ; n = Sg} ;
+  must_VV = mkVV (verboV (dovere_47 "dovere")) ;
+  no_Phr = ss "no" ;
+  on_Prep = {s = [] ; c = CPrep P_su} ;
+  one_Quant = {s = \\g,c => prepCase c ++ genForms "uno" "una" ! g} ;
+  only_Predet = {s = \\_,c => prepCase c ++ "soltanto" ; c = Nom} ; --- solo|a|i|e
+  or_Conj = {s = "o" ; n = Sg} ;
+  otherwise_PConj = ss "altramente" ;
+  part_Prep = complGen ;
+  please_Voc = ss ["per favore"] ;
+  possess_Prep = complGen ;
+  quite_Adv = ss "assai" ;
+  she_Pron = 
+    mkPronoun
+      "lei" "la" "le" "lei" "suo" "sua" "suoi" "sue"
+      Fem Sg P3 Clit2 ;
+  so_AdA = ss "così" ;
+  somebody_NP = pn2np (mkPN ["quelcuno"] Masc) ;
+  somePl_Det = {s = \\_,c => prepCase c ++ "qualche" ; n = Pl} ;
+  someSg_Det = {s = \\_,c => prepCase c ++ "qualche" ; n = Sg} ;
+  something_NP = pn2np (mkPN ["qualche cosa"] Masc) ;
+  somewhere_Adv = ss ["qualche parte"] ;
+  that_Quant = {s = \\g,c => prepCase c ++ genForms "quello" "quella" ! g} ;
+  that_NP = mkNP ["questo"] Masc Sg ;
+  there7from_Adv = ss ["di là"] ;
+  there7to_Adv = ss "là" ; --- ci
+  there_Adv = ss "là" ;
+  therefore_PConj = ss "quindi" ;
+  these_NP = mkNP ["queste"] Fem Pl ;
+  these_Quant = {s = \\g,c => prepCase c ++ genForms "questo" "questa" ! g} ;
+  they_Pron = mkPronoun
+    "loro" "loro" "li" "loro" "loro" "loro" "loro" "loro" 
+    Fem Pl P3 Clit1 ;
+  this_Quant = {s = \\g,c => prepCase c ++ genForms "questo" "questa" ! g} ;
+  this_NP = pn2np (mkPN ["questo"] Masc) ;
+  those_NP = mkNP ["quelle"] Fem Pl ;
+  those_Quant = {s = \\g,c => prepCase c ++ genForms "quelli" "quelle" ! g} ; --- quegli
+  through_Prep = mkPreposition "per" ;
+  too_AdA = ss "troppo" ;
+  to_Prep = complDat ;
+  under_Prep = mkPreposition "sotto" ;
+  very_AdA = ss "molto" ;
+  want_VV = mkVV (verboV (volere_96 "volere")) ;
+  we_Pron = 
+    mkPronoun "noi" "ci" "ci" "noi" "nostro" "nostra" "nostri" "nostre"
+    Fem Pl P1 Clit3 ;
+  whatSg_IP = {s = \\c => prepCase c ++ ["che cosa"] ; a = aagr Fem Sg} ;
+  whatPl_IP = {s = \\c => prepCase c ++ ["che cose"] ; a = aagr Fem Pl} ; ---
+  when_IAdv = ss "quando" ;
+  when_Subj = ss "quando" ** {m = Indic} ;
+  where_IAdv = ss "dove" ;
+  whichPl_IDet = {s = \\g,c => prepCase c ++ genForms "quale" "quale" ! g ; n = Sg} ;
+  whichSg_IDet = {s = \\g,c => prepCase c ++ genForms "quali" "quali" ! g; n = Pl} ;
+  whoPl_IP = {s = \\c => prepCase c ++ "chi" ; a = aagr Fem Pl} ;
+  whoSg_IP = {s = \\c => prepCase c ++ "chi" ; a = aagr Fem Sg} ;
+  why_IAdv = ss "perché" ;
+  without_Prep = mkPreposition "senza" ;
+  with_Prep = {s = [] ; c = CPrep P_con} ;
+  yes_Phr = ss "sì" ;
+  youSg_Pron = mkPronoun 
+    "tu" "ti" "ti" "te" "tuo" "tua" "tuoi" "tue"
+    Fem Sg P2 Clit1 ;
+  youPl_Pron =
+    mkPronoun
+       "voi" "vi" "vi" "voi" "vostro" "vostra" "vostri" "vostre"
+       Fem Pl P2 Clit3 ;
+
+}
+

lib/resource-1.0/italian/VerbIta.gf

@@ -0,0 +1,2 @@
+concrete VerbIta of Verb = CatIta ** VerbRomance with
+  (ResRomance = ResIta) ;

lib/resource-1.0/italian/log.txt

@@ -0,0 +1,14 @@
+1/2/2006
+
+14:05 rename and sed as in HOWTO
+The grammar compiles but produces French
+
+PhonoIta from 0.9
+MorphoIta from 0.9
+DiffIta
+ParadigmsIta from 0.9
+LexiconIta from 0.9
+StructuralIta, filling StructuralFre from 0.9
+NumeralsIta from 0.9 adding ordinals
+
+17:30 done - but needs more testing.

lib/resource-1.0/romance/CommonRomance.gf

@@ -25,6 +25,8 @@ resource CommonRomance = ParamRomance ** open Prelude in {
 
     Noun = {s : Number => Str ; g : Gender} ;
 
+    Adj = {s : AForm => Str} ;
+
     VP : Type = {
       s : VPForm => {
         fin : Agr  => Str ;             -- ai