msyds/gf-core
1
0
Fork 0
forked from GitHub/gf-core
Code Pull Requests Activity

Added French for new API. Started alpha conv. Fixed bugs.

Browse Source
This commit is contained in:
aarne
2003-12-04 12:08:29 +00:00
parent fa62fb4edf
commit 306d7cfc13
19 changed files with 3086 additions and 15 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
lib/resource-0.6/english/TestResourceEng.gf
View File

@@ -2,7 +2,7 @@
concrete TestResourceEng of TestResource = StructuralEng ** open SyntaxEng in {
flags startcat=Phr ; lexer=literals ; parser=chart ; unlexer=text ;
flags startcat=Phr ; lexer=textlit ; parser=chart ; unlexer=text ;
-- a random sample from the lexicon

4
lib/resource-0.6/french/CombinationsFre.gf Normal file
View File

@@ -0,0 +1,4 @@
--# -path=.:../romance:../abstract:../../prelude
concrete CombinationsFre of Combinations =
CombinationsRomance with (SyntaxRomance=SyntaxFre) ;

1231
lib/resource-0.6/french/MorphoFre.gf Normal file
View File

File diff suppressed because it is too large Load Diff

41
lib/resource-0.6/french/StructuralFre.gf Normal file
View File

@@ -0,0 +1,41 @@
--# -path=.:../romance:../abstract:../../prelude
concrete StructuralFre of Structural = CombinationsFre ** open SyntaxFre in {
lin
INP = pronNounPhrase pronJe ;
ThouNP = pronNounPhrase pronTu ;
HeNP = pronNounPhrase pronIl ;
SheNP = pronNounPhrase pronElle ;
WeNP n = pronNounPhrase (pronWithNum pronNous n) ;
YeNP n = pronNounPhrase (pronWithNum pronVous n) ;
YouNP = pronNounPhrase pronVous ;
TheyNP = pronNounPhrase pronIls ;
-- Here is a point where the API is really inadequate for French,
-- which distinguishes between masculine and feminine "they".
-- The following solution is not attractive.
--- TheyNP = pronNounPhrase (variants {pronIls ; pronElles}) ;
EveryDet = chaqueDet ;
---- AllDet = tousDet ;
WhichDet = quelDet ;
MostDet = plupartDet ;
HowIAdv = commentAdv ;
WhenIAdv = quandAdv ;
WhereIAdv = ouAdv ;
WhyIAdv = pourquoiAdv ;
AndConj = etConj ;
OrConj = ouConj ;
BothAnd = etetConj ;
EitherOr = ououConj ;
NeitherNor = niniConj ; --- requires ne !
IfSubj = siSubj ;
WhenSubj = quandSubj ;
PhrYes = ouiPhr ;
PhrNo = nonPhr ; --- and also Si!
}

292
lib/resource-0.6/french/SyntaxFre.gf Normal file
View File

@@ -0,0 +1,292 @@
--# -path=.:../romance:../../prelude
instance SyntaxFre of SyntaxRomance = TypesFre ** open Prelude, (CO=Coordination), MorphoFre in {
oper
nameNounPhrase = \jean ->
normalNounPhrase
(\\c => prepCase c ++ jean.s)
jean.g
Sg ;
chaqueDet = mkDeterminer1 Sg "chaque" ;
tousDet = mkDeterminer Pl ["tous les"] ["toutes les"] ;
plupartDet = mkDeterminer1 Pl ["la plupart des"] ;
unDet = mkDeterminer Sg "un" "une" ;
plDet = mkDeterminer1 Pl "des" ; ---
quelDet = mkDeterminer Sg "quel" "quelle" ;
quelsDet = mkDeterminer Pl "quels" "quelles" ;
npGenPoss = \n,ton,mec ->
\\c => prepCase c ++ ton.s ! Poss n mec.g ++ mec.s ! n ;
mkAdjReg : Str -> Bool -> Adjective = \adj,p ->
mkAdjective (adjGrand adj) p ;
comparConj = elisQue ;
mkAdjDegrReg : Str -> Bool -> AdjDegr = \adj,p ->
mkAdjDegrLong (adjGrand adj) p ;
-- The commonest case for functions is common noun + "de".
funDe : CommNounPhrase -> Function = \mere ->
mere ** complementCas genitive ;
-- Chains of "dont" - "dont" do not arise.
funRelPron : Function -> RelPron -> RelPron = \mere,lequel ->
{s = table {
RComplex g n c => variants {
case mere.c of { ---
Gen => lequel.s ! RSimple Gen ++
artDef mere.g n c ++ mere.s ! n ;
_ => nonExist} ;
artDef mere.g n c ++ mere.s ! n ++
mere.s2 ++ lequel.s ! RComplex g n mere.c
} ;
_ => nonExist
} ;
g = RG mere.g
} ;
-- Verbs
negVerb = \va -> elisNe ++ va ++ "pas" ;
copula = \b -> (etreNetre b).s ;
isTransVerbClit = \v -> case v.c of {
Acc => True ;
_ => False --- hmmm
} ;
-- The "ne - pas" negation.
posNeg = \b,v,c ->
if_then_else Str b
(v ++ c)
(elisNe ++ v ++ "pas" ++ c) ; --- exception: infinitive!
-- Exampe: 'to be or not to be'.
etreNetre : Bool -> VerbPres = \b ->
{s = \\w => posNeg b (verbEtre.s ! w) []} ; ---- v reveals a BUG in refresh
embedConj = elisQue ;
-- Relative pronouns
identRelPron = {
s = table {
RSimple c => relPronForms ! c ;
RComplex g n c => composRelPron g n c
} ;
g = RNoGen
} ;
suchPron = telPron ;
composRelPron = lequelPron ;
allRelForms = \lequel,g,n,c ->
variants {
lequel.s ! RSimple c ;
lequel.s ! RComplex g n c
} ;
-- Interrogative pronouns
nounIntPron = \n, mec ->
{s = \\c => prepCase c ++ quelPron mec.g n ++ mec.s ! n ;
g = mec.g ;
n = n
} ;
intPronWho = \num -> {
s = \\c => prepCase c ++ "qui" ;
g = Masc ; --- can we decide this?
n = num
} ;
intPronWhat = \num -> {
s = table {
Gen => ["de quoi"] ;
Acc => ["à quoi"] ;
c => elisQue
} ;
g = Masc ; --- can we decide this?
n = num
} ;
-- Questions
questVerbPhrase = \jean,dort ->
{s = table {
DirQ => optStr (estCeQue Acc) ++ (predVerbPhrase jean dort).s ! Ind ;
IndirQ => elisSi ++ (predVerbPhrase jean dort).s ! Ind
}
} ;
intVerbPhrase = \qui, dort ->
{s = table {
DirQ => qui.s ! Nom ++ optStr (estCeQue Nom) ++
dort.s ! qui.g ! VFin Ind qui.n P3 ;
IndirQ => "ce" ++ qui.s ! Nom ++ dort.s ! qui.g ! VFin Ind qui.n P3
}
} ;
intSlash = \Qui, Tuvois ->
let {qui = Tuvois.s2 ++ Qui.s ! Tuvois.c ; tuvois = Tuvois.s ! Ind} in
{s = table {
DirQ => qui ++ optStr (estCeQue Acc) ++ tuvois ;
IndirQ => ifCe Tuvois.c ++ qui ++ tuvois
}
} ;
-- An auxiliary to distinguish between
-- "je ne sais pas" ("ce qui dort" / "ce que tu veux" / "à qui tu penses").
ifCe : Case -> Str = \c -> case c of {
Nom => "ce" ;
Acc => "ce" ;
_ => []
} ;
questAdverbial = \quand, jean, dort ->
let {jeandort = (predVerbPhrase jean dort).s ! Ind} in
{s = table {
DirQ => quand.s ++ optStr (estCeQue Acc) ++ jeandort ;
IndirQ => quand.s ++ jeandort
}
} ;
----- moved from Morpho
--2 Articles
--
-- A macro for defining gender-dependent tables will be useful.
-- Its first application is in the indefinite article.
--
-- Notice that the plural genitive is special: "de femmes".
genForms : Str -> Str -> Gender => Str = \bon,bonne ->
table {Masc => bon ; Fem => bonne} ;
artIndef = \g,n,c -> case <n,c> of {
<Sg,_> => prepCase c ++ genForms "un" "une" ! g ;
<Pl,Gen> => elisDe ;
_ => prepCase c ++ "des"
} ;
artDef = \g,n,c -> artDefTable ! g ! n ! c ;
pronJe = mkPronoun
(elision "j")
(elision "m")
(elision "m")
"moi"
"mon" (elisPoss "m") "mes"
PNoGen -- gender cannot be known from pronoun alone
Sg
P1
Clit1 ;
pronTu = mkPronoun
"tu"
(elision "t")
(elision "t")
"toi"
"ton" (elisPoss "t") "tes"
PNoGen
Sg
P2
Clit1 ;
pronIl = mkPronoun
"il"
(elision "l")
"lui"
"lui"
"son" (elisPoss "s") "ses"
(PGen Masc)
Sg
P3
Clit2 ;
pronElle = mkPronoun
"elle"
elisLa
"lui"
"elle"
"son" (elisPoss "s") "ses"
(PGen Fem)
Sg
P3
Clit2 ;
pronNous = mkPronoun
"nous"
"nous"
"nous"
"nous"
"notre" "notre" "nos"
PNoGen
Pl
P1
Clit3 ;
pronVous = mkPronoun
"vous"
"vous"
"vous"
"vous"
"votre" "votre" "vos"
PNoGen
Pl --- depends!
P2
Clit3 ;
pronIls = mkPronoun
"ils"
"les"
"leur"
"eux"
"leur" "leur" "leurs"
(PGen Masc)
Pl
P3
Clit1 ;
pronElles = mkPronoun
"elles"
"les"
"leur"
"elles"
"leur" "leur" "leurs"
(PGen Fem)
Pl
P3
Clit1 ;
-- moved from ResFra
commentAdv = ss "comment" ;
quandAdv = ss "quand" ;
ouAdv = ss "où" ;
pourquoiAdv = ss "pourquoi" ;
etConj = ss "et" ** {n = Pl} ;
ouConj = ss "ou" ** {n = Sg} ;
etetConj = sd2 "et" "et" ** {n = Pl} ;
ououConj = sd2 "ou" "ou" ** {n = Sg} ;
niniConj = sd2 "ni" "ni" ** {n = Sg} ; --- requires ne !
siSubj = ss elisSi ;
quandSubj = ss "quand" ;
ouiPhr = ss ["Oui ."] ;
nonPhr = ss ["Non ."] ; --- and also Si!
}

34
lib/resource-0.6/french/TestResourceFre.gf Normal file
View File

@@ -0,0 +1,34 @@
--# -path=.:../romance:../abstract:../../prelude
concrete TestResourceFre of TestResource = StructuralFre ** open Prelude, TypesFre, MorphoFre, SyntaxFre in {
flags startcat=Phr ; lexer=text ; parser=chart ; unlexer=text ;
lin
Big = mkAdjDegrReg "grand" adjPre ;
Small = mkAdjDegrReg "petit" adjPre ;
Old = mkAdjDegrLong (mkAdj "vieux" "vieux" "vieille") adjPre ;
Young = mkAdjDegrLong (adjJeune "jeune") adjPre ;
Man = mkCNomReg "homme" Masc ;
Woman = mkCNomReg "femme" Fem ;
Car = mkCNomReg "voiture" Fem ;
Light = mkCNomReg "lumière" Fem ;
House = mkCNomReg "maison" Fem ;
Walk = verbPres (conj1aimer "marcher") ;
Run = verbPres (conj3courir "courir") ;
Send = mkTransVerbDir (verbPres (conj1envoyer "envoyer")) ;
Love = mkTransVerbDir (verbPres (conj1aimer "aimer")) ;
Wait = mkTransVerbDir (verbPres (conj3rendre "attendre")) ;
Say = verbSent (verbPres (conj3dire "dire")) Ind Ind ;
Prove = verbSent (verbPres (conj1aimer "démontrer")) Ind Ind ;
SwitchOn = mkTransVerbDir (verbPres (conj1aimer "allumer")) ;
SwitchOff = mkTransVerbDir (verbPres (conj3peindre "éteindre")) ;
Mother = funDe (mkCNomReg "mère" Fem) ;
Uncle = funDe (mkCNomReg "oncle" Masc) ;
Well = ss "bien" ;
Always = ss "toujours" ;
John = mkProperName "Jean" Masc ;
Mary = mkProperName "Marie" Fem ;
}

160
lib/resource-0.6/french/TypesFre.gf Normal file
View File

@@ -0,0 +1,160 @@
--1 French Word Classes and Morphological Parameters
--
-- This is a resource module for Italian morphology, defining the
-- morphological parameters and word classes of Italian.
-- The morphology is so far only
-- complete w.r.t. the syntax part of the resource grammar.
-- It does not include those parameters that are not needed for
-- analysing individual words: such parameters are defined in syntax modules.
instance TypesFre of TypesRomance = {
-- Now we can give values to the abstract types.
param
Case = Nom | Acc | Gen | Dat ; -- corresp. to prepositions de and à
NPForm = Ton Case | Aton Case | Poss Number Gender ;
oper
CaseA = Case ;
NPFormA = NPForm ;
nominative = Nom ;
accusative = Acc ;
genitive = Gen ;
dative = Dat ;
stressed = Ton ;
unstressed = Aton ;
------------------------- move this somewhere else!
--2 Some phonology
--
--3 Elision
--
-- The phonological rule of *elision* can be defined as follows in GF.
-- There is one thing that is not treated properly: the "h aspiré",
-- which is not separated orthographically from the "h muet".
-- Our definition works correctly only for the "h muet".
oper
voyelle : Strs = strs {
"a" ; "â" ; "à" ; "e" ; "ê" ; "é" ; "è" ;
"h" ;
"i" ; "î" ; "o" ; "ô" ; "u" ; "û" ; "y"
} ;
elision : Str -> Str = \d -> d + pre {"e" ; "'" / voyelle} ;
-- The following morphemes are the most common uses of elision.
elisDe = elision "d" ;
elisLa = pre {"la" ; "l'" / voyelle} ;
elisLe = elision "l" ;
elisNe = elision "n" ;
elisQue = elision "qu" ;
-- The subjunction "si" has a special kind of elision. The rule is
-- only approximatively correct, for "si" is not really elided before
-- the string "il" in general, but before the pronouns "il" and "ils".
elisSi = pre {"si" ; "s'" / strs {"il"}} ;
--2 Prepositions
--
-- The type $Cas$ in $types.Fra.gf$ has the dative and genitive
-- cases, which are relevant for pronouns and the definite article,
-- but which are otherwise expressed by prepositions.
prepCase = \c -> case c of {
Nom => [] ;
Acc => [] ;
Gen => elisDe ;
Dat => "à"
} ;
--2 Relative pronouns
--
-- The simple (atonic) relative pronoun shows genuine variation in all of the
-- cases.
relPronForms = table {
Nom => "qui" ; Gen => "dont" ; Dat => ["à qui"] ; Acc => elisQue
} ;
-- Usually the comparison forms are built by prefixing the word
-- "plus". The definite article needed in the superlative is provided in
-- $syntax.Fra.gf$.
adjCompLong : Adj -> AdjComp = \cher ->
mkAdjComp
cher.s
(\\g,n => "plus" ++ cher.s ! g ! n) ;
-- Comparative adjectives are only sometimes formed morphologically
-- (actually: by different morphemes).
mkAdjComp : (_,_ : Gender => Number => Str) -> AdjComp =
\bon, meilleur ->
{s = table {Pos => bon ; _ => meilleur}} ;
------------------------------
-- Their inflection tables has tonic and atonic forms, as well as
-- the possessive forms, which are inflected like determiners.
--
-- Example: "lui, de lui, à lui" - "il,le,lui" - "son,sa,ses".
--
-- Examples of each: "Jean" ; "je"/"te" ; "il"/"elle"/"ils"/"elles" ; "nous"/"vous".
-- The following coercions are useful:
oper
pform2case = \p -> case p of {
Ton x => x ;
Aton x => x ;
Poss _ _ => Gen
} ;
case2pform = \c -> case c of {
Nom => Aton Nom ;
Acc => Aton Acc ;
_ => Ton c
} ;
-- Relative pronouns: the case-dependent parameter type.
param RelForm = RSimple Case | RComplex Gender Number Case ;
oper RelFormA = RelForm ;
-- Verbs: conversion from full verbs to present-tense verbs.
verbPres = \aller -> {s = table {
VInfin => aller ! Inf ;
VFin Ind n p => aller ! Indic Pres n p ;
VFin Sub n p => aller ! Subjo SPres n p ;
VImper np => aller ! Imper np
}} ;
-- The full conjunction is a table on $VForm$:
param
Temps = Pres | Imparf | Passe | Futur ;
TSubj = SPres | SImparf ;
TPart = PPres | PPasse Gender Number ;
VForm = Inf
| Indic Temps Number Person
| Cond Number Person
| Subjo TSubj Number Person
| Imper NumPersI
| Part TPart ;
-- This is the full verb type.
oper
Verbum : Type = VForm => Str ;
}

162
lib/resource-0.6/romance/CombinationsRomance.gf Normal file
View File

@@ -0,0 +1,162 @@
--# -path=.:../abstract:../../prelude
--1 The Top-Level French Resource Grammar
--
-- Aarne Ranta 2002 -- 2003
--
-- This is the French concrete syntax of the multilingual resource
-- grammar. Most of the work is done in the file
-- $syntax.Romance.gf$, some in $syntax.Fra.gf$.
-- However, for the purpose of documentation, we make here explicit the
-- linearization types of each category, so that their structures and
-- dependencies can be seen.
-- Another substantial part are the linearization rules of some
-- structural words.
--
-- The users of the resource grammar should not look at this file for the
-- linearization rules, which are in fact hidden in the document version.
-- They should use $resource.Abs.gf$ to access the syntactic rules.
-- This file can be consulted in those, hopefully rare, occasions in which
-- one has to know how the syntactic categories are
-- implemented. Most parameter types are defined in $types.Romance.gf$, some in
-- $types.Fra.gf$.
incomplete concrete CombinationsRomance of Combinations =
open Prelude, SyntaxRomance in {
flags
startcat=Phr ;
lincat
N = CommNoun ;
-- = {s : Number => Str ; g : Gender} ;
CN = CommNoun ;
NP = {s : NPFormA => Str ; g : PronGen ;
n : Number ; p : Person ; c : ClitType} ;
PN = {s : Str ; g : Gender} ;
Det = {s : Gender => Str ; n : Number} ;
Adj1 = Adjective ;
-- = {s : Gender => Number => Str ; p : Bool} ;
Adj2 = Adjective ** {s2 : Preposition ; c : CaseA} ;
AdjDeg = {s : Degree => Gender => Number => Str ; p : Bool} ;
AP = Adjective ;
Fun = CommNoun ** {s2 : Preposition ; c : CaseA} ;
Prep = {s : Preposition ; c : CaseA} ;
Num = {s : Gender => Str} ;
V = Verb ;
-- = {s : VF => Str} ;
VG = {s : Bool => Gender => VF => Str} ;
VP = {s : Gender => VF => Str} ;
TV = Verb ** {s2 : Preposition ; c : CaseA} ;
VS = Verb ** {mp,mn : Mode} ;
AdV = {s : Str} ;
S = Sentence ;
-- = {s : Mode => Str} ;
Slash = Sentence ** {s2 : Preposition ; c : CaseA} ;
RP = {s : RelForm => Str ; g : RelGen} ;
RC = {s : Mode => Gender => Number => Str} ;
IP = {s : CaseA => Str ; g : Gender ; n : Number} ;
Qu = {s : QuestForm => Str} ;
Imp = {s : Gender => Number => Str} ;
Phr = {s : Str} ;
Conj = {s : Str ; n : Number} ;
ConjD = {s1,s2 : Str ; n : Number} ;
ListS = {s1,s2 : Mode => Str} ;
ListAP = {s1,s2 : Gender => Number => Str ; p : Bool} ;
ListNP = {s1,s2 : CaseA => Str ; g : PronGen ; n : Number ; p : Person} ;
--.
lin
UseN = noun2CommNounPhrase ;
ModAdj = modCommNounPhrase ;
ModGenOne = npGenDet singular ;
---- ModGenMany = npGenDet plural ;
UsePN = nameNounPhrase ;
UseFun = funAsCommNounPhrase ; -- [SyntaxFra.noun2CommNounPhrase]
AppFun = appFunComm ;
AdjP1 = adj2adjPhrase ;
ComplAdj = complAdj ;
PositAdjP = positAdjPhrase ;
ComparAdjP = comparAdjPhrase ;
SuperlNP = superlNounPhrase ;
DetNP = detNounPhrase ;
IndefOneNP = indefNounPhrase singular ;
---- IndefManyNP = indefNounPhrase plural ;
DefOneNP = defNounPhrase singular ;
---- DefManyNP = defNounPhrase plural ;
PredVP = predVerbPhrase ;
PredV = predVerb ;
PredAP = predAdjective ;
PredCN = predCommNoun ;
PredTV = complTransVerb ;
PredNP = predNounPhrase ;
PredVS = complSentVerb ;
AdvVP = adVerbPhrase ;
PrepNP = prepNounPhrase ;
AdvCN = advCommNounPhrase ;
PosSlashTV = slashTransVerb True ;
NegSlashTV = slashTransVerb False ;
IdRP = identRelPron ;
FunRP = funRelPron ;
RelVP = relVerbPhrase ;
RelSlash = relSlash ;
ModRC = modRelClause ;
RelSuch = relSuch ;
WhoOne = intPronWho singular ;
---- WhoMany = intPronWho plural ;
WhatOne = intPronWhat singular ;
---- WhatMany = intPronWhat plural ;
FunIP = funIntPron ;
NounIPOne = nounIntPron singular ;
---- NounIPMany = nounIntPron plural ;
QuestVP = questVerbPhrase ;
IntVP = intVerbPhrase ;
IntSlash = intSlash ;
QuestAdv = questAdverbial ;
ImperVP = imperVerbPhrase ;
IndicPhrase = indicUtt ;
QuestPhrase = interrogUtt ;
ImperOne = imperUtterance singular ;
ImperMany = imperUtterance plural ;
TwoS = twoSentence ;
ConsS = consSentence ;
ConjS = conjunctSentence ;
ConjDS = conjunctDistrSentence ; -- [Coordination.conjunctDistrTable]
TwoAP = twoAdjPhrase ;
ConsAP = consAdjPhrase ;
ConjAP = conjunctAdjPhrase ;
ConjDAP = conjunctDistrAdjPhrase ;
TwoNP = twoNounPhrase ;
ConsNP = consNounPhrase ;
ConjNP = conjunctNounPhrase ;
ConjDNP = conjunctDistrNounPhrase ;
SubjS = subjunctSentence ; -- stack
SubjImper = subjunctImperative ;
SubjQu = subjunctQuestion ;
PhrNP = useNounPhrase ;
PhrOneCN = useCommonNounPhrase singular ;
PhrManyCN = useCommonNounPhrase plural ;
PhrIP ip = ip ;
PhrIAdv ia = ia ;
}

925
lib/resource-0.6/romance/SyntaxRomance.gf Normal file
View File

@@ -0,0 +1,925 @@
--1 A Small Romance Resource Syntax
--
-- Aarne Ranta 2002
--
-- This resource grammar contains definitions needed to construct
-- indicative, interrogative, and imperative sentences in Romance languages.
-- We try to share as much as possible. Even if the definitions of certain
-- operations are different in $syntax.Fra.gf$ and $syntax.Ita.gf$, we can
-- often give their type signatures in this file.
--
-- The following files are presupposed:
interface SyntaxRomance = TypesRomance ** open Prelude, (CO=Coordination) in {
--2 Common Nouns
--
-- Common nouns are defined as number-dependent strings with a gender.
-- Complex common noun ($CommNounPhrase$) have the same type as simple ones.
-- (The distinction is made just because of uniformity with other languages.)
oper
CommNoun : Type = {s : Number => Str ; g : Gender} ;
CommNounPhrase = CommNoun ;
noun2CommNounPhrase : CommNounPhrase -> CommNoun = \x -> x ;
commonNounComp : CommNoun -> Str -> CommNoun = \numero, detelephone ->
{s = \\n => numero.s ! n ++ detelephone ;
g = numero.g
} ;
--2 Noun phrase
--
-- The worst case is pronouns, which have inflection in the possessive
-- forms. Other noun phrases express all possessive forms with the genitive case.
-- Proper names are the simples example.
ProperName : Type = {s : Str ; g : Gender} ;
NounPhrase : Type = Pronoun ; -- the worst case
nameNounPhrase : ProperName -> NounPhrase ;
mkProperName : Str -> Gender -> ProperName = \jean,m ->
{s = jean ; g = m} ;
mkNameNounPhrase : Str -> Gender -> NounPhrase = \jean,m ->
nameNounPhrase (mkProperName jean m) ;
normalNounPhrase : (CaseA => Str) -> Gender -> Number -> NounPhrase = \cs,g,n ->
{s = \\p => cs ! (pform2case p) ;
g = PGen g ;
n = n ;
p = P3 ; -- third person
c = Clit0 -- not clitic
} ;
pronNounPhrase : Pronoun -> NounPhrase = \pro -> pro ;
-- Many determiners can be modified with numerals, which may be inflected in
-- gender.
Numeral : Type = {s : Gender => Str} ;
pronWithNum : Pronoun -> Numeral -> Pronoun = \nous,deux ->
{s = \\c => nous.s ! c ++ deux.s ! pgen2gen nous.g ;
g = nous.g ;
n = nous.n ;
p = nous.p ;
c = nous.c
} ;
noNum : Numeral = {s = \\_ => []} ;
--2 Determiners
--
-- Determiners are inflected according to the gender of the nouns they determine.
-- The determiner determines the number of the argument noun.
Determiner : Type = {s : Gender => Str ; n : Number} ;
detNounPhrase : Determiner -> CommNoun -> NounPhrase = \tout, homme ->
normalNounPhrase
(\\c => prepCase c ++ tout.s ! homme.g ++ homme.s ! tout.n)
homme.g
tout.n ;
-- The following macros are sufficient to define most determiners,
-- as shown by the examples that follow.
mkDeterminer : Number -> Str -> Str -> Determiner = \n,tous,toutes ->
{s = genForms tous toutes ; n = n} ;
mkDeterminer1 : Number -> Str -> Determiner = \n,chaque ->
mkDeterminer n chaque chaque ;
mkDeterminerNum : Number -> Str -> Str -> Numeral -> Determiner =
\n,tous,toutes,nu ->
{s = \\g => genForms tous toutes ! g ++ nu.s ! g ; n = n} ;
-- Indefinite and definite noun phrases are treated separately,
-- since noun phrases formed by them also depend on case.
-- The indefinite case with a numeral has no separate article:
-- "il y a 86 voitures", not "il y a des 86 voitures".
indefNounPhrase : Number -> CommNounPhrase -> NounPhrase = \n,mec ->
normalNounPhrase
(\\c => artIndef mec.g n c ++ mec.s ! n)
mec.g
n ;
indefNounPhraseNum : Numeral -> CommNounPhrase -> NounPhrase = \nu,mec ->
normalNounPhrase
(\\c => nu.s ! mec.g ++ mec.s ! Pl)
mec.g
Pl ;
defNounPhrase : Number -> CommNounPhrase -> NounPhrase = \n,mec ->
normalNounPhrase
(\\c => artDef mec.g n c ++ mec.s ! n)
mec.g
n ;
defNounPhraseNum : Numeral -> CommNounPhrase -> NounPhrase = \nu,mec ->
normalNounPhrase
(\\c => artDef mec.g Pl c ++ nu.s !mec.g ++ mec.s ! Pl)
mec.g
Pl ;
-- We often need indefinite noun phrases synacategorematically.
indefNoun : Number -> CommNounPhrase -> Str = \n,mec ->
(indefNounPhrase n mec).s ! case2pform nominative ;
-- Genitives of noun phrases can be used like determiners, to build noun phrases.
-- The number argument makes the difference between "ma maison" - "mes maisons".
-- The clitic type of the NP decides between "ma maison" and "la maison de Jean".
npGenDet : Number -> NounPhrase -> CommNounPhrase -> NounPhrase =
\n,jeanne,mec ->
let {str : CaseA => Str = case jeanne.c of {
Clit0 => npGenDe n jeanne mec ;
_ => npGenPoss n jeanne mec
}
} in
normalNounPhrase str mec.g n ;
npGenDetNum : Numeral -> NounPhrase -> CommNounPhrase -> NounPhrase =
\nu,jeanne,mec ->
let {str : CaseA => Str = case jeanne.c of {
Clit0 => npGenDeNum nu jeanne mec ;
_ => npGenPossNum nu jeanne mec
}
} in
normalNounPhrase str mec.g Pl ;
-- These auxiliary rules define the genitive with "de" and with the possessive.
-- Here there is a difference between French and Italian: Italian has a definite
-- article before possessives (with certain exceptions).
npGenDe : Number -> NounPhrase -> CommNounPhrase -> CaseA => Str =
\n,jeanne,mec ->
\\c => artDef mec.g n c ++ mec.s ! n ++ jeanne.s ! case2pform genitive ;
npGenDeNum : Numeral -> NounPhrase -> CommNounPhrase -> CaseA => Str =
\nu,jeanne,mec ->
\\c => artDef mec.g Pl c ++ nu.s ! mec.g ++ mec.s ! Pl ++
jeanne.s ! case2pform genitive ;
npGenPoss : Number -> NounPhrase -> CommNounPhrase -> CaseA => Str ;
npGenPossNum : Numeral -> NounPhrase -> CommNounPhrase -> CaseA => Str ;
--2 Adjectives
--
-- Adjectives have a parameter $p$ telling if postposition is
-- allowed (complex APs). There is no real need in Romance languages to distinguish
-- between simple adjectives and adjectival phrases.
Adjective : Type = Adj ** {p : Bool} ;
adjPre = True ; adjPost = False ;
AdjPhrase : Type = Adjective ;
adj2adjPhrase : Adjective -> AdjPhrase = \x -> x ;
mkAdjective : Adj -> Bool -> Adjective = \adj,p -> adj ** {p = p} ;
--3 Comparison adjectives
--
-- The type is defined in $types.Romance.gf$. Syntax adds to lexicon the position
-- information.
AdjDegr = AdjComp ** {p : Bool} ;
mkAdjDegr : AdjComp -> Bool -> AdjDegr = \adj,p ->
adj ** {p = p} ;
mkAdjDegrLong : Adj -> Bool -> AdjDegr = \adj,p ->
adjCompLong adj ** {p = p} ;
-- Each of the comparison forms has a characteristic use:
--
-- Positive forms are used alone, as adjectival phrases ("bon").
positAdjPhrase : AdjDegr -> AdjPhrase = \bon ->
{s = bon.s ! Pos ;
p = bon.p
} ;
-- Comparative forms are used with an object of comparison, as
-- adjectival phrases ("meilleur que toi"). The comparing conjunction
-- is of course language-dependent; Italian moreover has the free
-- variants "che" and "di".
comparAdjPhrase : AdjDegr -> NounPhrase -> AdjPhrase = \bon, toi ->
{s = \\g,n => bon.s ! Comp ! g ! n ++ comparConj ++
toi.s ! stressed accusative ;
p = False
} ;
comparConj : Str ;
-- Superlative forms are used with a common noun, picking out the
-- maximal representative of a domain
-- ("le meilleur mec", "le mec le plus intelligent").
superlNounPhrase : AdjDegr -> CommNoun -> NounPhrase = \bon, mec ->
normalNounPhrase
(\\c => artDef mec.g Sg c ++ if_then_else Str bon.p
(bon.s ! Sup ! mec.g ! Sg ++ mec.s ! Sg)
(mec.s ! Sg ++ artDef mec.g Sg nominative ++ bon.s ! Sup ! mec.g ! Sg)
)
mec.g
Sg ;
--3 Prepositions and complements
--
-- Most prepositions are just strings. But "à" and "de" are treated as cases in
-- French. In Italian, there are more prepositions treated in this way:
-- "a", "di", "da", "in", "su", "con".
-- An invariant is that, if the preposition is not empty ($[]$), then the case
-- is $Acc$.
Preposition = Str ;
Complement = {s2 : Preposition ; c : CaseA} ;
complement : Str -> Complement = \par ->
{s2 = par ; c = nominative} ;
complementDir : Complement = complement [] ;
complementCas : CaseA -> Complement = \c ->
{s2 = [] ; c = c} ;
--3 Two-place adjectives
--
-- A two-place adjective is an adjective with a preposition used before
-- the complement, and the complement case.
AdjCompl = AdjPhrase ** Complement ;
mkAdjCompl : Adj -> Bool -> Complement -> AdjCompl = \adj,p,c ->
mkAdjective adj p ** c ;
complAdj : AdjCompl -> NounPhrase -> AdjPhrase = \relie,jean ->
{s = \\g,n => relie.s ! g ! n ++ relie.s2 ++ jean.s ! case2pform relie.c ;
p = False
} ;
--3 Modification of common nouns
--
-- The two main functions of adjective are in predication ("Jean est jeune")
-- and in modification ("un jeune homme"). Predication will be defined
-- later, in the chapter on verbs.
--
-- Modification must pay attention to pre- and post-noun
-- adjectives: "jeune homme"; "homme intelligent".
modCommNounPhrase : AdjPhrase -> CommNounPhrase -> CommNounPhrase = \bon,mec ->
{s = \\n => if_then_else Str bon.p
(bon.s ! mec.g ! n ++ mec.s ! n)
(mec.s ! n ++ bon.s ! mec.g ! n) ;
g = mec.g
} ;
--2 Function expressions
-- A function expression is a common noun together with the
-- preposition prefixed to its argument ("mère de x").
-- The type is analogous to two-place adjectives and transitive verbs.
Function : Type = CommNounPhrase ** Complement ;
-- The application of a function gives, in the first place, a common noun:
-- "mor/mödrar till Johan". From this, other rules of the resource grammar
-- give noun phrases, such as "la mère de Jean", "les mères de Jean",
-- "les mères de Jean et de Marie", and "la mère de Jean et de Marie" (the
-- latter two corresponding to distributive and collective functions,
-- respectively). Semantics will eventually tell when each
-- of the readings is meaningful.
appFunComm : Function -> NounPhrase -> CommNounPhrase = \mere,jean ->
noun2CommNounPhrase
{s = \\n => mere.s ! n ++ mere.s2 ++ jean.s ! case2pform mere.c ;
g = mere.g
} ;
-- It is possible to use a function word as a common noun; the semantics is
-- often existential or indexical.
funAsCommNounPhrase : Function -> CommNounPhrase =
noun2CommNounPhrase ;
-- The following is an aggregate corresponding to the original function application
-- producing "ma mère" and "la mère de Jean". It does not appear in the
-- resource grammar API any longer.
appFun : Bool -> Function -> NounPhrase -> NounPhrase = \coll, mere, jean ->
let {n = jean.n ; g = mere.g ; nf = if_then_else Number coll Sg n} in
variants {
defNounPhrase nf (appFunComm mere jean) ;
npGenDet nf jean mere
} ;
--2 Verbs
--
--3 Verb phrases
--
-- Unlike many other languages, verb phrases in Romance languages
-- are not discontinuous.
-- We use clitic parameters instead.
--
-- (It is not quite sure, though, whether this
-- will suffice in French for examples like "je n'*y* vais pas": one may want to
-- add "y" to "ne vais pas" instead of "ne - pas" to "y vais".)
--
-- So far we restrict the syntax to present-tense verbs, even though
-- morphology has complete conjugations.
VerbPhrase = {s : Gender => VF => Str} ;
VerbGroup = {s : Bool => Gender => VF => Str} ;
predVerbGroup : Bool -> VerbGroup -> VerbPhrase = \b,vg -> {
s = vg.s ! b
} ;
Verb = VerbPres ;
-- Predication is language-dependent in the negative case.
predVerb : VerbPres -> VerbGroup = \aller ->
{s = \\b,_,v => if_then_Str b (aller.s ! v) (negVerb (aller.s ! v))} ;
negVerb : Str -> Str ;
-- Verb phrases can also be formed from adjectives ("est bon"),
-- common nouns ("est un homme"), and noun phrases ("est Jean").
-- We need a copula, which is of course language-dependent.
copula : Bool -> VF => Str ;
-- The third rule is overgenerating: "est chaque homme" has to be ruled out
-- on semantic grounds.
predAdjective : AdjPhrase -> VerbGroup = \bon ->
{s = \\b,g,v => copula b ! v ++ bon.s ! g ! nombreVerb v} ;
predCommNoun : CommNounPhrase -> VerbGroup = \homme ->
{s = \\b,g,v => copula b ! v ++ indefNoun (nombreVerb v) homme} ;
predNounPhrase : NounPhrase -> VerbGroup = \jean ->
{s = \\b,g,v => copula b ! v ++ jean.s ! stressed nominative} ;
-- complement a verb with noun phrase and optional preposition
TransVerb : Type = VerbPres ** Complement ;
verbOfTransVerb : TransVerb -> VerbPres = \v -> {s = v.s} ;
complementOfTransVerb : TransVerb -> Complement = \v -> {s2 = v.s2 ; c = v.c} ;
isNounPhraseClit : NounPhrase -> Bool = \n -> case n.c of {
Clit0 => False ;
_ => True
} ;
-- This function is language-dependent, because it uses the language-dependent
-- type of case.
isTransVerbClit : TransVerb -> Bool ;
--3 Transitive verbs
--
-- Transitive verbs are verbs with a preposition for the complement,
-- in analogy with two-place adjectives and functions.
-- One might prefer to use the term "2-place verb", since
-- "transitive" traditionally means that the inherent preposition is empty.
-- Such a verb is one with a *direct object* - which may still be accusative,
-- dative, or genitive.
--
-- In complementation, we do need some dispatching of clitic types:
-- "aime Jean" ; "n'aime pas Jean" ; "l'aime" ; "ne l'aime pas".
-- More will be needed when we add ditransitive verbs.
complTransVerb : TransVerb -> NounPhrase -> VerbGroup = \aime,jean ->
{s = \\b,g,w => ---- BUG: v gives stack overflow
let {Jean = jean.s ! (case2pform aime.c) ; Aime = aime.s ! w} in
if_then_Str (andB (isNounPhraseClit jean) (isTransVerbClit aime))
(posNeg b (Jean ++ Aime) [])
(posNeg b Aime Jean)
} ;
mkTransVerb : Verb -> Preposition -> CaseA -> TransVerb = \v,p,c ->
v ** {s2 = p ; c = c} ;
mkTransVerbPrep : Verb -> Preposition -> TransVerb = \passer,par ->
mkTransVerb passer par accusative ;
mkTransVerbCas : Verb -> CaseA -> TransVerb = \penser,a ->
mkTransVerb penser [] a ;
mkTransVerbDir : Verb -> TransVerb = \aimer ->
mkTransVerbCas aimer accusative ;
-- The following macro builds the "ne - pas" or "non" negation. The second
-- string argument is used for the complement of a verb phrase. In Italian,
-- one string argument would actually be enough.
posNeg : Bool -> (verb, compl : Str) -> Str ;
--2 Adverbials
--
-- Adverbials are not inflected (we ignore comparison, and treat
-- compared adverbials as separate expressions; this could be done another way).
--
-- (We should also take into account clitic ones, like "y",
-- as well as the position: "est toujours heureux" / "est heureux à Paris".)
Adverb : Type = SS ;
adVerbPhrase : VerbPhrase -> Adverb -> VerbPhrase = \chante, bien ->
{s = \\g,v => chante.s ! g ! v ++ bien.s} ;
-- Adverbials are typically generated by prefixing prepositions.
-- The rule for prepositional phrases also comprises the use of prepositions
-- treated as cases. Therefore, both a preposition and a case are needed
-- as arguments.
prepNounPhrase : {s : Preposition ; c : CaseA} -> NounPhrase -> Adverb =
\dans,jean ->
{s = dans.s ++ jean.s ! Ton dans.c} ;
-- This is a source of the "homme avec un téléscope" ambiguity, and may produce
-- strange things, like "les voitures toujours".
-- Semantics will have to make finer distinctions among adverbials.
-- French moreover says "les voitures d'hier" rather than "les voitures hier".
advCommNounPhrase : CommNounPhrase -> Adverb -> CommNounPhrase = \mec,aparis ->
{s = \\n => mec.s ! n ++ aparis.s ;
g = mec.g
} ;
--2 Sentences
--
-- Sentences depend on a *mode parameter* selecting between
-- indicative and subjunctive forms.
Sentence : Type = SS1 Mode ;
-- This is the traditional $S -> NP VP$ rule. It takes care of both
-- mode and agreement.
predVerbPhrase : NounPhrase -> VerbPhrase -> Sentence = \jean,dort ->
{s = \\m => jean.s ! unstressed nominative ++
dort.s ! pgen2gen jean.g ! VFin m jean.n jean.p
} ;
--3 Sentence-complement verbs
--
-- Sentence-complement verbs take sentences as complements.
-- The mode of the complement depends on the verb, and can be different
-- for positive and negative uses of the verb
-- ("je crois qu'elle vient" -"je ne crois pas qu'elle vienne"),
SentenceVerb : Type = VerbPres ** {mp, mn : Mode} ;
complSentVerb : SentenceVerb -> Sentence -> VerbGroup = \croire,jeanboit ->
{s = \\b,_,w =>
let {m = if_then_else Mode b croire.mp croire.mn}
in posNeg b (croire.s ! w) (embedConj ++ jeanboit.s ! m)} ; ----w
verbSent : Verb -> Mode -> Mode -> SentenceVerb = \v,mp,mn ->
v ** {mp = mp ; mn = mn} ;
-- The embedding conjunction is language dependent.
embedConj : Str ;
--2 Sentences missing noun phrases
--
-- This is one instance of Gazdar's *slash categories*, corresponding to his
-- $S/NP$.
-- We cannot have - nor would we want to have - a productive slash-category former.
-- Perhaps a handful more will be needed.
--
-- Notice that the slash category has the same relation to sentences as
-- transitive verbs have to verbs: it's like a *sentence taking a complement*.
SentenceSlashNounPhrase = Sentence ** Complement ;
slashTransVerb : Bool -> NounPhrase -> TransVerb -> SentenceSlashNounPhrase =
\b,jean,aimer ->
predVerbPhrase jean (predVerbGroup b (predVerb (verbOfTransVerb aimer))) **
complementOfTransVerb aimer ;
--2 Relative pronouns and relative clauses
--
-- Relative pronouns are inflected in
-- gender, number, and case. They can also have an inherent case,
-- but this case if 'variable' in the sense that it
-- is sometimes just mediated from the correlate
-- ("homme qui est bon"), sometimes inherent to the
-- pronominal phrase itself ("homme dont la mère est bonne").
oper
RelPron : Type = {s : RelFormA => Str ; g : RelGen} ;
RelClause : Type = {s : Mode => Gender => Number => Str} ;
mkGenRel : RelGen -> Gender -> Gender = \rg,g -> case rg of {
RG gen => gen ;
_ => g
} ;
-- Simple relative pronouns ("qui", "dont", "par laquelle")
-- have no inherent gender.
identRelPron : RelPron ;
composRelPron : Gender -> Number -> CaseA -> Str ;
-- Complex relative pronouns ("dont la mère") do have an inherent gender.
funRelPron : Function -> RelPron -> RelPron ;
-- There are often variants, i.e. short and long forms
-- ("que" - "lequel", "dont" -"duquel"), etc.
allRelForms : RelPron -> Gender -> Number -> CaseA -> Str ;
-- Relative clauses can be formed from both verb phrases ("qui dort") and
-- slash expressions ("que je vois", "dont je parle").
relVerbPhrase : RelPron -> VerbPhrase -> RelClause = \qui,dort ->
{s = \\m,g,n => allRelForms qui g n nominative ++ dort.s ! g ! VFin m n P3
} ;
relSlash : RelPron -> SentenceSlashNounPhrase -> RelClause = \dont,jeparle ->
{s = \\m,g,n => jeparle.s2 ++ allRelForms dont g n jeparle.c ++ jeparle.s ! m
} ;
-- A 'degenerate' relative clause is the one often used in mathematics, e.g.
-- "nombre x tel que x soit pair".
relSuch : Sentence -> RelClause = \A ->
{s = \\m,g,n => suchPron g n ++ embedConj ++ A.s ! m
} ;
suchPron : Gender -> Number -> Str ;
-- The main use of relative clauses is to modify common nouns.
-- The result is a common noun, out of which noun phrases can be formed
-- by determiners. A comma is used before the relative clause.
--
-- N.B. subjunctive relative clauses
-- ("je cherche un mec qui sache chanter") must have another structure
-- (unless common noun phrases are given a mode parameter...).
modRelClause : CommNounPhrase -> RelClause -> CommNounPhrase = \mec,quidort ->
{s = \\n => mec.s ! n ++ quidort.s ! Ind ! mec.g ! n ;
g = mec.g
} ;
--2 Interrogative pronouns
--
-- If relative pronouns are adjective-like, interrogative pronouns are
-- noun-phrase-like. We use a simplified type, since we don't need the possessive
-- forms.
--
-- N.B. "est-ce que", etc, will be added below
-- when pronouns are used in direct questions.
IntPron : Type = {s : CaseA => Str ; g : Gender ; n : Number} ;
-- In analogy with relative pronouns, we have a rule for applying a function
-- to a relative pronoun to create a new one.
funIntPron : Function -> IntPron -> IntPron = \mere,qui ->
{s = \\c =>
artDef mere.g qui.n c ++ mere.s ! qui.n ++ mere.s2 ++ qui.s ! mere.c ;
g = mere.g ;
n = qui.n
} ;
-- There is a variety of simple interrogative pronouns:
-- "quelle maison", "qui", "quoi". Their definitions are language-dependent.
nounIntPron : Number -> CommNounPhrase -> IntPron ;
intPronWho : Number -> IntPron ;
intPronWhat : Number -> IntPron ;
--2 Utterances
-- By utterances we mean whole phrases, such as
-- 'can be used as moves in a language game': indicatives, questions, imperative,
-- and one-word utterances. The rules are far from complete.
--
-- N.B. we have not included rules for texts, which we find we cannot say much
-- about on this level. In semantically rich GF grammars, texts, dialogues, etc,
-- will of course play an important role as categories not reducible to utterances.
-- An example is proof texts, whose semantics show a dependence between premises
-- and conclusions. Another example is intersentential anaphora.
Utterance = SS ;
indicUtt : Sentence -> Utterance = \x -> ss (x.s ! Ind ++ ".") ;
interrogUtt : Question -> Utterance = \x -> ss (x.s ! DirQ ++ "?") ;
--2 Questions
--
-- Questions are either direct ("qui a pris la voiture") or indirect
-- ("ce qui a pris la voiture").
param
QuestForm = DirQ | IndirQ ;
oper
Question = SS1 QuestForm ;
--3 Yes-no questions
--
-- Yes-no questions are used both independently ("Tu es fatigué?")
-- and after interrogative adverbials ("Pourquoi tu es fatigué?").
-- It is economical to handle with these two cases by the one
-- rule, $questVerbPhrase'$. The only difference is if "si" appears
-- in the indirect form.
--
-- N.B. the inversion variant ("Es-tu fatigué?") is missing, mainly because our
-- verb morphology does not support the intervening "t" ("Marche-t-il?").
-- The leading "est-ce que" is recognized as a variant, and requires
-- direct word order.
questVerbPhrase : NounPhrase -> VerbPhrase -> Question ;
--3 Wh-questions
--
-- Wh-questions are of two kinds: ones that are like $NP - VP$ sentences,
-- others that are line $S/NP - NP$ sentences.
--
-- N.B. inversion variants and "est-ce que" are treated as above.
intVerbPhrase : IntPron -> VerbPhrase -> Question ;
intSlash : IntPron -> SentenceSlashNounPhrase -> Question ;
--3 Interrogative adverbials
--
-- These adverbials will be defined in the lexicon: they include
-- "quand", "où", "comment", "pourquoi", etc, which are all invariant one-word
-- expressions. In addition, they can be formed by adding prepositions
-- to interrogative pronouns, in the same way as adverbials are formed
-- from noun phrases.
--
-- N.B. inversion variants and "est-ce que" are treated as above.
IntAdverb = SS ;
questAdverbial : IntAdverb -> NounPhrase -> VerbPhrase -> Question ;
--2 Imperatives
--
-- We only consider second-person imperatives.
--
-- N.B. following the API, we don't distinguish between
-- singular and plural "vous", nor between masculine and feminine.
-- when forming utterances.
--
-- TODO: clitics, Italian negated imperative.
Imperative = {s : Gender => Number => Str} ;
imperVerbPhrase : VerbPhrase -> Imperative = \dormir ->
{s = \\g,n => dormir.s ! g ! vImper n P2
} ;
imperUtterance : Number -> Imperative -> Utterance = \n,I ->
ss (I.s ! Masc ! n ++ "!") ;
--2 Coordination
--
-- Coordination is to some extent orthogonal to the rest of syntax, and
-- has been treated in a generic way in the module $CO$ in the file
-- $coordination.gf$. The overall structure is independent of category,
-- but there can be differences in parameter dependencies.
--
--3 Conjunctions
--
-- Coordinated phrases are built by using conjunctions, which are either
-- simple ("et", "ou") or distributed ("et - et", "pu - ou").
Conjunction = CO.Conjunction ** {n : Number} ;
ConjunctionDistr = CO.ConjunctionDistr ** {n : Number} ;
--3 Coordinating sentences
--
-- We need a category of lists of sentences. It is a discontinuous
-- category, the parts corresponding to 'init' and 'last' segments
-- (rather than 'head' and 'tail', because we have to keep track of the slot between
-- the last two elements of the list). A list has at least two elements.
--
-- N.B. we don't have repetion of "que" in subordinate coordinated sentences.
ListSentence : Type = {s1,s2 : Mode => Str} ;
twoSentence : (_,_ : Sentence) -> ListSentence =
CO.twoTable Mode ;
consSentence : ListSentence -> Sentence -> ListSentence =
CO.consTable Mode CO.comma ;
-- To coordinate a list of sentences by a simple conjunction, we place
-- it between the last two elements; commas are put in the other slots,
-- e.g. "Pierre fume, Jean boit et les autres regardsnt".
conjunctSentence : Conjunction -> ListSentence -> Sentence =
CO.conjunctTable Mode ;
-- To coordinate a list of sentences by a distributed conjunction, we place
-- the first part in front of the first element, the second
-- part between the last two elements, and commas in the other slots.
-- For sentences this is really not used.
conjunctDistrSentence : ConjunctionDistr -> ListSentence -> Sentence =
CO.conjunctDistrTable Mode ;
--3 Coordinating adjective phrases
--
-- The structure is the same as for sentences. The result is a prefix adjective
-- if and only if all elements are prefix.
ListAdjPhrase : Type =
{s1,s2 : Gender => Number => Str ; p : Bool} ;
twoAdjPhrase : (_,_ : AdjPhrase) -> ListAdjPhrase = \x,y ->
CO.twoTable2 Gender Number x y ** {p = andB x.p y.p} ;
consAdjPhrase : ListAdjPhrase -> AdjPhrase -> ListAdjPhrase = \xs,x ->
CO.consTable2 Gender Number CO.comma xs x ** {p = andB xs.p x.p} ;
conjunctAdjPhrase : Conjunction -> ListAdjPhrase -> AdjPhrase = \c,xs ->
CO.conjunctTable2 Gender Number c xs ** {p = xs.p} ;
conjunctDistrAdjPhrase : ConjunctionDistr -> ListAdjPhrase -> AdjPhrase = \c,xs ->
CO.conjunctDistrTable2 Gender Number c xs ** {p = xs.p} ;
--3 Coordinating noun phrases
--
-- The structure is the same as for sentences. The result is either always plural
-- or plural if any of the components is, depending on the conjunction.
-- The gender is masculine if any of the components is. A coordinated noun phrase
-- cannot be clitic.
ListNounPhrase : Type =
{s1,s2 : CaseA => Str ; g : PronGen ; n : Number ; p : Person} ;
twoNounPhrase : (_,_ : NounPhrase) -> ListNounPhrase = \x,y ->
{s1 = \\c => x.s ! stressed c ; s2 = \\c => y.s ! stressed c} **
{n = conjNumber x.n y.n ; g = conjGender x.g y.g ; p = conjPers x.p y.p} ;
consNounPhrase : ListNounPhrase -> NounPhrase -> ListNounPhrase = \xs,x ->
{s1 = \\c => xs.s1 ! c ++ CO.comma ++ xs.s2 ! c ;
s2 = \\c => x.s ! stressed c} **
{n = conjNumber xs.n x.n ; g = conjGender xs.g x.g ; p =conjPers xs.p x.p} ;
conjunctNounPhrase : Conjunction -> ListNounPhrase -> NounPhrase = \co,xs ->
{s = \\c => xs.s1 ! pform2case c ++ co.s ++ xs.s2 ! pform2case c} **
{n = conjNumber co.n xs.n ; g = xs.g ; p = xs.p ; c = Clit0 } ;
conjunctDistrNounPhrase : ConjunctionDistr -> ListNounPhrase -> NounPhrase =
\co,xs ->
{s = \\c => co.s1++ xs.s1 ! pform2case c ++ co.s2 ++ xs.s2 ! pform2case c} **
{n = conjNumber co.n xs.n ; g = xs.g ; p = xs.p ; c = Clit0} ;
-- We have to define a calculus of numbers of genders. For numbers,
-- it is like the conjunction with $Pl$ corresponding to $False$. For genders,
-- $Masc$ corresponds to $False$.
conjNumber : Number -> Number -> Number = \m,n -> case <m,n> of {
<Sg,Sg> => Sg ;
_ => Pl
} ;
conjGen : Gender -> Gender -> Gender = \m,n -> case <m,n> of {
<Fem,Fem> => Fem ;
_ => Masc
} ;
conjGender : PronGen -> PronGen -> PronGen = \m,n -> case <m,n> of {
<PGen Fem, PGen Fem> => PGen Fem ;
_ => PNoGen
} ;
-- For persons, we go in the descending order:
-- "moi et toi sommes forts", "lui ou toi es fort".
-- This is not always quite clear.
conjPers : Person -> Person -> Person = \p,q -> case <p,q> of {
<P3,P3> => P3 ;
<P1,_> => P1 ;
<_,P1> => P1 ;
_ => P2
} ;
--2 Subjunction
--
-- Subjunctions ("si", "quand", etc)
-- are a different way to combine sentences than conjunctions.
-- The main clause can be a sentences, an imperatives, or a question,
-- but the subjoined clause must be a sentence.
Subjunction = SS ;
subjunctSentence : Subjunction -> Sentence -> Sentence -> Sentence = \si,A,B ->
{s = \\m => subjunctVariants si A (B.s ! m)
} ;
subjunctImperative : Subjunction -> Sentence -> Imperative -> Imperative =
\si,A,B ->
{s = \\g,n => subjunctVariants si A (B.s ! g ! n)
} ;
subjunctQuestion : Subjunction -> Sentence -> Question -> Question = \si,A,B ->
{s = \\q => subjunctVariants si A (B.s ! q)
} ;
-- There are uniformly two variant word orders, e.g.
-- "si tu fume je m'en vais"
-- and "je m'en vais si tu fume".
subjunctVariants : Subjunction -> Sentence -> Str -> Str = \si,A,B ->
let {As = A.s ! Ind} in
variants {
si.s ++ As ++ B ;
B ++ si.s ++ As
} ;
--2 One-word utterances
--
-- An utterance can consist of one phrase of almost any category,
-- the limiting case being one-word utterances. These
-- utterances are often (but not always) in what can be called the
-- default form of a category, e.g. the nominative.
-- This list is far from exhaustive.
useNounPhrase : NounPhrase -> Utterance = \jean ->
postfixSS "." (defaultNounPhrase jean) ;
useCommonNounPhrase : Number -> CommNounPhrase -> Utterance = \n,mec ->
useNounPhrase (indefNounPhrase n mec) ;
-- one-form variants
defaultNounPhrase : NounPhrase -> SS = \jean ->
ss (jean.s ! stressed nominative) ;
defaultQuestion : Question -> SS = \quiesttu ->
ss (quiesttu.s ! DirQ) ;
defaultSentence : Sentence -> SS = \x -> ss (x.s ! Ind) ;
----- moved from Types
artDef : Gender -> Number -> CaseA -> Str ;
artIndef : Gender -> Number -> CaseA -> Str ;
genForms : Str -> Str -> Gender => Str ;
----- moved from Res
pronJe, pronTu, pronIl, pronElle, pronNous, pronVous, pronIls, pronElles :
Pronoun ;
chaqueDet, tousDet, quelDet, plupartDet : Determiner ;
commentAdv, quandAdv, ouAdv, pourquoiAdv : Adverb ;
etConj, ouConj : Conjunction ;
etetConj, ououConj : ConjunctionDistr ;
siSubj, quandSubj : Subjunction ;
ouiPhr, noPhr : Utterance ;
}

175
lib/resource-0.6/romance/TypesRomance.gf Normal file
View File

@@ -0,0 +1,175 @@
--1 Romance Word Classes and Morphological Parameters
--
-- This is a resource module for French and Italian morphology, defining the
-- morphological parameters and parts of speech of Romance languages.
-- It is used as the major part of language-specific type systems,
-- defined in $types.Fra.gf$ and $types.Ita.gf$. The guiding principle has been
-- to share as much as possible, which has two advantages: it saves work in
-- encoding, and it shows how the languages are related.
interface TypesRomance = {
--2 Enumerated parameter types for morphology
--
-- These types are the ones found in school grammars.
-- Their parameter values are atomic.
param
Number = Sg | Pl ;
Gender = Masc | Fem ;
Person = P1 | P2 | P3 ;
Mode = Ind | Con ;
Degree = Pos | Comp | Sup ;
-- The case must be made an abstract type, since it varies from language to
-- language. The same concerns those parameter types that depend on case.
-- Certain cases can however be defined.
param
RelGen = RNoGen | RG Gender ;
oper
CaseA : PType ;
NPFormA : PType ;
nominative : CaseA ;
accusative : CaseA ;
genitive : CaseA ;
dative : CaseA ;
stressed : CaseA -> NPFormA ;
unstressed : CaseA -> NPFormA ;
RelFormA : PType ;
-- The genitive and dative cases are expressed by prepositions, except for
-- clitic pronouns. The accusative case only makes a difference for pronouns.
-- Personal pronouns are the following type:
oper
Pronoun : Type = {
s : NPFormA => Str ;
g : PronGen ;
n : Number ;
p : Person ;
c : ClitType
} ;
-- The following coercions are useful:
oper
pform2case : NPFormA -> CaseA ;
case2pform : CaseA -> NPFormA ;
prepCase : CaseA -> Str ;
adjCompLong : Adj -> AdjComp ;
relPronForms : CaseA => Str ;
-- For abstraction and API compatibility, we define two synonyms:
oper
singular = Sg ;
plural = Pl ;
--2 Word classes and hierarchical parameter types
--
-- Real parameter types (i.e. ones on which words and phrases depend)
-- are mostly hierarchical. The alternative is cross-products of
-- simple parameters, but this cannot be always used since it overgenerates.
--
--3 Common nouns
--
-- Common nouns are inflected in number, and they have an inherent gender.
CNom : Type = {s : Number => Str ; g : Gender} ;
--3 Pronouns
--
-- Pronouns are an example - the worst-case one of noun phrases,
-- which are defined in $syntax.Ita.gf$.
-- Their inflection tables has tonic and atonic forms, as well as
-- the possessive forms, which are inflected like determiners.
--
-- Example: "lui, de lui, à lui" - "il,le,lui" - "son,sa,ses".
-- Tonic forms are divided into four classes of clitic type.
-- The first value is used for never-clitic noun phrases.
-- This classification is incomplete, since we do not (yet) treat
-- ditransitive verbs.
--
-- Examples of each: "Giovanni" ; "io" ; "lui" ; "noi".
param ClitType = Clit0 | Clit1 | Clit2 | Clit3 ;
-- Gender is not morphologically determined for first and second person pronouns.
PronGen = PGen Gender | PNoGen ;
-- The following coercion is useful:
oper
pgen2gen : PronGen -> Gender = \p -> case p of {
PGen g => g ;
PNoGen => variants {Masc ; Fem} --- the best we can do for je, tu, nous, vous
} ;
--3 Adjectives
--
-- Adjectives are inflected in gender and number.
-- Comparative adjectives are moreover inflected in degree
-- (which in French and Italian is usually syntactic, though).
Adj : Type = {s : Gender => Number => Str} ;
AdjComp : Type = {s : Degree => Gender => Number => Str} ;
--3 Verbs
--
-- In the current syntax, we use
-- a reduced conjugation with only the present tense infinitive,
-- indicative, subjunctive, and imperative forms.
-- But our morphology has full Bescherelle conjunctions:
-- so we use a coercion between full and reduced verbs.
-- The full conjugations and the coercions are defined separately for French
-- and Italian, since they are not identical. The differences are mostly due
-- to Bescherelle structuring the forms in different groups; the
-- gerund and the present participles show real differences.
param
VF =
VFin Mode Number Person
| VImper NumPersI
| VInfin
;
NumPersI = SgP2 | PlP1 | PlP2 ;
-- It is sometimes useful to derive the number of a verb form.
oper
nombreVerb : VF -> Number = \v -> case v of {
VFin _ n _ => n ;
_ => singular ---
} ;
-- The imperative forms depend on number and person.
vImper : Number -> Person -> VF = \n,p -> case <n,p> of {
<Sg,P2> => VImper SgP2 ;
<Pl,P1> => VImper PlP1 ;
<Pl,P2> => VImper PlP2 ;
_ => VInfin
} ;
Verbum : Type ;
VerbPres : Type = {s : VF => Str} ;
verbPres : Verbum -> VerbPres ;
}

4
src/GF/CF/Profile.hs
View File

@@ -21,7 +21,7 @@ import List (nub)
postParse :: CFTree -> Err Exp
postParse tree = do
iterm <- errIn "postprocessing initial parse tree" $ tree2term tree
iterm <- errIn ("postprocessing parse tree" +++ prCFTree tree) $ tree2term tree
return $ term2trm iterm
-- an intermediate data structure
@@ -93,4 +93,4 @@ term2trm (ITerm (fun, binds) terms) =
where
mkAbsR c e = foldr EAbs e c
mkAppAtom a = mkApp (EAtom a)
mkApp = foldl EApp
mkApp = foldl EApp

4
src/GF/Compile/ShellState.hs
View File

@@ -295,10 +295,14 @@ stateAbstract = abstractOf . stateGrammarST
maybeStateAbstract (ShSt (ma,_,_)) = ma
hasStateAbstract = maybe False (const True) . maybeStateAbstract
abstractOfState = maybe emptyAbstractST id . maybeStateAbstract
-}
stateIsWord sg = isKnownWord (stateMorpho sg)
{-
-- getting info on a language
existLang :: ShellState -> Language -> Bool
existLang st lang = elem lang (allLanguages st)

2
src/GF/Shell/Commands.hs
View File

@@ -268,7 +268,7 @@ execECommand env c = case c of
_ -> changeMsg ["command not yet implemented"]
where
sgr = firstStateGrammar env
agrs = [sgr] ---- allActiveGrammars env
agrs = allStateGrammars env ---- allActiveGrammars env
cgr = canCEnv env
gr = grammarCEnv env
der = maybe True not $ caseYesNo (globalOptions env) noDepTypes

4
src/GF/UseGrammar/Custom.hs
View File

@@ -241,8 +241,8 @@ customTokenizer =
,(strCI "code", const $ lexHaskell)
,(strCI "text", const $ lexText)
,(strCI "unglue", \gr -> map tS . decomposeWords (stateMorpho gr))
---- ,(strCI "codelit", lexHaskellLiteral . stateIsWord)
---- ,(strCI "textlit", lexTextLiteral . stateIsWord)
,(strCI "codelit", lexHaskellLiteral . stateIsWord)
,(strCI "textlit", lexTextLiteral . stateIsWord)
,(strCI "codeC", const $ lexC2M)
,(strCI "codeCHigh", const $ lexC2M' True)
-- add your own tokenizers here

17
src/GF/UseGrammar/Linear.hs
View File

@@ -42,13 +42,17 @@ linearizeToRecord gr mk m = lin [] where
xs' <- mapM (\ (i,x) -> lin (i:ts) x) $ zip [0..] xs
r <- case at of
A.AtC f -> look f >>= comp xs'
A.AtC f -> lookf c t f >>= comp xs'
A.AtL s -> return $ recS $ tK $ prt at
A.AtI i -> return $ recS $ tK $ prt at
A.AtV x -> lookCat c >>= comp [tK (prt at)]
A.AtM m -> lookCat c >>= comp [tK (prt at)]
A.AtV x -> lookCat c >>= comp [tK (prt_ at)]
A.AtM m -> lookCat c >>= comp [tK (prt_ at)]
return $ fmk $ mkBinds binds r
r' <- case r of -- to see stg in case the result is variants {}
FV [] -> lookCat c >>= comp [tK (prt_ t)]
_ -> return r
return $ fmk $ mkBinds binds r'
look = lookupLin gr . redirectIdent m . rtQIdent
comp = ccompute gr
@@ -60,6 +64,11 @@ linearizeToRecord gr mk m = lin [] where
lookCat = return . errVal defLindef . look
---- should always be given in the module
-- to show missing linearization as term
lookf c t f = case look f of
Ok h -> return h
_ -> lookCat c >>= comp [tK (prt_ t)]
-- thus the special case:

7
src/GF/UseGrammar/Parsing.hs
View File

@@ -64,9 +64,10 @@ tokens2trms opts sg cn parser as = do
_ | null ts0 -> checkWarn "No success in cf parsing" >> return []
_ | raw -> do
ts1 <- return (map cf2trm0 ts0) ----- should not need annot
mapM (checkErr . (annotate gr) . trExp) ts1 ---- complicated
mapM (checkErr . (annotate gr) . trExp) ts1 ---- complicated; often fails
_ -> do
(ts1,_) <- checkErr $ mapErr postParse ts0
(ts1,ss) <- checkErr $ mapErr postParse ts0
if null ts1 then raise ss else return ()
ts2 <- mapM (checkErr . (annotate gr) . trExp) ts1 ----
if forgive then return ts2 else do
let tsss = [(t, allLinsOfTree gr cn t) | t <- ts2]
@@ -75,7 +76,7 @@ tokens2trms opts sg cn parser as = do
if null ps
then raise $ "Failure in morphology." ++
if verb
then "\nPossible corrections: " +++++
then "\nPossible corrections: " +++++
unlines (nub (map sstr (concatMap snd tsss)))
else ""
else return ps

5
src/GF/UseGrammar/Tokenize.hs
View File

@@ -129,6 +129,9 @@ unknown2string isKnown = map mkOne where
mkOne t@(TC s) = if isKnown s then t else mkTL s
mkOne t = t
lexTextLiteral isKnown = unknown2string isKnown . lexText
lexTextLiteral isKnown = unknown2string (eitherUpper isKnown) . lexText
lexHaskellLiteral isKnown = unknown2string isKnown . lexHaskell
eitherUpper isKnown w@(c:cs) = isKnown (toLower c : cs) || isKnown (toUpper c : cs)
eitherUpper isKnown w = isKnown w

2
src/Today.hs
View File

@@ -1 +1 @@
module Today where today = "Tue Nov 25 17:48:12 CET 2003"
module Today where today = "Thu Dec 4 13:52:32 CET 2003"

30
src/tools/AlphaConvGF.hs Normal file
View File

@@ -0,0 +1,30 @@
module Main where
import LexGF
import Alex
import System
main :: IO ()
main = do
file1:file2:_ <- getArgs
s <- readFile file1
ts <- tokens s
if file1==file2 then print (length ts) else return () -- make sure file1 is in mem
writeFile file2 [] -- create file2 or remove its old contents
alphaConv file2 ts (Pn 1 1 1)
alphaConv :: FilePath -> [Token] -> Posn -> IO ()
alphaConv file (t:ts) p0 = case t of
PT p (TV s) -> changeId file p0 p s ts
_ -> putToken file p0 t >>= alphaConv file ts
alphaConv _ _ = putStrLn "Ready."
putToken :: FilePath -> Posn -> Token -> IO Posn
putToken file (Pn _ l0 c0) t@(PT (Pn a l c) _) = do
let s = prToken t
ns = l - l0
ls = length s
replicate ns $ appendFile file '\n'
replicate (if ns == 0 then c - c0 else c-1) $ putChar ' '
putStr s
return $ Pn (a + ls) l (c + ls) ts