gf-core/lib/src/nynorsk/LexiconNno.gf

--# -path=.:../scandinavian:../common:../abstract:../../prelude

concrete LexiconNno of Lexicon = CatNno **
  open Prelude, ParadigmsNno, IrregNno in {

flags startcat=Phr ; lexer=textlit ; unlexer=text ;
    coding=utf8 ;
  optimize=values ;

lin
  airplane_N = mk2N "fly" "flyet" ;
  answer_V2S = mkV2S (regV "svare") (mkPrep "til") ;
  apartment_N = mk2N "leilegheit" "leilegheita" ;
  apple_N = mk2N "eple" "eplet" ;
  art_N = mk2N "kunst" "kunsten" ;
  ask_V2Q = mkV2Q spørre_V noPrep ; -- fikse
  baby_N = mk2N "baby" "babyen" ;
  bad_A = regADeg "dårleg" ;
  bank_N = mk2N "bank" "banken" ;
  beautiful_A = mkADeg "vakker" "vakkert" "vakre" "vakrare" "vakrast" ;
  become_VA = mkVA (vaereV verte_V) ; -- fikse
  beer_N = regGenN "øl" neutrum ; -- fikse
  beg_V2V = mkV2V be_V noPrep (mkPrep "å") ;
  big_A = irregADeg "stor" "større" "størst";
  bike_N = mkN "sykkel" "sykkelen" "syklar" "syklane" ;
  bird_N = mk2N "fugl" "fuglen" ;
  black_A = mk2ADeg "svart" "svart" ;
  blue_A = mk2ADeg "blå" "blått";
  boat_N = regGenN "båt" masculine ;
  book_N = mkN "bok" "boka" "bøker" "bøkene" ;
  boot_N = mkN "støvel" "støvelen" "støvlar" "støvlane" ;
  boss_N = mk2N "sjef" "sjefen" ;
  boy_N = regGenN "gut" masculine ;
  bread_N = regGenN "brød" neutrum ;
  break_V2 = dirV2 (mk2V "knuse" "knuste") ;
  broad_A = regADeg "brei" ;
  brother_N2 = mkN2 ( (mkN "bror" "broren" "brødre" "brødrene")) (mkPrep "til") ;
  brown_A = regADeg "brun" ;
  butter_N = regGenN "smør" neutrum ;
  buy_V2 = dirV2 (mk2V "kjøpe" "kjøpte") ;
  camera_N = mk2N "kamera" "kameraet" ; ----
  cap_N = mk2N "hue" "hua" ;
  car_N = regGenN "bil" masculine ;
  carpet_N = regGenN "matte" feminine ;
  cat_N = mk2N "katt" "katten" ;
  ceiling_N = regGenN "tak" neutrum ;
  chair_N = regGenN "stol" masculine ;
  cheese_N = regGenN "ost" masculine ;
  child_N = regGenN "born" neutrum ;
  church_N = regGenN "kyrke" feminine ;
  city_N = mk2N "by" "byen" ;
  clean_A = regADeg "rein" ;
  clever_A = regADeg "klok" ;
  close_V2 = dirV2 (mk2V "lukke" "lukket") ; -- ?
  coat_N = regGenN "frakk" masculine ;
  cold_A = regADeg "kald" ;
  come_V = vaereV IrregNno.komme_V ;
  computer_N = mk2N "datamaskin" "datamaskina" ;
  country_N = mk2N "land" "landet" ;
  cousin_N = mk2N "fetter" "fetteren" ; ----
  cow_N = mkN "ku" "kua" "kyr" "kyrne" ; ----
  die_V = vaereV IrregNno.dø_V ;
  dirty_A = mkADeg "skiten" "skite" "skitne" "skitnare" "skitnast" ;
  distance_N3 = mkN3 (regGenN "avstand" masculine) (mkPrep "frå") (mkPrep "til") ;
  doctor_N = mk2N "lege" "legen" ;
  dog_N = regGenN "hund" masculine ;
  door_N = regGenN "dør" feminine ;
  drink_V2 = dirV2 IrregNno.drikke_V ;
  easy_A2V = mkA2V (regA "grei") (mkPrep "for") ; -- ?
  eat_V2 = dirV2 (mk2V "spise" "spiste") ; -- fikse ete
  empty_A = mkADeg "tom" "tomt" "tomme" "tommare" "tommast" ;
  enemy_N = regGenN "fiende" masculine ;
  factory_N = mk2N "fabrikk" "fabrikken" ;
  father_N2 = mkN2 ( (mkN "far" "faren" "fedre" "fedrene")) (mkPrep "til") ;
  fear_VS = mkVS (regV "frykte") ;
  find_V2 = dirV2 (irregV "finne" "fann" "funnet") ; --?
  fish_N = mk2N "fisk" "fisken" ;
  floor_N = regGenN "golv" neutrum ;
  forget_V2 = dirV2 (mkV "gløyme" "gløymer" "gløymas" "gløymde" "gløymt" "gløym") ;
  fridge_N = regGenN "kjøleskap" neutrum ;
  friend_N = mkN "ven" "venen" "venar" "venane" ;
  fruit_N = mk2N "frukt" "frukta" ;
  fun_AV = mkAV (mkA "morosam" "morosamt" "morosame") ;
  garden_N = regGenN "hage" masculine ;
  girl_N = regGenN "jente" feminine ;
  glove_N = regGenN "hanske" masculine ;
  gold_N = regGenN "gull" neutrum ;
  good_A = mkADeg "god" "godt" "gode" "betre" "best" ;
  go_V = IrregNno.gå_V ;
  green_A = mk2ADeg "grøn" "grønt" ;
  harbour_N = regGenN "havn" feminine;
  hate_V2 = dirV2 (regV "hate") ;
  hat_N = regGenN "hatt" masculine ;
  hear_V2 = dirV2 (mk2V "høyre" "høyrte") ;
  hill_N = regGenN "bakke" masculine ;
  hope_VS = mkVS (regV "vone") ;
  horse_N = regGenN "hest" masculine ;
  hot_A = regADeg "varm" ;
  house_N = regGenN "hus" neutrum ;
  important_A = regADeg "viktig" ;
  industry_N = mk2N "industri" "industrien" ;
  iron_N = regGenN "jern" neutrum ;
  john_PN = mkPN "John" masculine ;
  king_N = regGenN "konge" masculine ;
  know_V2 = dirV2 (mkV "kjenne" "kjenner" "kjennast" "kjende" "kjent" "kjenn") ;
  know_VQ = mkVQ IrregNno.vite_V ;
  know_VS = mkVS IrregNno.vite_V ;
  lake_N = regGenN "vatn" neutrum ;
  lamp_N = regGenN "lampe" feminine ;
  learn_V2 = dirV2 (mk2V "lære" "lærde") ;
  leather_N = regGenN "ler" neutrum ;
  leave_V2 = dirV2 forlate_V ;
  like_V2 = dirV2 (mk2V "like" "likte") ;
  listen_V2 = dirV2 (regV "lytte") ;
  live_V = mk2V "leve" "levde" ;
  long_A = irregADeg "lang" "lengre" "lengst" ;
  lose_V2 = dirV2 (mk2V "tape" "tapte") ;
  love_N = regGenN "kjærleik" masculine ;
  love_V2 = dirV2 (regV "elske") ;
  man_N =  (mkN "mann" "mannen" "menn" "mennene") ;
  married_A2 = mkA2 (mk2A "gift" "gift") (mkPrep "med") ;
  meat_N = regGenN "kjøtt" neutrum ;
  milk_N = regGenN "mjølk" feminine ;
  moon_N = regGenN "måne" masculine ;
  mother_N2 = mkN2 (mkN "mor" "mora" "mødre" "mødrene") (mkPrep "til") ; ---- fem
  mountain_N = regGenN "fjell" neutrum ;
  music_N = mk2N "musikk" "musikken" ;
  narrow_A = regADeg "smal" ;
  new_A = mkADeg "ny" "nytt" "nye" "nyare" "nyast" ;
  newspaper_N = regGenN "avis" feminine ;
  oil_N = regGenN "olje" masculine ;
  old_A = mkADeg "gammal" "gammalt" "gamle" "eldre" "eldst" ;
  open_V2 = dirV2 (regV "opne") ;
  paint_V2A = mkV2A (regV "måle") noPrep ;
  paper_N = regGenN "papir" neutrum ; ----
  paris_PN = regGenPN "Paris" neutrum ;
  peace_N = regGenN "fred" masculine ;
  pen_N = regGenN "penn" masculine ;
  planet_N = mk2N "planet" "planeten" ;
  plastic_N = mk2N "plast" "plasten" ;
  play_V2 = dirV2 (mk2V "spele" "spelde") ;
  policeman_N = mk2N "politi" "politiet" ;
  priest_N = mk2N "prest" "presten" ;
  probable_AS = mkAS (regA "sannsynleg") ;
  queen_N = regGenN "dronning" feminine ;
  radio_N = regGenN "radio" masculine ;
  rain_V0 = mkV0 (regV "regne") ;
  read_V2 = dirV2 (mk2V "lese" "leste") ;
  red_A = regADeg "raud" ;
  religion_N = mk2N "religion" "religionen" ;
  restaurant_N = mk2N "restaurant" "restauranten" ;
  river_N = mk2N "elv" "elva" ;
  rock_N = regGenN "stein" masculine ;
  roof_N = regGenN "tak" neutrum ;
  rubber_N = mk2N "gummi" "gummien" ;
  run_V = springe_V ;
  say_VS = mkVS si_V ;
  school_N = regGenN "skule" masculine;
  science_N = mk2N "vitskap" "vitskapen" ;
  sea_N = mk2N "sjø" "sjøen" ;
  seek_V2 = mkV2 (mk2V "leite" "leita") (mkPrep "etter") ;
  see_V2 = dirV2 se_V ;
  sell_V3 = dirV3 selge_V (mkPrep "til") ;
  send_V3 = dirV3 (mk2V "sende" "sendte") (mkPrep "til") ;
  sheep_N = mk2N "får" "fåret" ;
  ship_N = regGenN "skip" neutrum ;
  shirt_N = regGenN "skjorte" feminine ;
  shoe_N = mkN "sko" "skoen" "sko" "skoa" ;
  shop_N = mk2N "butikk" "butikken" ;
  short_A = regADeg "kort" ;
  silver_N = mk2N "sølv" "sølvet";
  sister_N = mkN "syster" "systera" "systrer" "systrene" ;
  sleep_V = vaereV IrregNno.sove_V ;
  small_A = mkADeg "liten" "lite" "små" "mindre" "minst" ; ---- lille
  snake_N = regGenN "slange" masculine ;
  sock_N = regGenN "strømpe" feminine ;
  speak_V2 = dirV2 (regV "snakke") ;
  star_N = regGenN "stjerne" feminine ;
  steel_N = regGenN "stål" neutrum ;
  stone_N = regGenN "stein" masculine ;
  stove_N = regGenN "komfyr" masculine ;
  student_N = mk2N "student" "studenten" ;
  stupid_A = mkADeg "dum" "dumt" "dumme" "dummare" "dummast" ;
  sun_N = regGenN "sol" feminine ;
  switch8off_V2 = dirV2 (partV (irregV "slå" "slo" "slått") "av") ;
  switch8on_V2 = dirV2 (partV (irregV "slå" "slo" "slått") "på") ;
  table_N = regGenN "bord" neutrum ;
  talk_V3 = mkV3 (regV "snakke") (mkPrep "til") (mkPrep "om") ;
  teacher_N = mkN "lærar" "læraren" "lærarar" "lærarane" ;
  teach_V2 = dirV2 (mk2V "undervise" "underviste") ;
  television_N = mk2N "fjernsyn" "fjernsynet" ;
  thick_A = mk2ADeg "tjukk" "tjukt" ;
  thin_A = mk2ADeg "tynn" "tynt" ;
  train_N = regGenN "tog" neutrum ;
  travel_V = vaereV (mk2V "reise" "reiste") ;
  tree_N = mkN "tre" "treet" "tre" "trea" ;
  ----  trousers_N = regGenN "trousers" ; ---- pl t !
  ugly_A = mk2ADeg "stygg" "stygt" ;
  understand_V2 = dirV2 (irregV "forstå" "forstod" "forstått") ;
  university_N = regGenN "universitet" neutrum ;
  village_N = mk2N "grend" "grenda" ;
  wait_V2 = mkV2 (regV "vente") (mkPrep "på") ;
  walk_V = IrregNno.gå_V ;
  warm_A = regADeg "varm" ;
  war_N = regGenN "krig" masculine ;
  watch_V2 = mkV2 se_V (mkPrep "på") ;
  water_N = mk2N "vatn" "vatnet" ;
  white_A = regADeg "kvit" ;
  window_N = mkN "vindauge" "vindauget" "vindauge" "vindauga" ;
  wine_N = mk2N "vin" "vinen" ;
  win_V2 = dirV2 (irregV "vinne" "vant" "vunne") ;
  woman_N = regGenN "kvinne" feminine ;
  wonder_VQ = mkVQ (regV "undre") ; ---- seg
  wood_N = mkN "tre" "treet" "tre" "trea" ;
  write_V2 = dirV2 (irregV "skrive" "skreiv" "skrive") ;
  yellow_A = regADeg "gul" ;
  young_A = irregADeg "ung" "yngre" "yngst" ;

  do_V2 = dirV2 (irregV "gjere" "gjorde" "gjort") ;
  now_Adv = mkAdv "no" ;
  already_Adv = mkAdv "allereie" ;
  song_N = mk2N "song" "songen" ;
  add_V3 = mkV3 (partV (irregV "leggje" "la" "lagt") "til") noPrep (mkPrep "til") ;
  number_N = mk2N "nummer" "nummeret" ;
  put_V2 = mkV2 (irregV "sette" "satte" "satt") noPrep ;
  stop_V = vaereV (regV "stoppe") ;
  jump_V = regV "hoppe" ;

  left_Ord = {s = "venstre" ; isDet = True} ;
  right_Ord = {s = "høgre" ; isDet = True} ;
  far_Adv = mkAdv "fjern" ;
  correct_A = regA "riktig" ;
  dry_A = mk2A "tørr" "tørt" ;
  dull_A = regA "sløv" ;
  full_A = regA "full" ;
  heavy_A = irregADeg "tung" "tyngre" "tyngst" ;
  near_A = mkADeg "nær" "nært" "nære" "nærmare" "nærmast" ;
  rotten_A = mkADeg "roten" "rote" "rotne" "rotnare" "rotnast" ;
  round_A = regA "rund" ;
  sharp_A = mk2A "kvass" "kvast" ;
  smooth_A = mk2A "slett" "slett" ;
  straight_A = regA "rak" ;
  wet_A = regA "våt" ;
  wide_A = regA "breid" ;
  animal_N = mk2N "dyr" "dyret" ;
  ashes_N = mk2N "aske" "aska" ;
  back_N = mk2N "rygg" "ryggen" ;
  bark_N = mk2N "bark" "barken" ;
  belly_N = mk2N "mage" "magen" ;
  blood_N = mk2N "blod" "blodet" ;
  bone_N = mk2N "bein" "beinet" ;
  breast_N = mk2N "bryst" "brystet" ;
  cloud_N = mk2N "sky" "skya" ;
  day_N = mk2N "dag" "dagen" ;
  dust_N = mk2N "støv" "støvet" ;
  ear_N = mk2N "øyre" "øyret" ;
  earth_N = mk2N "jord" "jorda" ;
  egg_N = mk2N "egg" "egget" ;
  eye_N = mkN "auge" "auget" "auge" "auga" ;
  fat_N = mk2N "fett" "fettet" ;
  feather_N = mk2N "fjør" "fjøra" ;
  fingernail_N = mkN "nagl" "naglen" "negler" "neglene" ;
  fire_N = mk2N "eld" "elden" ;
  flower_N = mk2N "blome" "blomen" ;
  fog_N = mk2N "tåke" "tåka" ;
  foot_N = mkN "fot" "foten" "føter" "føtene" ;
  forest_N = mk2N "skog" "skogen" ;
  grass_N = mk2N "gras" "graset" ;
  guts_N = mk2N "tarm" "tarmen" ; ---- involler
  hair_N = mk2N "hår" "håret" ;
  hand_N = mkN "hand" "handa" "hender" "hendene" ;
  head_N = mk2N "hovud" "hovudet" ;
  heart_N = mkN "hjarte" "hjartet" "hjarte" "hjarta" ;
  horn_N = mk2N "horn" "hornet" ;
  husband_N = mkN "ektemann" "ektemannen" "ektemenn" "ektemennene" ;
  ice_N = mk2N "is" "isen" ;
  knee_N = mkN "kne" "kneet" "kne" "knea" ;
  leaf_N = mk2N "lauv" "lauvet" ;
  leg_N = mk2N "bein" "beinet" ;
  liver_N = mkN "lever" "levra" "levrer" "levrene" ;
  louse_N = mkN "lus" "lusa" "lus" "lusene";
  mouth_N = mk2N "munn" "munnen" ;
  name_N = mk2N "namn" "namnet" ;
  neck_N = mk2N "nakke" "nakken" ;
  night_N = mkN "natt" "natta" "netter" "nettene" ;
  nose_N = mk2N "nase" "nasen" ;
  person_N = mk2N "person" "personen" ;
  rain_N = mk2N "regn" "regnet" ;
  road_N = mk2N "veg" "vegen" ;
  root_N = mkN "rot" "rota" "røter" "røtene" ;
  rope_N = mk2N "tau" "tauet" ;
  salt_N = mk2N "salt" "saltet" ;
  sand_N = mk2N "sand" "sanden" ;
  seed_N = mk2N "frø" "frøet" ;
  skin_N = mk2N "skinn" "skinnet" ;
  sky_N = mkN "himmel" "himmelen" "himlar" "himlane" ;
  smoke_N = mk2N "røyk" "røyken" ;
  snow_N = mk2N "snø" "snøen" ;
  stick_N = mk2N "pinne" "pinnen" ;
  tail_N = mk2N "hale" "halen" ;
  tongue_N = mk2N "tunge" "tunga" ;
  tooth_N = mkN "tann" "tanna" "tenner" "tennene" ;
  wife_N = mk2N "kone" "kona" ;
  wind_N = mk2N "vind" "vinden" ;
  wing_N = mk2N "vinge" "vingen" ;
  worm_N = mk2N "mark" "marka" ;
  year_N = mk2N "år" "året" ;
  bite_V2 = dirV2 (IrregNno.bite_V) ;
  blow_V = blase_V ;
  burn_V = brenne_V ;
  count_V2 = dirV2 (regV "regne") ;
  cut_V2 = dirV2 (skjære_V) ;
  dig_V = mk2V "grave" "gravde" ;
  fall_V = vaereV falle_V ;
  fear_V2 = dirV2 (regV "frykte") ;
  fight_V2 = dirV2 (slåss_V) ;
  float_V = flyte_V ;
  flow_V = renne_V ;
  fly_V = vaereV IrregNno.fly_V ;
  freeze_V = fryse_V ;
  give_V3 = dirV3 gi_V (mkPrep "til");
  hit_V2 = dirV2 (slå_V) ;
  hold_V2 = dirV2 (holde_V) ;
  hunt_V2 = dirV2 (regV "jakte") ;
  kill_V2 = dirV2 (mk2V "drepe" "drepte") ;
  laugh_V = mkV "le" "ler" "les" "lo" "ledd" "le" ;
  lie_V = ligge_V ;
  play_V = mk2V "leike" "leikte" ;
  pull_V2 = dirV2 (dra_V) ;
  push_V2 = dirV2 (irregV "skuve" "skuva" "skuva") ;
  rub_V2 = dirV2 (gni_V) ;
  scratch_V2 = dirV2 (regV "klø") ;
  sew_V = mk2V "sy" "sydde" ;
  sing_V = synge_V ;
  sit_V = sitte_V ;
  smell_V = regV "lukte" ;
  spit_V = regV "spytte" ;
  split_V2 = dirV2 (mk2V "kløyve" "kløyvde") ;
  squeeze_V2 = dirV2 (mk2V "klemme" "klemte") ;
  stab_V2 = dirV2 (stikke_V) ;
  stand_V = vaereV stå_V ;
  suck_V2 = dirV2 (suge_V) ;
  swell_V = partV (regV "hovne") "opp" ;
  swim_V = regV "svømme" ;
  think_V = mk2V "tenkje" "tenkte" ;
  throw_V2 = dirV2 (regV "kaste") ;
  tie_V2 = dirV2 (regV "knytte") ;
  turn_V = mk2V "vende" "vende" ;
  vomit_V = partV (regV "kaste") "opp" ;
  wash_V2 = dirV2 (regV "vaske") ;
  wipe_V2 = dirV2 (regV "tørke") ;
  breathe_V = regV "puste" ;


  grammar_N = regN "grammatikk" ;
  language_N = mk2N "språk" "språket" ;
  rule_N = mkN "regel" "regelen" "reglar" "reglane" ;

    question_N = mk2N "spørsmål" "spørsmålet" ;
----    ready_A = regA "färdig" ;
----    reason_N = regN "anledning" ;
    today_Adv = mkAdv "i dag" ;
----    uncertain_A = mk3A "osäker" "osäkert" "osäkra" ;

} ;

-- a" -> e"   86
-- ö  -> ø    66
-- ck -> kk   20
-- ä  -> e    44