a fairly complete Nynorsk implementation added

lib/src/api/CombinatorsNno.gf

@@ -0,0 +1,6 @@
+--# -path=.:alltenses:prelude
+
+resource CombinatorsNno = Combinators with 
+  (Cat = CatNno),
+  (Structural = StructuralNno),
+  (Constructors = ConstructorsNno) ;

lib/src/api/ConstructorsNno.gf

@@ -0,0 +1,3 @@
+--# -path=.:alltenses:prelude
+
+resource ConstructorsNno = Constructors with (Grammar = GrammarNno) ;

lib/src/api/SymbolicNno.gf

@@ -0,0 +1,5 @@
+--# -path=.:../nynorsk:../scandinavian:../common:../abstract:../prelude
+
+resource SymbolicNno = Symbolic with 
+  (Symbol = SymbolNno),
+  (Grammar = GrammarNno) ;

lib/src/api/SyntaxNno.gf

@@ -0,0 +1,5 @@
+--# -path=.:alltenses:prelude
+
+instance SyntaxNno of Syntax = ConstructorsNno, CatNno, StructuralNno, CombinatorsNno
+ ;
+

lib/src/api/TryNno.gf

@@ -0,0 +1,3 @@
+--# -path=.:../nynorsk:../scandinavian:../common:../abstract:../prelude
+
+resource TryNno = SyntaxNno, LexiconNno, ParadigmsNno - [mkAdv] ;

lib/src/nynorsk/AdjectiveNno.gf

@@ -0,0 +1,2 @@
+concrete AdjectiveNno of Adjective = CatNno ** AdjectiveScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/AdverbNno.gf

@@ -0,0 +1,2 @@
+concrete AdverbNno of Adverb = CatNno ** AdverbScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/AllNno.gf

@@ -0,0 +1,7 @@
+--# -path=.:../scandinavian:../abstract:../common:../prelude
+
+concrete AllNno of AllNnoAbs =
+  LangNno,
+  IrregNno - [fly_V],
+  ExtraNno
+  ** {} ;

lib/src/nynorsk/AllNnoAbs.gf

@@ -0,0 +1,5 @@
+abstract AllNnoAbs = 
+  Lang,
+  IrregNnoAbs - [fly_V],
+  ExtraNnoAbs
+  ** {} ;

lib/src/nynorsk/CatNno.gf

@@ -0,0 +1,2 @@
+concrete CatNno of Cat = CommonX - [Tense, Temp] ** CatScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/ConjunctionNno.gf

@@ -0,0 +1,2 @@
+concrete ConjunctionNno of Conjunction = CatNno ** ConjunctionScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/DiffNno.gf

@@ -0,0 +1,114 @@
+instance DiffNno of DiffScand = open CommonScand, Prelude in {
+  flags coding=utf8 ;
+
+-- Parameters.
+
+  oper
+    NGender = NGenderNno ;
+
+    ngen2gen g = case g of {NUtr _ => Utr ; NNeutr => Neutr} ;
+
+  param
+    NGenderNno = NUtr Sex | NNeutr ;
+    Sex    = Masc | Fem ;
+
+  oper
+    utrum = NUtr Masc ;
+    neutrum = NNeutr ;
+
+    detDef : Species = Def ;
+
+    Verb : Type = {
+      s : VForm => Str ;
+      part : Str ;
+      vtype : VType ;
+      isVaere : Bool
+      } ;
+
+    hasAuxBe v = v.isVaere ;
+
+-- Strings.
+
+    conjThat = "at" ;
+    conjThan = "enn" ;
+    conjAnd = "og" ;
+    compMore = "meir" ;
+    infMark  = "å" ;
+
+    subjIf = "viss" ;
+
+--    artDef : GenNum -> Str = \gn -> gennumForms "den" "det" "dei" ! gn ;
+
+    artIndef : NGender => Str = table {
+      NUtr Masc => "ein" ;
+      NUtr Fem  => "ei" ;
+      NNeutr    => "eit"
+      } ;
+    detIndefPl = "noko" ;
+
+    verbHave =
+      mkVerb9 "ha" "har" "ha" "hadde" "hatt" "haven" "havet" "havne" "havande"
+      **       {part = [] ; isVaere = False} ;
+    verbBe =
+      mkVerb9 "vere" "er" "var" "var" "vore" "veren" "veret" "verne" "verande"
+      **       {part = [] ; isVaere = False} ;
+    verbBecome =
+      mkVerb9 "verte" "vert" "verte" "vart" "vorte" "vorte" "vorte" "vorte" "vertande"
+      **       {part = [] ; isVaere = True} ;
+
+    -- auxiliary
+    noPart = {part = []} ;
+
+    auxFut = "vil" ;      -- "skal" in ExtNno
+    auxFutKommer = "kjem" ;
+    auxFutPart = "til" ;
+    auxCond = "ville" ;
+
+    negation : Polarity => Str = table {
+      Pos => [] ;
+      Neg => "ikkje"
+      } ;
+
+    genderForms : (x1,x2 : Str) -> NGender => Str = \all,allt ->
+      table {
+        NUtr _ => all ;
+        NNeutr => allt
+        } ;
+
+    relPron : Gender => Number => RCase => Str = \\g,n,c => case c of {
+      RNom | RAcc | RPrep False => "som" ;
+      RGen  => "viss" ;
+      RPrep _ => gennumForms "kva" "kva" "kva" ! gennum g n
+      } ;
+
+    pronSuch = gennumForms "slik" "slikt" "slike" ;
+
+    reflPron : Agr -> Str = \a -> case <a.n,a.p> of {
+      <Pl,P1> => "oss" ;
+      <Pl,P2> => "dykk" ;
+      <Sg,P1> => "meg" ;
+      <Sg,P2> => "deg" ;
+      <_, P3> => "seg"
+      } ;
+
+    hur_IAdv = {s = "kvar"} ;
+
+    av_Prep = "av" ;
+
+---- added by AR
+    possPron : Number -> Person -> Number -> Gender -> Str = \sn,sb,on,og -> case <sn,sb,on,og> of {
+       <Sg,P1,Sg,Utr>   => "min" ;
+       <Sg,P1,Sg,Neutr> => "mitt" ;
+       <Sg,P1,Pl,_>     => "mine" ;
+       <Sg,P2,Sg,Utr>   => "din" ;
+       <Sg,P2,Sg,Neutr> => "ditt" ;
+       <Sg,P2,Pl,_>     => "dine" ;
+       <Pl,P1,Sg,Utr>   => "vår" ;
+       <Pl,P1,Sg,Neutr> => "vårt" ;
+       <Pl,P1,Pl,_>     => "våre" ;
+       <Pl,P2,_,_>      => "dykkar" ;
+       <_,_,Sg,Utr>     => "sin" ;
+       <_,_,Sg,Neutr>   => "sitt" ;
+       <_,_,Pl,_>       => "sine"
+       } ;
+}

lib/src/nynorsk/ExtraNno.gf

@@ -0,0 +1,12 @@
+concrete ExtraNno of ExtraNnoAbs = ExtraScandNno ** open CommonScand, ResNno, Prelude in {
+
+  lin
+    PossNPPron np pro = {
+      s = \\c => np.s ! NPNom ++ pro.s ! NPPoss (gennumAgr np.a) (caseNP c) ;
+      a = np.a ;
+      isPron = False ;
+      } ;
+
+    TFutKommer = {s = []} ** {t = SFutKommer} ;   --# notpresent
+
+}

lib/src/nynorsk/ExtraNnoAbs.gf

@@ -0,0 +1,9 @@
+-- Structures special for Norwegian. These are not implemented in other
+-- Scandinavian languages.
+
+abstract ExtraNnoAbs = ExtraScandAbs ** {
+
+  fun
+    PossNPPron : NP -> Pron -> NP ;   -- bilen min
+
+}

lib/src/nynorsk/ExtraScandNno.gf

@@ -0,0 +1,2 @@
+concrete ExtraScandNno of ExtraScandAbs = CatNno ** ExtraScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/GrammarNno.gf

@@ -0,0 +1,22 @@
+--# -path=.:../scandinavian:../abstract:../common:prelude
+
+concrete GrammarNno of Grammar =
+  NounNno,
+  VerbNno,
+  AdjectiveNno,
+  AdverbNno,
+  NumeralNno,
+  SentenceNno,
+  QuestionNno,
+  RelativeNno,
+  ConjunctionNno,
+  PhraseNno,
+  TextX - [Tense,Temp] ,
+  IdiomNno,
+  StructuralNno,
+  TenseNno
+  ** {
+
+flags startcat = Phr ; unlexer = text ; lexer = text ;
+
+} ;

lib/src/nynorsk/IdiomNno.gf

@@ -0,0 +1,40 @@
+concrete IdiomNno of Idiom = CatNno **
+  open MorphoNno, ParadigmsNno, IrregNno, Prelude in {
+
+  flags optimize=all_subs ;
+    coding=utf8 ;
+
+  lin
+
+    ImpersCl vp = mkClause "det" (agrP3 Neutr Sg) vp ;
+    GenericCl vp = mkClause "eine" (agrP3 Utr Sg) vp ;
+
+    CleftNP np rs = mkClause "det" (agrP3 Neutr Sg)
+        (insertObj (\\_ => np.s ! rs.c ++ rs.s ! np.a ! RNom) (predV verbBe)) ;
+
+    CleftAdv ad s = mkClause "det" (agrP3 Neutr Sg)
+      (insertObj (\\_ => ad.s ++ s.s ! Sub) (predV verbBe)) ;
+
+    ExistNP np =
+      mkClause "det" (agrP3 Neutr Sg) (insertObj
+        (\\_ => np.s ! accusative) (predV (depV finnast_V))) ;
+
+    ExistIP ip = {
+      s = \\t,a,p =>
+            let
+              cls =
+               (mkClause "det" (agrP3 Neutr Sg) (predV (depV finnast_V))).s ! t ! a ! p ;
+              who = ip.s ! accusative
+            in table {
+              QDir   => who ++ cls ! Inv ;
+              QIndir => who ++ cls ! Sub
+              }
+      } ;
+
+    ProgrVP vp =
+      insertObj (\\a => ["ved å"] ++ infVP vp a) (predV verbBe) ;
+
+    ImpPl1 vp = {s = ["lat oss"] ++ infVP vp {g = Utr ; n = Pl ; p = P1}} ;
+
+
+}

lib/src/nynorsk/IrregNno.gf

@@ -0,0 +1,75 @@
+--# -path=.:../scandinavian:../common:../abstract:../../prelude
+
+-- see: http://frodo.bruderhof.com/norskklassen/commonverbs.htm
+
+concrete IrregNno of IrregNnoAbs = CatNno ** open ParadigmsNno in {
+
+  flags optimize=values ;
+    coding=utf8 ;
+
+  lin be_V = mkV "be" "ber" "bes" "bad" "bede" "be" ;
+  lin bite_V = mkV "bite" "bit" "bitast" "beit" "bite" "bit" ;
+  lin verte_V = mkV "verte" "vert" "vertast" "vart" "vorte" "vert" ;
+  lin brenne_V = mkV "brenne" "brenn" "brenn" "brann" "brunne" "brenn" ;
+  lin blase_V = mkV "blåse" "blæs" "blåsast" "bles" "blåse" "blås" ;
+  lin bringe_V = mkV "bringe" "bringar" "bringast" "bringa" "bringa" "bring" ;
+  lin burde_V = mkV "burde" "bør" "burdest" "burde" "burda" "burde" ;
+  lin bære_V = mkV "bere" "ber" "berast" "bar" "bore" "ber" ;
+  lin dra_V = mkV "dra" "dreg" "dragast" "drog" "drege" "dra" ;
+  lin drikke_V = mkV "drikke" "drikk" "drikkast" "drakk" "drukke" "drikk" ;
+  lin drive_V = irregV "drive" "dreiv" "drive" ;
+  lin dø_V = mkV "døy" "døyr" "døyast" "døydde" "døydd" "døy" ;
+  lin eie_V = mkV "eige" "eig" "eigast" "eigde" "eigd" "eig" ;
+  lin falle_V = mkV "falle" "fell" "fallast" "fall" "falle" "fall" ;
+  lin finne_V = mkV "finne" "finn" "finnas" "fann" "funne" "finn" ;
+  lin finnast_V = mkV "finnast" "finst" "finst" "fans" "funnest" "finnast" ;
+  lin fly_V = mkV "flyge" "flyg" "flygast" "flaug" "flyge" "flyg" ;
+  lin flyte_V = mkV "flyte" "flyt" "flytast" "flaut" "flyte" "flyt" ;
+  lin foretrekke_V = mkV "føretrekkje" "føretrekkjer" "føretrekkjast" "føretrekte" "føretrekt" "føretrekk" ;
+  lin forlate_V = mkV "forlate" "forlèt" "forlatast" "forlét" "forlate" "forlat" ;
+  lin forstå_V = irregV "forstå" "forstod" "forstått" ;
+  lin fortelle_V = mkV "fortelje" "fortel" "forteljast" "fortalde" "fortalt" "fortel" ;
+  lin fryse_V = mkV "fryse" "frys" "frysast" "fraus" "frose" "frys" ;
+  lin få_V = mkV "få" "får" "fåast" "fekk" "fått" "få" ;
+  lin gi_V = mkV "gje" "gjev" "gjevast" "gav" "gjeve" "gje" ;
+  lin gjelde_V = mkV "gjelde" "gjeld" "gjeldast" "gjaldt" "gjeldt" "gjeld";
+  lin gjøre_V = mkV "gjere" "gjer" "gjerast" "gjorde" "gjort" "gjer";
+  lin gni_V = irregV "gni" "gnidde" "gnidd" ;
+  lin gå_V = irregV "gå" "gjekk" "gått" ;
+  lin ha_V = irregV "ha" "hadde" "hatt" ;
+  lin hente_V = irregV "hente" "henta" "henta" ;
+  lin hete_V = irregV "heite" "heitte" "heitt" ;
+  lin hjelpe_V = irregV "hjelpe" "hjelpte" "hjelpt" ;
+  lin holde_V = mkV "halde" "held" "haldast" "heldt" "halde" "hald" ;
+  lin komme_V = mkV "kome" "kjem" "kommast" "kom" "kome" "kom" ;
+  lin kunne_V = mkV "kunne" "kan" "kan" "kunne" "kunna" "kunn" ;
+  lin la_V = mkV "la" "lar" "lar" "let" "latt" "la" ;
+  lin legge_V = mkV "leggje" "legg" "leggast" "la" "lagt" "legg";
+  lin ligge_V = mkV "liggje" "ligg" "liggast" "låg" "lege" "ligg";
+  lin løpe_V = springe_V ;
+  lin måtte_V = mkV "måtte" "må" "måast" "måtte" "måtta" "må";
+  lin renne_V = mkV "renne" "renn" "rennast" "rant" "rent" "renn" ;
+  lin se_V = mkV "sjå" "ser" "sjåast" "såg" "sett" "sjå" ;
+  lin selge_V = mkV "selje" "sel" "seljast" "selde" "selt" "sel" ;
+  lin sette_V = irregV "sette" "satte" "satt" ;
+  lin si_V = mkV "seie" "seier" "seiast" "sa" "sagt" "sei" ;
+  lin sitte_V = mkV "sitje" "sit" "sits" "sat" "sete" "sit" ;
+  lin skjære_V = irregV "skjere" "skar" "skure" ;
+  lin skrive_V = irregV "skrive" "skreiv" "skrive" ;
+  lin skulle_V = irregV "skulle" "skulle" "skulla" ;
+  lin slå_V = irregV "slå" "slo" "slått" ;
+  lin slåss_V = mkV "slåss" "slåss" "slåss" "sloss" "slåss" "slåss" ;
+  lin sove_V = mkV "sove" "søv" "sovast" "sov" "sove" "sov" ;
+  lin springe_V = mkV "springe" "spring" "springast" "sprang" "sprunge" "spring";
+  lin spørre_V = mkV "spørje" "spør" "spørjas" "spurte" "spurt" "spør" ;
+  lin stikke_V = irregV "stikke" "stakk" "stukke" ;
+  lin stå_V = irregV "stå" "stod" "stått" ;
+  lin suge_V = mkV "suge" "sug" "sugast" "saug" "sugd" "sug" ;
+  lin synes_V = irregV "synes" "syntes" (variants {"synes" ; "syns"}) ;
+  lin synge_V = mkV "synge" "syng" "syngast" "sang" "sunge" "syng";
+  lin ta_V = mkV "ta" "tek" "tek" "tok" "teke" "ta" ;
+  lin treffe_V = mkV "treffe" "treff" "treffast" "traff" "truffe" "treff" ;
+  lin trives_V = mkV "trivast" "trivst" "trivast" "treivst" "trivest" "trivst" ;
+  lin ville_V = irregV "ville" "ville" "villet" ;
+  lin vite_V = mkV "vite" "veit" "vitast" "visste" "visst" "vit" ;
+}

lib/src/nynorsk/IrregNnoAbs.gf

@@ -0,0 +1,68 @@
+abstract IrregNnoAbs = Cat ** {
+  flags coding=utf8 ;
+  fun be_V : V ;
+  fun bite_V : V ;
+  fun verte_V : V ;
+  fun blase_V : V ;
+  fun brenne_V : V ;
+  fun bringe_V : V ;
+  fun burde_V : V ;
+  fun bære_V : V ;
+  fun dra_V : V ;
+  fun drikke_V : V ;
+  fun drive_V : V ;
+  fun dø_V : V ;
+  fun eie_V : V ;
+  fun falle_V : V ;
+  fun finne_V : V ;
+  fun finnast_V : V ;
+  fun fly_V : V ;
+  fun flyte_V : V ;
+  fun foretrekke_V : V ;
+  fun forlate_V : V ;
+  fun forstå_V : V ;
+  fun fortelle_V : V ;
+  fun fryse_V : V ;
+  fun få_V : V ;
+  fun gi_V : V ;
+  fun gjelde_V : V ;
+  fun gjøre_V : V ;
+  fun gni_V : V ;
+  fun gå_V : V ;
+  fun ha_V : V ;
+  fun hente_V : V ;
+  fun hete_V : V ;
+  fun hjelpe_V : V ;
+  fun holde_V : V ;
+  fun komme_V : V ;
+  fun kunne_V : V ;
+  fun la_V : V ;
+  fun legge_V : V ;
+  fun ligge_V : V ;
+  fun løpe_V : V ;
+  fun måtte_V : V ;
+  fun renne_V : V ;
+  fun se_V : V ;
+  fun selge_V : V ;
+  fun sette_V : V ;
+  fun si_V : V ;
+  fun sitte_V : V ;
+  fun skjære_V : V ;
+  fun skrive_V : V ;
+  fun skulle_V : V ;
+  fun slå_V : V ;
+  fun slåss_V : V ;
+  fun sove_V : V ;
+  fun springe_V : V ;
+  fun spørre_V : V ;
+  fun stikke_V : V ;
+  fun stå_V : V ;
+  fun suge_V : V ;
+  fun synes_V : V ;
+  fun synge_V : V ;
+  fun ta_V : V ;
+  fun treffe_V : V ;
+  fun trives_V : V ;
+  fun ville_V : V ;
+  fun vite_V : V ;
+}

lib/src/nynorsk/LangNno.gf

@@ -0,0 +1,10 @@
+--# -path=.:../scandinavian:../abstract:../common:../prelude
+
+concrete LangNno of Lang =
+  GrammarNno,
+  LexiconNno
+  ** {
+
+flags startcat = Phr ; unlexer = text ; lexer = text ;
+
+} ;

lib/src/nynorsk/LexiconNno.gf

@@ -0,0 +1,370 @@
+--# -path=.:../scandinavian:../common:../abstract:../../prelude
+
+concrete LexiconNno of Lexicon = CatNno **
+  open Prelude, ParadigmsNno, IrregNno in {
+
+flags startcat=Phr ; lexer=textlit ; unlexer=text ;
+    coding=utf8 ;
+  optimize=values ;
+
+lin
+  airplane_N = mk2N "fly" "flyet" ;
+  answer_V2S = mkV2S (regV "svare") (mkPrep "til") ;
+  apartment_N = mk2N "leilegheit" "leilegheita" ;
+  apple_N = mk2N "eple" "eplet" ;
+  art_N = mk2N "kunst" "kunsten" ;
+  ask_V2Q = mkV2Q spørre_V noPrep ; -- fikse
+  baby_N = mk2N "baby" "babyen" ;
+  bad_A = regADeg "dårleg" ;
+  bank_N = mk2N "bank" "banken" ;
+  beautiful_A = mkADeg "vakker" "vakkert" "vakre" "vakrare" "vakrast" ;
+  become_VA = mkVA (vaereV verte_V) ; -- fikse
+  beer_N = regGenN "øl" neutrum ; -- fikse
+  beg_V2V = mkV2V be_V noPrep (mkPrep "å") ;
+  big_A = irregADeg "stor" "større" "størst";
+  bike_N = mkN "sykkel" "sykkelen" "syklar" "syklane" ;
+  bird_N = mk2N "fugl" "fuglen" ;
+  black_A = mk2ADeg "svart" "svart" ;
+  blue_A = mk2ADeg "blå" "blått";
+  boat_N = regGenN "båt" masculine ;
+  book_N = mkN "bok" "boka" "bøker" "bøkene" ;
+  boot_N = mkN "støvel" "støvelen" "støvlar" "støvlane" ;
+  boss_N = mk2N "sjef" "sjefen" ;
+  boy_N = regGenN "gut" masculine ;
+  bread_N = regGenN "brød" neutrum ;
+  break_V2 = dirV2 (mk2V "knuse" "knuste") ;
+  broad_A = regADeg "brei" ;
+  brother_N2 = mkN2 ( (mkN "bror" "broren" "brødre" "brødrene")) (mkPrep "til") ;
+  brown_A = regADeg "brun" ;
+  butter_N = regGenN "smør" neutrum ;
+  buy_V2 = dirV2 (mk2V "kjøpe" "kjøpte") ;
+  camera_N = mk2N "kamera" "kameraet" ; ----
+  cap_N = mk2N "hue" "hua" ;
+  car_N = regGenN "bil" masculine ;
+  carpet_N = regGenN "matte" feminine ;
+  cat_N = mk2N "katt" "katten" ;
+  ceiling_N = regGenN "tak" neutrum ;
+  chair_N = regGenN "stol" masculine ;
+  cheese_N = regGenN "ost" masculine ;
+  child_N = regGenN "born" neutrum ;
+  church_N = regGenN "kyrke" feminine ;
+  city_N = mk2N "by" "byen" ;
+  clean_A = regADeg "rein" ;
+  clever_A = regADeg "klok" ;
+  close_V2 = dirV2 (mk2V "lukke" "lukket") ; -- ?
+  coat_N = regGenN "frakk" masculine ;
+  cold_A = regADeg "kald" ;
+  come_V = vaereV IrregNno.komme_V ;
+  computer_N = mk2N "datamaskin" "datamaskina" ;
+  country_N = mk2N "land" "landet" ;
+  cousin_N = mk2N "fetter" "fetteren" ; ----
+  cow_N = mkN "ku" "kua" "kyr" "kyrne" ; ----
+  die_V = vaereV IrregNno.dø_V ;
+  dirty_A = mkADeg "skiten" "skite" "skitne" "skitnare" "skitnast" ;
+  distance_N3 = mkN3 (regGenN "avstand" masculine) (mkPrep "frå") (mkPrep "til") ;
+  doctor_N = mk2N "lege" "legen" ;
+  dog_N = regGenN "hund" masculine ;
+  door_N = regGenN "dør" feminine ;
+  drink_V2 = dirV2 IrregNno.drikke_V ;
+  easy_A2V = mkA2V (regA "grei") (mkPrep "for") ; -- ?
+  eat_V2 = dirV2 (mk2V "spise" "spiste") ; -- fikse ete
+  empty_A = mkADeg "tom" "tomt" "tomme" "tommare" "tommast" ;
+  enemy_N = regGenN "fiende" masculine ;
+  factory_N = mk2N "fabrikk" "fabrikken" ;
+  father_N2 = mkN2 ( (mkN "far" "faren" "fedre" "fedrene")) (mkPrep "til") ;
+  fear_VS = mkVS (regV "frykte") ;
+  find_V2 = dirV2 (irregV "finne" "fann" "funnet") ; --?
+  fish_N = mk2N "fisk" "fisken" ;
+  floor_N = regGenN "golv" neutrum ;
+  forget_V2 = dirV2 (mkV "gløyme" "gløymer" "gløymas" "gløymde" "gløymt" "gløym") ;
+  fridge_N = regGenN "kjøleskap" neutrum ;
+  friend_N = mkN "ven" "venen" "venar" "venane" ;
+  fruit_N = mk2N "frukt" "frukta" ;
+  fun_AV = mkAV (mkA "morosam" "morosamt" "morosame") ;
+  garden_N = regGenN "hage" masculine ;
+  girl_N = regGenN "jente" feminine ;
+  glove_N = regGenN "hanske" masculine ;
+  gold_N = regGenN "gull" neutrum ;
+  good_A = mkADeg "god" "godt" "gode" "betre" "best" ;
+  go_V = IrregNno.gå_V ;
+  green_A = mk2ADeg "grøn" "grønt" ;
+  harbour_N = regGenN "havn" feminine;
+  hate_V2 = dirV2 (regV "hate") ;
+  hat_N = regGenN "hatt" masculine ;
+  hear_V2 = dirV2 (mk2V "høyre" "høyrte") ;
+  hill_N = regGenN "bakke" masculine ;
+  hope_VS = mkVS (regV "vone") ;
+  horse_N = regGenN "hest" masculine ;
+  hot_A = regADeg "varm" ;
+  house_N = regGenN "hus" neutrum ;
+  important_A = regADeg "viktig" ;
+  industry_N = mk2N "industri" "industrien" ;
+  iron_N = regGenN "jern" neutrum ;
+  john_PN = mkPN "John" masculine ;
+  king_N = regGenN "konge" masculine ;
+  know_V2 = dirV2 (mkV "kjenne" "kjenner" "kjennast" "kjende" "kjent" "kjenn") ;
+  know_VQ = mkVQ IrregNno.vite_V ;
+  know_VS = mkVS IrregNno.vite_V ;
+  lake_N = regGenN "vatn" neutrum ;
+  lamp_N = regGenN "lampe" feminine ;
+  learn_V2 = dirV2 (mk2V "lære" "lærde") ;
+  leather_N = regGenN "ler" neutrum ;
+  leave_V2 = dirV2 forlate_V ;
+  like_V2 = dirV2 (mk2V "like" "likte") ;
+  listen_V2 = dirV2 (regV "lytte") ;
+  live_V = mk2V "leve" "levde" ;
+  long_A = irregADeg "lang" "lengre" "lengst" ;
+  lose_V2 = dirV2 (mk2V "tape" "tapte") ;
+  love_N = regGenN "kjærleik" masculine ;
+  love_V2 = dirV2 (regV "elske") ;
+  man_N =  (mkN "mann" "mannen" "menn" "mennene") ;
+  married_A2 = mkA2 (mk2A "gift" "gift") (mkPrep "med") ;
+  meat_N = regGenN "kjøtt" neutrum ;
+  milk_N = regGenN "mjølk" feminine ;
+  moon_N = regGenN "måne" masculine ;
+  mother_N2 = mkN2 (mkN "mor" "mora" "mødre" "mødrene") (mkPrep "til") ; ---- fem
+  mountain_N = regGenN "fjell" neutrum ;
+  music_N = mk2N "musikk" "musikken" ;
+  narrow_A = regADeg "smal" ;
+  new_A = mkADeg "ny" "nytt" "nye" "nyare" "nyast" ;
+  newspaper_N = regGenN "avis" feminine ;
+  oil_N = regGenN "olje" masculine ;
+  old_A = mkADeg "gammal" "gammalt" "gamle" "eldre" "eldst" ;
+  open_V2 = dirV2 (regV "opne") ;
+  paint_V2A = mkV2A (regV "måle") noPrep ;
+  paper_N = regGenN "papir" neutrum ; ----
+  paris_PN = regGenPN "Paris" neutrum ;
+  peace_N = regGenN "fred" masculine ;
+  pen_N = regGenN "penn" masculine ;
+  planet_N = mk2N "planet" "planeten" ;
+  plastic_N = mk2N "plast" "plasten" ;
+  play_V2 = dirV2 (mk2V "spele" "spelde") ;
+  policeman_N = mk2N "politi" "politiet" ;
+  priest_N = mk2N "prest" "presten" ;
+  probable_AS = mkAS (regA "sannsynleg") ;
+  queen_N = regGenN "dronning" feminine ;
+  radio_N = regGenN "radio" masculine ;
+  rain_V0 = mkV0 (regV "regne") ;
+  read_V2 = dirV2 (mk2V "lese" "leste") ;
+  red_A = regADeg "raud" ;
+  religion_N = mk2N "religion" "religionen" ;
+  restaurant_N = mk2N "restaurant" "restauranten" ;
+  river_N = mk2N "elv" "elva" ;
+  rock_N = regGenN "stein" masculine ;
+  roof_N = regGenN "tak" neutrum ;
+  rubber_N = mk2N "gummi" "gummien" ;
+  run_V = springe_V ;
+  say_VS = mkVS si_V ;
+  school_N = regGenN "skule" masculine;
+  science_N = mk2N "vitskap" "vitskapen" ;
+  sea_N = mk2N "sjø" "sjøen" ;
+  seek_V2 = mkV2 (mk2V "leite" "leita") (mkPrep "etter") ;
+  see_V2 = dirV2 se_V ;
+  sell_V3 = dirV3 selge_V (mkPrep "til") ;
+  send_V3 = dirV3 (mk2V "sende" "sendte") (mkPrep "til") ;
+  sheep_N = mk2N "får" "fåret" ;
+  ship_N = regGenN "skip" neutrum ;
+  shirt_N = regGenN "skjorte" feminine ;
+  shoe_N = mkN "sko" "skoen" "sko" "skoa" ;
+  shop_N = mk2N "butikk" "butikken" ;
+  short_A = regADeg "kort" ;
+  silver_N = mk2N "sølv" "sølvet";
+  sister_N = mkN "syster" "systera" "systrer" "systrene" ;
+  sleep_V = vaereV IrregNno.sove_V ;
+  small_A = mkADeg "liten" "lite" "små" "mindre" "minst" ; ---- lille
+  snake_N = regGenN "slange" masculine ;
+  sock_N = regGenN "strømpe" feminine ;
+  speak_V2 = dirV2 (regV "snakke") ;
+  star_N = regGenN "stjerne" feminine ;
+  steel_N = regGenN "stål" neutrum ;
+  stone_N = regGenN "stein" masculine ;
+  stove_N = regGenN "komfyr" masculine ;
+  student_N = mk2N "student" "studenten" ;
+  stupid_A = mkADeg "dum" "dumt" "dumme" "dummare" "dummast" ;
+  sun_N = regGenN "sol" feminine ;
+  switch8off_V2 = dirV2 (partV (irregV "slå" "slo" "slått") "av") ;
+  switch8on_V2 = dirV2 (partV (irregV "slå" "slo" "slått") "på") ;
+  table_N = regGenN "bord" neutrum ;
+  talk_V3 = mkV3 (regV "snakke") (mkPrep "til") (mkPrep "om") ;
+  teacher_N = mkN "lærar" "læraren" "lærarar" "lærarane" ;
+  teach_V2 = dirV2 (mk2V "undervise" "underviste") ;
+  television_N = mk2N "fjernsyn" "fjernsynet" ;
+  thick_A = mk2ADeg "tjukk" "tjukt" ;
+  thin_A = mk2ADeg "tynn" "tynt" ;
+  train_N = regGenN "tog" neutrum ;
+  travel_V = vaereV (mk2V "reise" "reiste") ;
+  tree_N = mkN "tre" "treet" "tre" "trea" ;
+  ----  trousers_N = regGenN "trousers" ; ---- pl t !
+  ugly_A = mk2ADeg "stygg" "stygt" ;
+  understand_V2 = dirV2 (irregV "forstå" "forstod" "forstått") ;
+  university_N = regGenN "universitet" neutrum ;
+  village_N = mk2N "grend" "grenda" ;
+  wait_V2 = mkV2 (regV "vente") (mkPrep "på") ;
+  walk_V = IrregNno.gå_V ;
+  warm_A = regADeg "varm" ;
+  war_N = regGenN "krig" masculine ;
+  watch_V2 = mkV2 se_V (mkPrep "på") ;
+  water_N = mk2N "vatn" "vatnet" ;
+  white_A = regADeg "kvit" ;
+  window_N = mkN "vindauge" "vindauget" "vindauge" "vindauga" ;
+  wine_N = mk2N "vin" "vinen" ;
+  win_V2 = dirV2 (irregV "vinne" "vant" "vunne") ;
+  woman_N = regGenN "kvinne" feminine ;
+  wonder_VQ = mkVQ (regV "undre") ; ---- seg
+  wood_N = mkN "tre" "treet" "tre" "trea" ;
+  write_V2 = dirV2 (irregV "skrive" "skreiv" "skrive") ;
+  yellow_A = regADeg "gul" ;
+  young_A = irregADeg "ung" "yngre" "yngst" ;
+
+  do_V2 = dirV2 (irregV "gjere" "gjorde" "gjort") ;
+  now_Adv = mkAdv "no" ;
+  already_Adv = mkAdv "allereie" ;
+  song_N = mk2N "song" "songen" ;
+  add_V3 = mkV3 (partV (irregV "leggje" "la" "lagt") "til") noPrep (mkPrep "til") ;
+  number_N = mk2N "nummer" "nummeret" ;
+  put_V2 = mkV2 (irregV "sette" "satte" "satt") noPrep ;
+  stop_V = vaereV (regV "stoppe") ;
+  jump_V = regV "hoppe" ;
+
+  left_Ord = {s = "venstre" ; isDet = True} ;
+  right_Ord = {s = "høgre" ; isDet = True} ;
+  far_Adv = mkAdv "fjern" ;
+  correct_A = regA "riktig" ;
+  dry_A = mk2A "tørr" "tørt" ;
+  dull_A = regA "sløv" ;
+  full_A = regA "full" ;
+  heavy_A = irregADeg "tung" "tyngre" "tyngst" ;
+  near_A = mkADeg "nær" "nært" "nære" "nærmare" "nærmast" ;
+  rotten_A = mkADeg "roten" "rote" "rotne" "rotnare" "rotnast" ;
+  round_A = regA "rund" ;
+  sharp_A = mk2A "kvass" "kvast" ;
+  smooth_A = mk2A "slett" "slett" ;
+  straight_A = regA "rak" ;
+  wet_A = regA "våt" ;
+  wide_A = regA "breid" ;
+  animal_N = mk2N "dyr" "dyret" ;
+  ashes_N = mk2N "aske" "aska" ;
+  back_N = mk2N "rygg" "ryggen" ;
+  bark_N = mk2N "bark" "barken" ;
+  belly_N = mk2N "mage" "magen" ;
+  blood_N = mk2N "blod" "blodet" ;
+  bone_N = mk2N "bein" "beinet" ;
+  breast_N = mk2N "bryst" "brystet" ;
+  cloud_N = mk2N "sky" "skya" ;
+  day_N = mk2N "dag" "dagen" ;
+  dust_N = mk2N "støv" "støvet" ;
+  ear_N = mk2N "øyre" "øyret" ;
+  earth_N = mk2N "jord" "jorda" ;
+  egg_N = mk2N "egg" "egget" ;
+  eye_N = mkN "auge" "auget" "auge" "auga" ;
+  fat_N = mk2N "fett" "fettet" ;
+  feather_N = mk2N "fjør" "fjøra" ;
+  fingernail_N = mkN "nagl" "naglen" "negler" "neglene" ;
+  fire_N = mk2N "eld" "elden" ;
+  flower_N = mk2N "blome" "blomen" ;
+  fog_N = mk2N "tåke" "tåka" ;
+  foot_N = mkN "fot" "foten" "føter" "føtene" ;
+  forest_N = mk2N "skog" "skogen" ;
+  grass_N = mk2N "gras" "graset" ;
+  guts_N = mk2N "tarm" "tarmen" ; ---- involler
+  hair_N = mk2N "hår" "håret" ;
+  hand_N = mkN "hand" "handa" "hender" "hendene" ;
+  head_N = mk2N "hovud" "hovudet" ;
+  heart_N = mkN "hjarte" "hjartet" "hjarte" "hjarta" ;
+  horn_N = mk2N "horn" "hornet" ;
+  husband_N = mkN "ektemann" "ektemannen" "ektemenn" "ektemennene" ;
+  ice_N = mk2N "is" "isen" ;
+  knee_N = mkN "kne" "kneet" "kne" "knea" ;
+  leaf_N = mk2N "lauv" "lauvet" ;
+  leg_N = mk2N "bein" "beinet" ;
+  liver_N = mkN "lever" "levra" "levrer" "levrene" ;
+  louse_N = mkN "lus" "lusa" "lus" "lusene";
+  mouth_N = mk2N "munn" "munnen" ;
+  name_N = mk2N "namn" "namnet" ;
+  neck_N = mk2N "nakke" "nakken" ;
+  night_N = mkN "natt" "natta" "netter" "nettene" ;
+  nose_N = mk2N "nase" "nasen" ;
+  person_N = mk2N "person" "personen" ;
+  rain_N = mk2N "regn" "regnet" ;
+  road_N = mk2N "veg" "vegen" ;
+  root_N = mkN "rot" "rota" "røter" "røtene" ;
+  rope_N = mk2N "tau" "tauet" ;
+  salt_N = mk2N "salt" "saltet" ;
+  sand_N = mk2N "sand" "sanden" ;
+  seed_N = mk2N "frø" "frøet" ;
+  skin_N = mk2N "skinn" "skinnet" ;
+  sky_N = mkN "himmel" "himmelen" "himlar" "himlane" ;
+  smoke_N = mk2N "røyk" "røyken" ;
+  snow_N = mk2N "snø" "snøen" ;
+  stick_N = mk2N "pinne" "pinnen" ;
+  tail_N = mk2N "hale" "halen" ;
+  tongue_N = mk2N "tunge" "tunga" ;
+  tooth_N = mkN "tann" "tanna" "tenner" "tennene" ;
+  wife_N = mk2N "kone" "kona" ;
+  wind_N = mk2N "vind" "vinden" ;
+  wing_N = mk2N "vinge" "vingen" ;
+  worm_N = mk2N "mark" "marka" ;
+  year_N = mk2N "år" "året" ;
+  bite_V2 = dirV2 (IrregNno.bite_V) ;
+  blow_V = blase_V ;
+  burn_V = brenne_V ;
+  count_V2 = dirV2 (regV "regne") ;
+  cut_V2 = dirV2 (skjære_V) ;
+  dig_V = mk2V "grave" "gravde" ;
+  fall_V = vaereV falle_V ;
+  fear_V2 = dirV2 (regV "frykte") ;
+  fight_V2 = dirV2 (slåss_V) ;
+  float_V = flyte_V ;
+  flow_V = renne_V ;
+  fly_V = vaereV IrregNno.fly_V ;
+  freeze_V = fryse_V ;
+  give_V3 = dirV3 gi_V (mkPrep "til");
+  hit_V2 = dirV2 (slå_V) ;
+  hold_V2 = dirV2 (holde_V) ;
+  hunt_V2 = dirV2 (regV "jakte") ;
+  kill_V2 = dirV2 (mk2V "drepe" "drepte") ;
+  laugh_V = mkV "le" "ler" "les" "lo" "ledd" "le" ;
+  lie_V = ligge_V ;
+  play_V = mk2V "leike" "leikte" ;
+  pull_V2 = dirV2 (dra_V) ;
+  push_V2 = dirV2 (irregV "skuve" "skuva" "skuva") ;
+  rub_V2 = dirV2 (gni_V) ;
+  scratch_V2 = dirV2 (regV "klø") ;
+  sew_V = mk2V "sy" "sydde" ;
+  sing_V = synge_V ;
+  sit_V = sitte_V ;
+  smell_V = regV "lukte" ;
+  spit_V = regV "spytte" ;
+  split_V2 = dirV2 (mk2V "kløyve" "kløyvde") ;
+  squeeze_V2 = dirV2 (mk2V "klemme" "klemte") ;
+  stab_V2 = dirV2 (stikke_V) ;
+  stand_V = vaereV stå_V ;
+  suck_V2 = dirV2 (suge_V) ;
+  swell_V = partV (regV "hovne") "opp" ;
+  swim_V = regV "svømme" ;
+  think_V = mk2V "tenkje" "tenkte" ;
+  throw_V2 = dirV2 (regV "kaste") ;
+  tie_V2 = dirV2 (regV "knytte") ;
+  turn_V = mk2V "vende" "vende" ;
+  vomit_V = partV (regV "kaste") "opp" ;
+  wash_V2 = dirV2 (regV "vaske") ;
+  wipe_V2 = dirV2 (regV "tørke") ;
+  breathe_V = regV "puste" ;
+
+
+  grammar_N = regN "grammatikk" ;
+  language_N = mk2N "språk" "språket" ;
+  rule_N = mkN "regel" "regelen" "reglar" "reglane" ;
+
+    question_N = mk2N "spørsmål" "spørsmålet" ;
+----    ready_A = regA "färdig" ;
+----    reason_N = regN "anledning" ;
+    today_Adv = mkAdv "i dag" ;
+----    uncertain_A = mk3A "osäker" "osäkert" "osäkra" ;
+
+} ;
+
+-- a" -> e"   86
+-- ö  -> ø    66
+-- ck -> kk   20
+-- ä  -> e    44

lib/src/nynorsk/MathNno.gf

@@ -0,0 +1,2 @@
+concrete MathNno of Math = CatNno ** MathScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/MorphoNno.gf

@@ -0,0 +1,178 @@
+--1 A Simple Norwegian Resource Morphology
+--
+-- Aarne Ranta 2002
+--
+-- This resource morphology contains definitions needed in the resource
+-- syntax. It moreover contains copies of the most usual inflectional patterns
+-- as defined in functional morphology (in the Haskell file $RulesSw.hs$).
+--
+-- We use the parameter types and word classes defined for morphology.
+
+resource MorphoNno = CommonScand, ResNno ** open Prelude, Predef in {
+  flags coding=utf8 ;
+
+-- genders
+
+oper
+  masc  = NUtr Masc ;
+  fem   = NUtr Fem ;
+  neutr = NNeutr ;
+
+-- type synonyms
+
+  Subst : Type = {s : Number => Species => Case => Str} ;
+  Adj = Adjective ;
+
+-- nouns
+
+  mkSubstantive : (_,_,_,_ : Str) -> Subst =
+    \dreng, drengen, drenger, drengene ->
+    {s = nounForms dreng drengen drenger drengene} ;
+
+  extNGen : Str -> NGender = \s -> case last s of {
+    "n" => masc ;
+    "a" => fem ;
+    _   => neutr
+    } ;
+
+  nBil : Str -> Subst = \bil ->
+    mkSubstantive bil (bil + "en") (bil + "ar")  (bil + "ane") **
+      {h1 = masc} ;
+
+  nUke : Str -> Subst = \uke ->
+    mkSubstantive uke (init uke + "a") (uke + "r")  (uke + "ne") **
+      {h1 = fem} ;
+
+  nHus : Str -> Subst = \hus ->
+    mkSubstantive hus (hus + "et") hus  (hus + "a") **
+      {h1 = neutr} ;
+
+  nHotell : Str -> Subst = \hotell ->
+    mkSubstantive hotell (hotell + "et") hotell (hotell + "a") **
+      {h1 = neutr} ;
+
+
+
+
+-- adjectives
+
+  mkAdject : (_,_,_,_,_ : Str) -> Adj =
+    \stor,stort,store,storre,storst -> {s = table {
+       AF (APosit (Strong (GSg Utr  ))) c    => mkCase c stor ;
+       AF (APosit (Strong (GSg Neutr))) c   => mkCase c stort ;
+       AF (APosit _) c                  => mkCase c store ;
+       AF ACompar c                     => mkCase c storre ;
+       AF (ASuperl SupStrong) c         => mkCase c storst ;
+       AF (ASuperl SupWeak) c           => mkCase c (storst + "e") ;
+       AAdv                             => stort
+       }
+    } ;
+
+  aRod : Str -> Adj = \rod ->
+    mkAdject rod (rod + "t") (rod + "e") (rod + "are") (rod + "ast") ;
+
+  aAbstrakt : Str -> Adj = \abstrakt ->
+    mkAdject abstrakt abstrakt (abstrakt + "e") (abstrakt + "are") (abstrakt + "ast") ;
+
+  aRask : Str -> Adj = \rask ->
+    mkAdject rask rask (rask + "e") (rask + "are") (rask + "ast") ;
+
+  aBillig : Str -> Adj = \billig ->
+    mkAdject billig billig (billig + "e") (billig + "are") (billig + "ast") ;
+
+-- verbs
+
+  Verbum : Type = {s : VForm => Str} ;
+
+  mkVerb6 : (_,_,_,_,_,_ : Str) -> Verbum =
+    \spise,spiser,spises,spiste,spist,spis -> {s = table {
+       VI (VInfin v)       => mkVoice v spise ;
+       VF (VPres Act)    => spiser ;
+       VF (VPres Pass)   => spises ;
+       VF (VPret v)      => mkVoice v spiste ;   --# notpresent
+       VI (VSupin v)     => mkVoice v spist ;    --# notpresent
+       VI (VPtPret (Strong (GSg _)) c) => mkCase c spist ;
+       VI (VPtPret _ c)  => case last spist of {
+         "a" => mkCase c spist ;
+         _   => mkCase c (spist + "e")
+         } ;
+       VI (VPtPres _ _ c)  => case last spise of {
+         "a" => mkCase c (spise + "nde") ;
+         "i" => mkCase c (spise + "vande") ; --- gi, bli
+         _   => mkCase c (spise + "ande")
+         } ;
+       VF (VImper v)     => mkVoice v spis
+       }
+     } ;
+
+  vHusk : Str -> Verbum = \husk ->
+    let huska : Str = husk + "a"  ---- variants {husk + "a" ; husk + "et"}
+    in
+    mkVerb6 (husk + "e") (husk + "ar") (husk + "as") huska huska husk ;
+
+  vSpis : Str -> Verbum = \spis ->
+    mkVerb6 (spis + "e") (spis + "ar") (spis + "as") (spis + "te") (spis + "t") spis ;
+
+  vLev : Str -> Verbum = \lev ->
+    let lever = case last lev of {
+      "r" => lev ;
+      _   => lev + "er"
+      }
+    in
+    mkVerb6 (lev + "e") lever (lev + "as") (lev + "de") (lev + "d") lev ;
+
+  vBo : Str -> Verbum = \bo ->
+    mkVerb6 bo (bo + "r") (bo + "as") (bo + "dde") (bo + "dd") bo ;
+
+  regVerb : Str -> Str -> Verbum = \spise, spiste ->
+    let
+      spis = init spise ;
+      te   = dp 2 spiste
+    in
+    case te of {
+      "te" => vSpis spis ;
+      "de" => case last spise of {
+         "e" => vLev spis ;
+         _   => vBo spise
+         } ;
+      _  => vHusk spis
+      } ;
+
+
+-- For $Numeral$.
+
+param DForm = ental  | ton  | tiotal  ;
+
+oper
+  LinDigit = {s : DForm => CardOrd => Str} ;
+
+  cardOrd : Str -> Str -> CardOrd => Str = \tre,tredje ->
+    table {
+      NCard _ => tre ;
+      NOrd a  => tredje ---- a
+      } ;
+
+  cardReg : Str -> CardOrd => Str = \syv ->
+    cardOrd syv (syv + case last syv of {
+      "n" => "de" ;
+      "e" => "nde" ;
+      _   => "ende"
+      }) ;
+
+
+  mkTal : (x1,_,_,_,x5 : Str) -> LinDigit =
+    \två, tolv, tjugo, andra, tolfte ->
+    {s = table {
+           ental  => cardOrd två andra ;
+           ton    => cardOrd tolv tolfte ;
+           tiotal => cardReg tjugo
+           }
+     } ;
+
+  numPl : (CardOrd => Str) -> {s : CardOrd => Str ; n : Number} = \n ->
+    {s = n ; n = Pl} ;
+
+  invNum : CardOrd = NCard NNeutr ;
+
+
+}

lib/src/nynorsk/NounNno.gf

@@ -0,0 +1,2 @@
+concrete NounNno of Noun = CatNno ** NounScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/NumeralNno.gf

@@ -0,0 +1,85 @@
+concrete NumeralNno of Numeral = CatNno [Numeral,Digits] ** open MorphoNno, Prelude in {
+  flags coding=utf8 ;
+
+lincat
+  Digit = {s : DForm => CardOrd => Str} ;
+  Sub10 = {s : DForm => CardOrd => Str ; n : Number} ;
+  Sub100, Sub1000, Sub1000000 =
+          {s :          CardOrd => Str ; n : Number} ;
+
+lin
+  num x = x ;
+
+  n2 = mkTal "to"   "tolv"    "tjue"   "andre"   "tolvte" ;
+  n3 = mkTal "tre"  "tretten" "tretti" "tredje"  "trettande" ;
+  n4 = mkTal "fire" "fjorten" "førti"  "fjerde"  "fjortande" ;
+  n5 = mkTal "fem"  "femten"  "femti"  "femte"   "femtande" ;
+  n6 = mkTal "seks" "seksten" "seksti" "sjette"  "sekstande" ;
+  n7 = mkTal "sju"  "sytten"  "sytti"  "sjunde" "syttande" ;
+  n8 = mkTal "åtte" "atten"   "åtti"   "åttande" "attande" ;
+  n9 = mkTal "ni"   "nitten"  "nitti"  "niande"  "nittande" ;
+
+  pot01 = {
+    s = \\f => table {
+          NCard g => case g of {NNeutr => "eit" ; NUtr _ => "ein"} ; ---- ei ?
+          _ => "første"
+          } ;
+    n = Sg
+    } ;
+  pot0 d = {s = \\f,g => d.s ! f ! g ; n = Pl} ;
+  pot110 = numPl (cardReg "ti") ;
+  pot111 = numPl (cardOrd "elve" "elfte") ;
+  pot1to19 d = numPl (d.s ! ton) ;
+  pot0as1 n = {s = n.s ! ental ; n = n.n} ;
+  pot1 d = numPl (d.s ! tiotal) ;
+  pot1plus d e = {s = \\g => d.s ! tiotal ! invNum ++ e.s ! ental ! g ; n = Pl} ;
+  pot1as2 n = n ;
+  pot2 d =
+    numPl (\\g => d.s ! ental ! invNum ++ cardOrd "hundre" "hundrede" ! g) ;
+  pot2plus d e =
+    {s = \\g => d.s ! ental ! invNum ++ "hundre" ++ "og" ++ e.s ! g ; n = Pl} ;
+  pot2as3 n = n ;
+  pot3 n =
+    numPl (\\g => n.s ! invNum ++ cardOrd "tusen" "tusende" ! g) ;
+  pot3plus n m =
+    {s = \\g => n.s ! invNum ++ "tusen" ++ "og" ++ m.s ! g ; n = Pl} ;
+
+-- Numerals from sequences of digits.
+
+  lincat
+    Dig = TDigit ;
+
+  lin
+    IDig d = d ;
+
+    IIDig d i = {
+      s = \\o => d.s ! NCard neutrum ++ BIND ++ i.s ! o ;
+      n = Pl
+    } ;
+
+    D_0 = mkDig "0" ;
+    D_1 = mk3Dig "1" "1:e" Sg ;
+    D_2 = mk2Dig "2" "2:e" ;
+    D_3 = mkDig "3" ;
+    D_4 = mkDig "4" ;
+    D_5 = mkDig "5" ;
+    D_6 = mkDig "6" ;
+    D_7 = mkDig "7" ;
+    D_8 = mkDig "8" ;
+    D_9 = mkDig "9" ;
+
+  oper
+    mk2Dig : Str -> Str -> TDigit = \c,o -> mk3Dig c o Pl ;
+    mkDig : Str -> TDigit = \c -> mk2Dig c (c + ":e") ;
+
+    mk3Dig : Str -> Str -> Number -> TDigit = \c,o,n -> {
+      s = table {NCard _ => c ; NOrd _ => o} ;
+      n = n
+      } ;
+
+    TDigit = {
+      n : Number ;
+      s : CardOrd => Str
+    } ;
+
+}

lib/src/nynorsk/ParadigmsNno.gf

@@ -0,0 +1,503 @@
+--# -path=.:../scandinavian:../common:../abstract:../../prelude
+
+--1 Norwegian Lexical Paradigms
+--
+-- Aarne Ranta 2003
+--
+-- This is an API for the user of the resource grammar
+-- for adding lexical items. It gives functions for forming
+-- expressions of open categories: nouns, adjectives, verbs.
+-- It covers the "bokmål" variant of Norwegian.
+--
+-- Closed categories (determiners, pronouns, conjunctions) are
+-- accessed through the resource syntax API, $Structural$.
+--
+-- The main difference with $MorphoNno.gf$ is that the types
+-- referred to are compiled resource grammar types. We have moreover
+-- had the design principle of always having existing forms, rather
+-- than stems, as string arguments of the paradigms.
+--
+-- The structure of functions for each word class $C$ is the following:
+-- first we give a handful of patterns that aim to cover all
+-- regular cases. Then we give a worst-case function $mkC$, which serves as an
+-- escape to construct the most irregular words of type $C$.
+-- However, this function should only seldom be needed: we have a
+-- separate module [``IrregNno`` ../../norwegian/IrregNno],
+-- which covers irregularly inflected verbs.
+
+resource ParadigmsNno =
+  open
+    (Predef=Predef),
+    Prelude,
+    CommonScand,
+    ResNno,
+    MorphoNno,
+    CatNno in {
+
+  flags coding=utf8 ;
+--2 Parameters
+--
+-- To abstract over gender names, we define the following identifiers.
+
+oper
+  Gender : Type ;
+
+  masculine : Gender ; -- the "ein" gender
+  feminine  : Gender ; -- the "ei" gender
+  neutrum   : Gender ; -- the "eit" gender
+
+-- To abstract over number names, we define the following.
+
+  Number : Type ;
+
+  singular : Number ;
+  plural   : Number ;
+
+-- To abstract over case names, we define the following.
+
+  Case : Type ; --%
+
+  nominative : Case ; --%
+  genitive   : Case ; --%
+
+-- Prepositions used in many-argument functions are just strings.
+
+  mkPrep : Str -> Prep ; -- e.g. "etter"
+  noPrep : Prep ;        -- empty string
+
+--2 Nouns
+
+-- The regular function takes the singular indefinite form
+-- and computes the other forms and the gender by a heuristic.
+-- The heuristic is that nouns ending "e" are feminine like "kvinne",
+-- all others are masculine like "bil".
+-- Giving gender manually makes the heuristic more reliable.
+-- One can also compute the gender from the definite form.
+-- gender is computed from the definite form.
+-- If in doubt, use the $cc$ command to test!
+-- In the worst case, give all four forms. The gender is computed from the
+-- last letter of the second form (if "n", then $utrum$, otherwise $neutrum$).
+
+  mkN : overload {
+    mkN : Str -> N ; -- predictable noun, feminine for "-e" otherwise masculine
+    mkN : Str -> Gender -> N ; -- force gender
+    mkN : (bil,bilen : Str) -> N ; --%
+    mkN  : (dreng,drengen,drenger,drengene : Str) -> N -- worst case
+  } ;
+
+
+
+--3 Compound nouns
+--
+-- All the functions above work quite as well to form compound nouns,
+-- such as "fotboll".
+
+
+--3 Relational nouns
+--
+-- Relational nouns ("datter til x") need a preposition.
+
+  mkN2 : N -> Prep -> N2 ; -- e.g. datter + til
+
+-- The most common preposition is "av", and the following is a
+-- shortcut for regular, $nonhuman$ relational nouns with "av".
+
+  regN2 : Str -> Gender -> N2 ; --%
+
+-- Use the function $mkPrep$ or see the section on prepositions below to
+-- form other prepositions.
+--
+-- Three-place relational nouns ("forbindelse fra x til y")
+-- need two prepositions.
+
+  mkN3 : N -> Prep -> Prep -> N3 ; -- e.g forbindelse + fra + til
+
+
+--3 Relational common noun phrases
+--
+-- In some cases, you may want to make a complex $CN$ into a
+-- relational noun (e.g. "den gamle kongen av"). However, $N2$ and
+-- $N3$ are purely lexical categories. But you can use the $AdvCN$
+-- and $PrepNP$ constructions to build phrases like this.
+
+--
+--3 Proper names and noun phrases
+--
+-- Proper names, with a regular genitive, are formed as follows
+-- Sometimes you can reuse a common noun as a proper name, e.g. "Bank".
+
+  mkPN : overload {
+    mkPN : Str -> PN ;       -- masculine
+    mkPN : Str -> Gender -> PN ;  -- force gender
+    mkPN : N -> PN ; --%
+    } ;
+
+
+--2 Adjectives
+
+-- The regular pattern works for many adjectives, e.g. those ending
+-- with "ig". Two, five, or at worst five forms are sometimes needed.
+
+  mkA : overload {
+    mkA : (fin : Str) -> A ; -- predictable adjective
+    mkA : (fin,fint : Str) -> A ; -- deviant neuter
+    mkA : (galen,galet,galne : Str) -> A ; -- also plural deviant
+    mkA : (stor,stort,store,storre,storst : Str) -> A ; -- worst case
+
+-- If comparison is formed by "mer", "mest", as in general for
+-- long adjective, the following pattern is used:
+
+    mkA : A -> A ; -- comparison with mer/mest, e.g. "norsk"
+  } ;
+
+
+--3 Two-place adjectives
+--
+-- Two-place adjectives need a preposition for their second argument.
+
+  mkA2 : A -> Prep -> A2 ; -- e.g. gift + med
+
+
+
+--2 Adverbs
+
+-- Adverbs are not inflected. Most lexical ones have position
+-- after the verb. Some follow the verb (e.g. "altid").
+
+  mkAdv : Str -> Adv ;  -- e.g. her
+  mkAdV : Str -> AdV ;  -- e.g. altid
+
+-- Adverbs modifying adjectives and sentences can also be formed.
+
+  mkAdA : Str -> AdA ; -- e.g. mye
+
+
+--2 Verbs
+--
+
+  mkV : overload {
+
+-- The 'regular verb' function is the first conjugation.
+
+    mkV : (snakke : Str) -> V ; -- regular verb (first conjugation)
+
+-- The almost regular verb function needs the infinitive and the preteritum.
+
+    mkV : (leve,levde : Str) -> V ; -- other past tense
+
+-- There is an extensive list of irregular verbs in the module $IrregNno$.
+-- In practice, it is enough to give three forms, as in school books.
+
+    mkV : (drikke, drakk, drukket  : Str) -> V ; -- theme of irregular verb
+
+-- The worst case needs six forms.
+
+    mkV : (spise,spiser,spises,spiste,spist,spis : Str) -> V ; -- worst case
+
+--3 Verbs with a particle.
+--
+-- The particle, such as in "lukke opp", is given as a string.
+
+    mkV : V -> Str -> V ; -- verb with particle, e.g. lukke + opp
+  } ;
+
+
+
+--3 Verbs with 'være' as auxiliary
+--
+-- By default, the auxiliary is "have". This function changes it to "være".
+
+  vaereV : V -> V ; -- force "være" as auxiliary (default "have")
+
+
+
+--3 Deponent verbs.
+--
+-- Some words are used in passive forms only, e.g. "trives", some as
+-- reflexive e.g. "forestille seg".
+
+  depV  : V -> V ; -- deponent, e.g "trives"
+  reflV : V -> V ; -- reflexive, e.g. "forestille seg"
+
+--3 Two-place verbs
+--
+-- Two-place verbs need a preposition, except the special case with direct object.
+-- (transitive verbs). Notice that, if a particle is needed, it comes from the $V$.
+
+  mkV2 : overload {
+    mkV2 : Str -> V2 ; -- regular, direct object
+    mkV2 : V -> V2 ;   -- direct object
+    mkV2 : V -> Prep -> V2 ; -- preposition for complement
+  } ;
+
+
+--3 Three-place verbs
+--
+-- Three-place (ditransitive) verbs need two prepositions, of which
+-- the first one or both can be absent.
+
+  mkV3     : V -> Prep -> Prep -> V3 ;    -- snakke, med, om
+  dirV3    : V -> Prep -> V3 ;            -- gi,_,til
+  dirdirV3 : V -> V3 ;                    -- gi,_,_
+
+--3 Other complement patterns
+--
+-- Verbs and adjectives can take complements such as sentences,
+-- questions, verb phrases, and adjectives.
+
+  mkV0  : V -> V0 ; --%
+  mkVS  : V -> VS ;
+  mkV2S : V -> Prep -> V2S ;
+  mkVV  : V -> VV ;
+  mkV2V : V -> Prep -> Prep -> V2V ;
+  mkVA  : V -> VA ;
+  mkV2A : V -> Prep -> V2A ;
+  mkVQ  : V -> VQ ;
+  mkV2Q : V -> Prep -> V2Q ;
+
+  mkAS  : A -> AS ; --%
+  mkA2S : A -> Prep -> A2S ; --%
+  mkAV  : A -> AV ; --%
+  mkA2V : A -> Prep -> A2V ; --%
+
+-- Notice: categories $AS, A2S, AV, A2V$ are just $A$.
+-- $V0$ is just $V$.
+
+  V0 : Type ; --%
+  AS, A2S, AV, A2V : Type ; --%
+
+
+--.
+--2 Definitions of the paradigms
+--
+-- The definitions should not bother the user of the API. So they are
+-- hidden from the document.
+
+  Gender = MorphoNno.NGender ;
+  Number = MorphoNno.Number ;
+  Case = MorphoNno.Case ;
+  masculine = NUtr Masc ;
+  feminine = NUtr Fem ;
+  neutrum = NNeutr ;
+  singular = Sg ;
+  plural = Pl ;
+  nominative = Nom ;
+  genitive = Gen ;
+
+  mk4N x y z u = mkSubstantive x y z u ** {g = extNGen y ; lock_N = <> ; co = x} ; ---- TODO co
+
+  regN x = regGenN x g where {
+    g = case <x : Str> of {
+      _ + "e" => fem ;
+      _ => masc
+      }
+    } ;
+
+  regGenN x g = case last x of {
+    "e" => case g of {
+       NUtr Masc   => mk4N x (x      + "n") (init x + "ar") (init x + "ane") ;
+       NUtr Fem    => mk4N x (init x + "a") (x + "r") (x + "ne") ;
+       NNeutr      => mk4N x (x      + "t") (x + "r") (init x + "a")
+       } ;
+    _ => case g of {
+       NUtr Masc   => mk4N x (x      + "en") (x + "ar") (x + "ane") ;
+       NUtr Fem    => mk4N x (x      + "a")  (x + "er") (x + "ene") ;
+       NNeutr      => mk4N x (x      + "et") (x + "")   (x + "a")
+       }
+    } ;
+
+  mk2N x y = case last y of {
+    "n" => regGenN x masculine ;
+    "a" => regGenN x feminine ;
+    _   => regGenN x neutrum
+    } ;
+
+
+  mkN2 = \n,p -> n ** {lock_N2 = <> ; c2 = mkComplement  p.s} ;
+  regN2 n g = mkN2 (regGenN n g) (mkPrep "av") ;
+  mkN3 = \n,p,q -> n ** {lock_N3 = <> ; c2 = mkComplement  p.s ; c3 = mkComplement  q.s} ;
+
+  regGenPN n g = {s = \\c => mkCase c n ; g = ngen2gen g} ** {lock_PN = <>} ;
+  regPN n = regGenPN n utrum ;
+  nounPN n = {s = n.s ! singular ! Indef ; g = ngen2gen n.g ; lock_PN = <>} ;
+
+-- To form a noun phrase that can also be plural and have an irregular
+-- genitive, you can use the worst-case function.
+
+  makeNP : Str -> Str -> Number -> Gender -> NP ;
+  makeNP x y n g =
+    {s = table {NPPoss _ _ => x ; _ => y} ; a = agrP3 (ngen2gen g) n ; isPron = False ;
+     lock_NP = <>} ;
+
+  mk3A = mk3ADeg ; ---- (mkAdject a b c [] []) ** {isComp = False ; lock_A = <>} ;
+  mk2A a b = mk3A a b (a + "e") ;
+  regA a = (regADeg a) **  {isComp = False ; lock_A = <>} ;
+
+  mkA2 a p = a ** {c2 = mkComplement  p.s ; lock_A2 = <>} ;
+
+  mkADeg a b c d e = mkAdject a b c d e ** {isComp = False ; lock_A = <>} ;
+  regADeg a = case Predef.dp 2 a of {
+    "eg" => aBillig a ;
+    "sk" => aRask a ;
+    _ => aRod a
+    }  ** {isComp = False ; lock_A = <>} ;
+  irregADeg a b c = mkAdject a (a + "t") (a + "e") b c **
+    {isComp = False ; lock_A = <>} ;
+  mk3ADeg a b c = mkAdject a b c (a + "are") (a + "ast") **
+    {isComp = False ; lock_A = <>} ;
+  mk2ADeg a b = mkAdject a b (a + "e") (a + "are") (a + "ast") **
+    {isComp = False ; lock_A = <>} ;
+
+  compoundA adj = {s = adj.s ; isComp = True ; lock_A = <>} ;
+
+  mkAdv x = ss x ** {lock_Adv = <>} ;
+  mkAdV x = ss x ** {lock_AdV = <>} ;
+  mkAdA x = ss x ** {lock_AdA = <>} ;
+
+  mkPrep p = {s = p ; lock_Prep = <>} ;
+  noPrep = mkPrep [] ;
+
+  mk6V a b c d e f = mkVerb6 a b c d e f **
+    {part = [] ; vtype = VAct ; isVaere = False ; lock_V = <>} ;
+
+  regV a = case last a of {
+
+--3 Verbs with a particle.
+--
+-- The particle, such as in "lukke opp", is given as a string.
+
+
+
+--3 Verbs with a particle.
+--
+-- The particle, such as in "lukke opp", is given as a string.
+
+
+    "e" => vHusk (init a) ;
+    _ => vBo a
+    } ** {part = [] ; vtype = VAct ; isVaere = False ; lock_V = <>} ;
+
+  mk2V a b = regVerb a b ** {part = [] ; vtype = VAct ; isVaere = False ; lock_V = <>} ;
+
+  irregV =
+    \drikke,drakk,drukket ->
+    let
+      drikk = case last drikke of {
+        "e" => init drikke ;
+        _ => drikke
+        } ;
+      drikker = case last (init drikke) of {
+        "r" => init drikke ;
+        _   => drikke + "r"
+        }
+    in
+    mk6V drikke drikker (drikke + "s") drakk drukket drikk ;
+
+  vaereV v = {
+    s = v.s ;
+    part = [] ;
+    vtype = v.vtype ;
+    isVaere = True ;
+    lock_V = <>
+    } ;
+
+  partV v p = {s = v.s ; part = p ; vtype = v.vtype ; isVaere = v.isVaere ; lock_V = <>} ;
+  depV v = {s = v.s ; part = v.part ; vtype = VPass ; isVaere = False ; lock_V = <>} ;
+  reflV v = {s = v.s ; part = v.part ; vtype = VRefl ; isVaere = False ; lock_V = <>} ;
+
+  mk2V2 v p = v ** {c2 = mkComplement  p.s ; lock_V2 = <>} ;
+  dirV2 v = mk2V2 v noPrep ;
+
+  mkV3 v p q = v ** {c2 = mkComplement  p.s ; c3 = mkComplement  q.s ; lock_V3 = <>} ;
+  dirV3 v p = mkV3 v noPrep p ;
+  dirdirV3 v = dirV3 v noPrep ;
+
+  mkV0  v = v ** {lock_V0 = <>} ;
+  mkVS  v = v ** {lock_VS = <>} ;
+  mkV2S v p = mk2V2 v p ** {lock_V2S = <>} ;
+  mkVV  v = v ** {c2 = mkComplement  "å" ; lock_VV = <>} ;
+  mkV2V v p t = mk2V2 v p ** {c3 = mkComplement t.s ; lock_V2V = <>} ;
+  mkVA  v = v ** {lock_VA = <>} ;
+  mkV2A v p = mk2V2 v p ** {lock_V2A = <>} ;
+  mkVQ  v = v ** {lock_VQ = <>} ;
+  mkV2Q v p = mk2V2 v p ** {lock_V2Q = <>} ;
+
+  mkAS  v = v ** {lock_A = <>} ;
+  mkA2S v p = mkA2 v p ** {lock_A = <>} ;
+  mkAV  v = v ** {lock_A = <>} ;
+  mkA2V v p = mkA2 v p ** {lock_A = <>} ;
+
+  V0 : Type = V ;
+  AS, A2S, AV : Type = A ;
+  A2V : Type = A2 ;
+
+
+---------
+
+  mk2N : (bil,bilen : Str) -> N ;
+  mk4N  : (dreng,drengen,drenger,drengene : Str) -> N ;
+  regN : Str -> N ;
+  regGenN : Str -> Gender -> N ;
+  mk2N : (bil,bilen : Str) -> N ;
+
+  mkN = overload {
+    mkN : Str -> N = regN ;
+    mkN : Str -> Gender -> N = regGenN ;
+    mkN : (bil,bilen : Str) -> N = mk2N ;
+    mkN  : (dreng,drengen,drenger,drengene : Str) -> N = mk4N
+  } ;
+
+  mkPN = overload {
+    mkPN : Str -> PN = regPN ;       -- masculine
+    mkPN : Str -> Gender -> PN = regGenPN ;
+    mkPN : N -> PN = nounPN ;
+    } ;
+
+  regPN    : Str -> PN ;            -- utrum
+  regGenPN : Str -> Gender -> PN ;
+  nounPN : N -> PN ;
+
+  mkA = overload {
+    mkA : (fin : Str) -> A = regADeg ;
+    mkA : (fin,fint : Str) -> A = mk2ADeg ;
+    mkA : (galen,galet,galne : Str) -> A = mk3ADeg ;
+    mkA : (stor,stort,store,storre,storst : Str) -> A = mkADeg ;
+    mkA : A -> A = compoundA ; -- -/mer/mest norsk
+  } ;
+
+  mk3A : (galen,galet,galne : Str) -> A ;
+  regA : Str -> A ;
+  mk2A : (stor,stort : Str) -> A ;
+  mkADeg : (stor,stort,store,storre,storst : Str) -> A ;
+  regADeg : Str -> A ;
+  irregADeg : (tung,tyngre,tyngst : Str) -> A ;
+  mk3ADeg : (galen,galet,galne : Str) -> A ;
+  mk2ADeg : (bred,bredt        : Str) -> A ;
+  compoundA : A -> A ; -- -/mer/mest norsk
+
+  mkV = overload {
+    mkV : (snakke : Str) -> V = regV ;
+    mkV : (leve,levde : Str) -> V = mk2V ;
+    mkV : (drikke, drakk, drukket  : Str) -> V = irregV ;
+    mkV : (spise,spiser,spises,spiste,spist,spis : Str) -> V = mk6V ;
+    mkV : V -> Str -> V = partV ;
+  } ;
+
+
+  regV : (snakke : Str) -> V ;
+  mk2V : (leve,levde : Str) -> V ;
+  irregV : (drikke, drakk, drukket  : Str) -> V ;
+  mk6V : (spise,spiser,spises,spiste,spist,spis : Str) -> V ;
+  partV  : V -> Str -> V ;
+
+
+  mkV2 = overload {
+    mkV2 : Str -> V2 = \s -> dirV2 (regV s) ;
+    mkV2 : V -> V2 = dirV2 ;
+    mkV2 : V -> Prep -> V2 = mk2V2 ;
+  } ;
+
+  mk2V2  : V -> Prep -> V2 ;
+  dirV2 : V -> V2 ;
+
+} ;

lib/src/nynorsk/PhraseNno.gf

@@ -0,0 +1,2 @@
+concrete PhraseNno of Phrase = CatNno ** PhraseScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/QuestionNno.gf

@@ -0,0 +1,2 @@
+concrete QuestionNno of Question = CatNno ** QuestionScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/RelativeNno.gf

@@ -0,0 +1,2 @@
+concrete RelativeNno of Relative = CatNno ** RelativeScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/ResNno.gf

@@ -0,0 +1,2 @@
+instance ResNno of ResScand = DiffNno ** open CommonScand, Prelude in {
+} ;

lib/src/nynorsk/SentenceNno.gf

@@ -0,0 +1,2 @@
+concrete SentenceNno of Sentence = CatNno ** SentenceScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/StructuralNno.gf

@@ -0,0 +1,134 @@
+concrete StructuralNno of Structural = CatNno **
+  open MorphoNno, ParadigmsNno, (X = ConstructX), IrregNno, Prelude in {
+
+  flags optimize=all ;
+    coding=utf8 ;
+
+  lin
+  above_Prep = ss "ovanfor" ;
+  after_Prep = ss "etter" ;
+  by8agent_Prep = ss "av" ;
+  all_Predet = {s = detForms "all" "alt" "alle" ; p = [] ; a = PNoAg} ;
+  almost_AdA, almost_AdN = ss "nesten" ;
+  although_Subj = ss ["sjølv om"] ;
+  always_AdV = ss "alltid" ;
+  and_Conj = {s1 = [] ; s2 = "og" ; n = Pl ; isDiscont = False} ;
+  because_Subj = ss "fordi" ;
+  before_Prep = ss "før" ;
+  behind_Prep = ss "bakom" ;
+  between_Prep = ss "mellom" ;
+  both7and_DConj = sd2 "både" "og" ** {n = Pl ; isDiscont = True} ;
+  but_PConj = ss "men" ;
+  by8means_Prep = ss "med" ;
+  can8know_VV, can_VV =
+    mkV "kunne" "kan" "kunn" "kunne" "kunna" "kunn" **
+    {c2 = mkComplement [] ; lock_VV = <>} ;
+  during_Prep = ss "under" ;
+  either7or_DConj = sd2 "anten" "eller" ** {n = Sg ; isDiscont = True} ;
+  everybody_NP = regNP "alle" "alles" Utr Pl ;
+  every_Det = {s = \\_,_ => "kvar" ; sp = \\_,_ =>"einkvar" ; n = Sg ; det = DDef Indef} ;
+  everything_NP = regNP "alt" "alts" Neutr Sg ;
+  everywhere_Adv = ss "overalt" ;
+  few_Det  = {s,sp = \\_,_ => "få" ; n = Pl ; det = DDef Indef} ;
+---  first_Ord = {s = "første" ; isDet = True} ; DEPREC
+  for_Prep = ss "for" ;
+  from_Prep = ss "frå" ;
+  he_Pron = MorphoNno.mkNP "han"  "han"  "hans" "hans" "hans"  Utr Sg P3 ;
+  here_Adv = ss "her" ;
+  here7to_Adv = ss "hit" ;
+  here7from_Adv = ss "herifrå" ;
+  how_IAdv = ss "korleis" ;
+  how8many_IDet = {s = \\_ => ["kor mange"] ; n = Pl ; det = DDef Indef} ;
+  if_Subj = ss "viss" ;
+  in8front_Prep = ss "framfor" ;
+  i_Pron =
+    MorphoNno.mkNP "eg" "meg" "min" "mitt" "mine"  Utr Sg P1 ; --- mi
+---    MorphoNno.mkNP "eg" "meg" (variants {"min" ; "mi"}) "mitt" "mine"  Utr Sg P1 ;
+  in_Prep = ss "i" ;
+  it_Pron = MorphoNno.regNP "det" "dets" Neutr Sg ;
+  less_CAdv = X.mkCAdv "mindre" conjThan ;
+  many_Det = {s,sp = \\_,_ => "mange" ; n = Pl ; det = DDef Indef} ;
+  more_CAdv = X.mkCAdv "meir" conjThan ;
+  most_Predet = {s = detForms ["den mest"] ["det meste"] ["dei fleste"] ; p = [] ; a = PNoAg} ;
+  much_Det = {s,sp = \\_,_ => "mykje" ; n = Pl ; det = DDef Indef} ;
+  must_VV =
+    mkV "måtte" "må" "må" "måtte" "måtte" "mått" **
+    {c2 = mkComplement [] ; lock_VV = <>} ;
+  no_Utt = ss ["nei"] ;
+  on_Prep = ss "på" ;
+
+  only_Predet = {s = \\_,_ => "kun" ; p = [] ; a = PNoAg} ;
+  or_Conj = {s1 = [] ; s2 = "eller" ; n = Pl ; isDiscont = False} ;
+  otherwise_PConj = ss "elles" ;
+  part_Prep = ss "av" ;
+  please_Voc = ss "takk" ; ---
+  possess_Prep = ss "av" ;
+  quite_Adv = ss "temmeleg" ;
+  she_Pron = MorphoNno.mkNP "ho" "henne" "hennar" "hennar" "hennar"  Utr Sg P3 ;
+  so_AdA = ss "så" ;
+  someSg_Det = {s,sp = \\_ => genderForms "nokon" "noko" ; n = Sg ; det = DIndef} ;
+  somePl_Det = {s,sp = \\_,_ => "nokre" ; n = Pl ; det = DIndef} ;
+  somebody_NP = regNP "nokon" "nokons" Utr Sg ;
+  something_NP = regNP "noko" "nokos" Neutr Sg ;
+  somewhere_Adv = ss ["ein eller anna plass"] ; ---- ?
+  that_Quant =
+    {s,sp = table {
+       Sg => \\_,_ => genderForms ["den der"] ["det der"] ;
+       Pl => \\_,_,_ => ["de der"]
+       } ;
+     det = DDef Def
+    } ;
+  there_Adv = ss "der" ;
+  there7to_Adv = ss "dit" ;
+  there7from_Adv = ss "derifrå" ;
+  therefore_PConj = ss "derfor" ;
+  they_Pron = MorphoNno.mkNP "dei" "dei" "deira" "deira" "deira" Utr Pl P1 ;
+  this_Quant =
+    {s,sp = table {
+       Sg => \\_,_ => genderForms ["denne"] ["dette"] ;
+       Pl => \\_,_,_ => ["desse"]
+       } ;
+     det = DDef Def
+    } ;
+  through_Prep = ss "gjennom" ;
+  too_AdA = ss "for" ;
+  to_Prep = ss "til" ;
+  under_Prep = ss "under" ;
+  very_AdA = ss "mykje" ;
+  want_VV =
+    mkV "vilje" "vil" "vil" "ville" "ville" "ville" **
+    {c2 = mkComplement [] ; lock_VV = <>} ;
+  we_Pron = MorphoNno.mkNP "vi"  "oss"  "vår" "vårt" "våre"  Utr Pl P1 ;
+  whatSg_IP = {s = \\_ => "kva" ; g = Neutr ; n = Sg} ; ---- infl
+  whatPl_IP = {s = \\_ => "kva" ; g = Neutr ; n = Pl} ; ---- infl
+  when_IAdv = ss "når" ;
+  when_Subj = ss "når" ;
+  where_IAdv = ss "kvar" ;
+  which_IQuant = {
+    s = table {
+      Sg => genderForms "kva" "kva" ;
+      Pl => \\_ => "kva"
+      } ;
+    det = DIndef
+    } ;
+  whoSg_IP = {s = vem.s ; g = Utr ; n = Sg} ;
+  whoPl_IP = {s = \\_ => "kven" ; g = Utr ; n = Pl} ;
+  why_IAdv = ss "kvifor" ;
+  without_Prep = ss "utan" ;
+  with_Prep = ss "med" ;
+  yes_Utt = ss ["ja"] ;
+  youSg_Pron =
+    MorphoNno.mkNP "du" "deg" "din" "ditt" "dine" Utr Sg P2 ; ----
+---    MorphoNno.mkNP "du" "deg" (variants {"din" ; "di"}) "ditt" "dine" Utr Sg P2 ; ----
+  youPl_Pron = MorphoNno.mkNP "de" "dykk" "dykkar" "dykkar" "dykkar"  Utr Pl P2 ;
+  youPol_Pron = MorphoNno.mkNP "De" "Dykk" "Dykkar" "Dykkar" "Dykkar"  Utr Sg P2 ; --- wrong in refl
+  have_V2 = dirV2 IrregNno.ha_V ;
+
+-- Auxiliaries that are used repeatedly.
+
+  oper
+    vem = MorphoNno.mkNP "kven" "kven" "kvens" "kvens" "kvens" Utr Sg P3 ;
+
+  lin language_title_Utt = ss "nynorsk" ;
+
+}

lib/src/nynorsk/SymbolNno.gf

@@ -0,0 +1,4 @@
+--# -path=.:../scandinavian:../abstract:../common:../prelude
+
+concrete SymbolNno of Symbol = CatNno ** SymbolScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/TenseNno.gf

@@ -0,0 +1,3 @@
+concrete TenseNno of Tense = CatNno, TenseX [Ant,Pol,AAnter,ASimul,PNeg,PPos] **  
+  TenseScand with
+  (ResScand = ResNno) ;

lib/src/nynorsk/VerbNno.gf

@@ -0,0 +1,2 @@
+concrete VerbNno of Verb = CatNno ** VerbScand with
+  (ResScand = ResNno) ;